Google Maps über COM (Component Object Model)

Thom

Use Google Maps API inside your Delphi application. Free, easy to use and much more powerful than a component.

Der Kern besteht aus einer Delphi-To-JavaScript-Bridge, mit deren Hilfe Delphi-Programme über das COM-Interface des Internet Explorers auf JavaScript-Objekte und -Funktionen zugreifen können. Die Kommunikation ist dabei bidirektional: Das bedeutet, daß Objekt- und anonyme Methoden aus JavaScript heraus aufgerufen werden können - zum Beispiel als Callback-Funktion, Event-Handler oder "injizierter" Code.

In diesem Framework wurde mit Hilfe dieser Delphi-To-JavaScript-Bridge das komplette Google Maps API abgebildet. Damit ist es möglich, alle Funktionen und Objekte dieses API's anzusprechen, ohne eine einzige Zeile JavaScript schreiben zu müssen.

Nun gibt es schon eine Reihe von Lösungsvorschlägen und Komponenten für Delphi, die das Google Maps API kapseln (ohne Anspruch auf Vollständigkeit):

jasontpenny (Lösungsansatz)
Rodrigo (Lösungsansatz)
TGoMaps (Komponente, kommerziell, 599 € + MwSt.)
TGoMaps Lite (Komponente, kostenlos, stark eingeschränkte Version von TGoMaps, dient als "Testversion" von TGoMaps)
TGAgisGoogleMap und TGAgisGoogleGeo (Komponenten, kommerziell, 799 USD + MwSt.)
TECMap (Komponente, kommerziell, 500 € + MwSt., Testkomponente auf Anfrage)
TMS WebGMaps (Komponenten, kommerziell, 95 € + MwSt.)
DelphiMaps (Komponenten, MPL 1.1)
GMLib (Komponenten, LGPL 3.0)

Weshalb dann noch dieses Framework?
Ganz klar zwei Gründe:

Der Preis. Für Freeware oder OpenSource, die nach den Lizenzbedingungen von Google keine Premier Lizenz benötigt, sind diese Preise indiskutabel. Eine kostenlose Version, die das komplette API bedient, ist mir nicht bekannt.
Die Flexibilität. Eine Komponente kann prinzipiell kein API ersetzen. Sie macht zwar die Arbeit des Programmierers bedeutend leichter und spart viel Zeit bei der Einarbeitung und Umsetzung des Projektes (bei kommerziellen Projekten ist Zeit gleich Geld, daher auch die hohen Preise für diese Komponenten) - schränkt aber mehr oder weniger stark ein.
Eine JavaScript-ähnliche Programmierung ist nicht möglich.

Mit diesem Framework können JavaScript-Beispiele ohne Probleme nach Delphi umgesetzt werden - mit den Vorteilen einer Code-Vervollständigung und komfortablen Debugging-Möglichkeiten.

Ein kleines Beispiel:

markieren

Code:

			[...]

<script type="text/javascript">

  function CreateMap() {

    var Options = {zoom: 13,

                   center: new google.maps.LatLng(47.651743,-122.349243),

                   mapTypeId: google.maps.MapTypeId.SATELLITE};

    new google.maps.Map(document.getElementById("div_map"),Options);

  };

</script>

</head>

<body onload="CreateMap()">

[...]

zusammenfalten · markieren

Delphi-Quellcode:

			procedure TForm1.FormShow(Sender: TObject);

begin

  if Script=nil then

    with TScript.Create(WebBrowser1) do

      LoadAPIAsync(InitMap);

end;

procedure TForm1.InitMap(Sender: TObject);

var

  Options: TMapOptions;

begin

  with TScript(Sender) do

  begin

    Options:=TMapOptions.Create;

    with Options do

    begin

      Zoom:=13;

      Center:=New(Google.Maps.LatLng(47.651743,-122.349243));

      MapTypeID:=Google.Maps.MapTypeID.Satellite;

    end;

    New(Google.Maps.Map(Options));

  end;

end;

In der aktuellen Version 2.0 besteht das Framework aus rund 30000 Quelltextzeilen, 10000 Zeilen Dokumentation im XML-Format und rund 10000 Zeilen in reichlich 80 Demos.

Systemvoraussetzungen

Delphi ab Version 5 (empfohlen Delphi 2009 oder neuer zur Nutzung von Unicode und anonymen Methoden)
Internet Explorer ActiveX (zum Beispiel TWebBrowser (1) oder TEmbeddedWB)
bei einigen Demos installierte Indy-Komponenten
bei einer Demo eine installierte TChart-Komponente

Das Framework wurde bisher mit folgenden Delphi-Versionen getestet:

Delphi 5
Delphi 7 (vielen Dank an angos!) (2)
Delphi 2005
Delphi 2007
Delphi 2010
Delphi XE
Delphi XE2 32/64 Bit
Delphi XE3 32/64 Bit (vielen Dank an Stefan für die angepaßte inc-Datei und für's Testen!)
Delphi XE4 32/64 Bit
Delphi XE5 32/64 Bit

Bekannte Probleme

In Zusammenhang mit dem Internet Explorer 6 (sollte eigentlich keiner mehr benutzen):

Darstellungsfehler bei Schatteneffekten
langsamer Schatten- und Bildaufbau
keine Überblendeffekte
keine Base64/Data-Unterstützung
Probleme bei der Nutzung von Icons (die Demos Icon Simple und Icon Complex bleiben hängen)
keine Animation von Markern
das StreetView-Symbol verschwindet sporadisch

Allgemein:

werden vor Delphi 2007 TGIFImage und vor Delphi 2009 TPNGImage verwendet (bis dahin nicht Bestandteil von Delphi), können die entsprechenden Compilerschalter in der Datei gmConfig.inc aktiviert werden
die integrierte XML-Hilfe funktioniert noch nicht richtig und ist noch nicht vollständig
unter den verstärkten Sicherheitseinstellungen für den Internet Explorer in einem Server-System konnte bisher kein Zugriff auf die Funktionen der JavaScript-Engine hergestellt werden
die Demo Places Autocomplete führt unter IE9 64 Bit zu einem Absturz des Programmes, wenn das Edit-Feld benutzt wird

Installation, Migration bestehender Projekte

Da es sich um ein Framework handelt, muß nichts in der IDE installiert werden - es müssen lediglich die Pfade zur gmConfig.inc sowie den Verzeichnissen API und JScript eingetragen werden (global oder in den Projekt-Optionen).

Die Umstellung von bestehenden Projekten unter Verwendung der Versionen 1.x auf die Version 2.0 sollte sich in der Regel auf die Anpassung der Unit-Namen beschränken. Um eine bessere Übereinstimmung zur Google Maps API-Dokumentation zu erzielen, wurden einige Units umbenannt. Auf die Einführung eines Namespace wurde mit Rücksicht auf ältere Delphi-Versionen (noch) verzichtet.
Es wird empfohlen, die Initialisierung der Karte in eine separaten Methode auszulagern, um den Refresh-Mechanismus (Taste F5) des Frameworks nutzen zu können.

Lizenz

(Möglichst) kurz und schmerzlos:
Ich mag keine seitenlangen Texte, die meist nur verunsichern (siehe aktuelle Problematik mit einer speziellen Datenbank) und die sowieso kaum jemand liest. Noch weniger mag ich Quelltexte, die am Anfang einen Hinweis enthalten, der länger ist als der eigentliche Code. Auch bin ich aus dem Alter heraus, in dem ich nach jeweils drei Zeilen mein Copyright hinterlassen muß, als hätte ich die genialste Erfindung aller Zeiten gemacht und müßte wie ein Hund mein Revier markieren. Wer das nötig hat, soll das machen - ich jedenfalls nicht.
Deshalb nur folgende Regeln:

Die Nutzungsbedingungen von Google sind zu beachten.
Die Verwendung des Frameworks ist kostenfrei, wenn die Anwendung, die damit erstellt wurde, kostenlos und frei für alle zur Verfügung steht (siehe Lizenzbestimmungen von Google: Das schließt zum Beispiel die Kopplung an kostenpflichtige Hard- oder Software und eine innerbetriebliche Nutzung aus!!!). Das veröffentlichte Programm muß keinesfalls OpenSource sein.
Keine Leistung - keine Verpflichtung. Wird das Framework in der kostenlosen Community-Edition verwendet, gibt es keinen Anspruch auf Bugfixes, Updates oder Hilfe. Das bedeutet natürlich nicht, daß ich hier im Forum nicht mehr auf Fragen antworte.
Für jegliche andere Nutzung (kommerziell, innerbetrieblich, geschlossene Benutzergruppe) ist eine Lizenzierung bei Google und mir notwendig. Bei Nachfrage bitte per PM oder Email melden. Von meiner Seite sind dann Bugfixes, Updates und Support für ein Jahr garantiert.
Wem das Framework gefällt und wer die Weiterentwicklung unterstützen möchte, kann das in Form eine Spende tun. Ab einer Spendenhöhe von gegenwärtig 25 € erhält der/die Spender/in als Dankeschön zusätzliche Units, Komponenten und Demos (siehe Abschnitt Erweiterungen) sowie alle weiteren Bonus-Komponenten, die in der Version 2.x veröffentlicht werden. Falls jemand kein PayPal-Konto besitzt, kann er mich auch für eine direkte Überweisung (innerhalb Deutschlands) kontaktieren. Für einen Betrag von mindestens 100 € wird der Spender namentlich genannt (falls er nicht anonym bleiben möchte). (3)

Erweiterungen

Panoramio API
- Wrapper-Unit
- Demo
KeyDragZoom Library
- Wrapper-Unit
- sechs Demos
MarkerClustererPlus Library
- Wrapper-Unit
- fünf Demos
RichMarker Library
- Wrapper-Unit
- zwei Demos

Viel Spaß!

(1) Wer für die Starter Editionen (XE bzw. XE2) keine TWebBrowser-Komponente besitzt, kann diese

hier nachrüsten.
(2) siehe

Beitrag
(3) Spenden über

PayPal (Bitte Name und Email-Adresse angeben, damit ich die Bonus-Units versenden kann.)

**Gruber_Hans_12345**

Hi

Wollte es auch gerade ausprobieren, alles runtergeladen, suchpfade und co
aber beim compilieren bringt er mir einen fehler

markieren

Code:

			DCC Fehler BrowserTools.pas(266): E2250 Es gibt keine überladene Version von 'Encode64', die man mit diesen Argumenten aufrufen kann
		

zusammenfalten · markieren

Delphi-Quellcode:

			function Encode64(Data: TStream; MediaType: String): String;

var

  Stream: TStringStream;

begin

  Result:='';

  if not assigned(Data)

    then Exit;

  Stream:=TStringStream.Create('data:'+MediaType+';base64,');

  try

    Stream.Seek(0,soFromEnd);

    Encode64(Data,Stream); <<< Hier 

    Stream.Seek(0,soFromBeginning);

    Result:=Stream.DataString;

  finally

    Stream.Free;

  end;

end;

**Thom**

Doch:
Diese Funktion mit zwei Streams als Parameter gibt es. Sie befindet sich in der Unit Base64 (function Encode64(Src, Dest: TStream): Boolean; overload; ). Diese Unit wird auch von der Unit BrowserTools, aus der die von Dir zitierte Funktion function Encode64(Data: TStream; MediaType: String): String; stammt, über die uses-Anweisung eingebunden.

Du könntest testhalber einmal versuchen, den Aufruf explizit zu formulieren: Base64.Encode64(Data,Stream);

**Gruber_Hans_12345**

ah, habe es gefunden, ich habe ein anderes Base64 das auch im suchpfad ist, und das nimmt er als erstes her ...

eine andere Frage
was bedeuten all diese New `?

New(Google.Maps.Marker(MarkerOptions)); Die tuen gar nichts eigetnlich, sind die für zukünftige Sachen da, oder braucht es die für etwas?

**Thom**

Ja, Du hast vollkommen Recht:
Momentan hat die New-Funktion keinerlei Bedeutung - sie gibt lediglich den Eingangsparameter als Resultat zurück. Sie dient hier nur dazu, den Quelltext etwas leserlicher zu gestalten, indem darauf hingewiesen wird, daß ein neues Objekt angelegt wird/wurde. So erstellt die Funktion Google.Maps.LatLng(...) ein neues TLatLng-Objekt, was aber nicht sofort offensichtlich ist.
Insofern kann die New-Funktion momentan auch ohne Bedenken weggelassen werden.

Das wird sich aber in der kommenden Version grundlegend ändern: Dann wird das Objekt wirklich erst von der New-Funktion erstellt, die dann etwa wie der New-Operator in JavaScript arbeitet.
So liefert - um bei dem Beispiel zu bleiben - Google.Maps.LatLng nur die Klasse und New() erstellt eine Instanz. Das Ganze dient - wie schon erwähnt - der Lesbarkeit des Quelltextes.
Auch Hilfsobjekte werden dann über die New-Funktion erstellt, so daß der Delphi-typische Syntax TObject.Create bei der Verwendung des Frameworks überflüssig wird:

zusammenfalten · markieren

Delphi-Quellcode:

			procedure TForm1.FormShow(Sender: TObject);

begin

  with Script(WebBrowser1) do

    if not APILoaded

      then LoadAPIAsync(InitMap);

end;

procedure TForm1.InitMap(Sender: IObject);

var

  MapOptions: IMapOptions;

begin

  with Sender as IScript do

  begin

    MapOptions:=New(Google.Maps.MapOptions);

    with MapOptions do

    begin

      Zoom:=8;

      Center:=New(Google.Maps.LatLng(-34.397,150.644));

      MapTypeID:=Google.Maps.MapTypeID.Roadmap;

    end;

    New(Google.Maps.Map(MapOptions));

  end;

end;

Zu beachten ist hier, daß die Objekte nur noch über Interfaces angesprochen werden, was der besseren Speicherverwaltung dient.

**Gruber_Hans_12345**

Hallo

Gibt es eine möglichkeit alle Marker zu lsöchen
und / oder einen spezifischen

Ich finde irgendwie noch nicht das richtige

**Thom**

Jedes Objekt auf der Karte wird in einer entsprechenden Liste des Script-Objektes gespeichert und verwaltet.

markieren

Delphi-Quellcode:

			with Script do

  while Markers.Count>0 do

  begin

    Markers[0].SetMap(TMap(nil));

    Markers.Delete(0);

  end;

Für neuere Delphi-Versionen wird auch der for-in-Syntax unterstützt:

markieren

Delphi-Quellcode:

			with Script do

begin

  for Marker in Markers do

    Marker.SetMap(TMap(nil));

  Markers.Clear;

end;

In Zukunft wird der Aufruf von Script.Markers.Clear; ausreichen. Momentan werden dabei die Marker aber nicht von der Karte entfernt. Deshalb der explizite Aufruf von SetMap(...) ;

**Gruber_Hans_12345**

Danke hat funktioniert

**jonathan**

hallo,

gibt es eine möglichkeit, das erstellen vieler Custom-Marker mit OnClick-Event zu beschleunigen?

beispiel:

markieren

Code:

			MarkerArray:=TMarkerArray.Create;

for n:=1 to 3000 do begin

   newMarkerPos:=New(Script.Google.Maps.LatLng(... , ...));

   MarkerOptions:=TMarkerOptions.Create;

   with MarkerOptions do begin

      Position:=newMarkerPos;

   end;

   Marker:=New(Script.Google.Maps.Marker(MarkerOptions));

   MarkerArray.Push(Marker);

end;

MarkerClusterer.AddMarkers(MarkerArray,true);

MarkerClusterer.Repaint;

das läuft wunderbar (<1s)

packe ich in die MarkerOptions noch mehr rein:

markieren

Code:

			      Title:=...;

      zIndex:=...;

      IconImage:=...;

      ShadowImage:=...;

      Shape:=...;

dauert es schon knapp 10s

natürlich würde ich aber auch gerne was mit den Markern machen...
setze ich

markieren

Code:

Marker.OnClick:=MarkerClick;

dauert das ganze dann allerdings schlappe 5min !!!
was natürlich nicht mehr bedienbar ist...

irgendwelche tipps oder ideen?
oder mache ich was grundlegendes falsch?
1000 dank!

**Thom**

Ja, was soll ich sagen: JavaScript bleibt nun mal JavaScript - und darauf muß das Framework leider aufbauen (Lizenzbestimmungen von Google).

Ich habe Deine Aussagen untersucht und mußte feststellen, daß die Zuweisung von Ereignishandlern tatsächliche überproportional viel Zeit kostet. Ein kleiner Patch in der Unit JScriptObjects sollte etwas Entspannung bringen:

zusammenfalten · markieren

Delphi-Quellcode:

			procedure TCustomScript.MakeFunctionNameUnique(var FunctionName: String);

var

  s: String;

  GUID: TGUID;

begin

  if Assigned(FExternalMethods) then

  begin

    if FExternalMethods.IndexOf(FunctionName)>=0 then

    begin

      CreateGuid(GUID);

      s:=GUIDToString(GUID);

      s:=StringReplace(s,'{','',[rfReplaceAll]);

      s:=StringReplace(s,'}','',[rfReplaceAll]);

      s:=StringReplace(s,'-','',[rfReplaceAll]);

      FunctionName:=FunctionName+s;

      if AnsiChar(FunctionName[1]) in ['0'..'9']

        then FunctionName:='_'+FunctionName;

    end;

  end;

end;

Das Ganze ist zwar kein Wundermittel - brachte aber auf meinem Rechner reichlich 50% Zeitersparnis bei 1000 Markern.

Um für die Marker nicht die ganze Oberfläche zu blockieren, könntest Du deren Erstellung auch in das OnIdle-Ereignis der Anwendung auslagern oder zwischendurch Application.ProcessMessages aufrufen. Die Auslagerung in einen Thread geht leider nicht, da Microsoft's JavaScript-Engine nicht threadsicher ist.

Es wäre schön, wenn Du den Patch testen und mir mitteilen könntest, wie viel er gebracht hat. Wenn ich wieder etwas mehr Zeit habe, werde ich das Ganze noch einmal intensiver untersuchen und finde vielleicht noch die eine oder andere Optimierungsmöglichkeit.

**jonathan**

vielen dank, der patch funktioniert soweit - das ganze ist jetzt DEUTLICH schneller.
der schlimmste "zeitfresser" scheint wohl mit der GUID-methode behoben zu sein...
wobei ein wenig weitere optimierung natürlich nie schaden kann

falls du den patch in deine "offiziellen sourcen" übernehmen möchtest, müsstest
du beachten, dass CreateGUID unter Delphi 5 noch CoCreateGUID heisst und in der
unit ActiceX deklariert ist...

Erstellt von	For	Type	Datum
DELPHI \| (google maps)	This thread	Refback	11. Nov 2011 09:07
Twebbrowser HTML tag to UniHTMLFrame1 - uniGUI Discussion Forums	This thread	Refback	4. Nov 2011 06:52
DoraDev1975: google maps	This thread	Refback	23. Sep 2011 08:18
delphi osm - Google Search	Post #0	Refback	19. Sep 2011 09:02
DoraDev1975: ?ิ????? 2011	This thread	Refback	11. Sep 2011 16:39
DoraDev1975	This thread	Refback	30. Aug 2011 10:13
Untitled document	This thread	Refback	25. Jun 2011 19:57
Interact with Google Maps in a TWebBrowser from Delphi \| Ramblings	This thread	Refback	26. Jan 2011 05:12
google maps mit delphi link - Google Search	This thread	Refback	24. Jan 2011 14:24
google maps mit delphi - Google Search	This thread	Refback	24. Jan 2011 14:20
Untitled document	This thread	Refback	19. Jan 2011 21:49

Google Maps über COM (Component Object Model)

Forumregeln

LinkBack to this Thread

Gruber_Hans_12345 Delphi 2007 Professional	#273 29. Aug 2012, 12:52 ah, habe es gefunden, ich habe ein anderes Base64 das auch im suchpfad ist, und das nimmt er als erstes her ... eine andere Frage was bedeuten all diese New `? New(Google.Maps.Marker(MarkerOptions)); Die tuen gar nichts eigetnlich, sind die für zukünftige Sachen da, oder braucht es die für etwas?
	Zitat

Gruber_Hans_12345 Delphi 2007 Professional	#275 30. Aug 2012, 09:47 Hallo Gibt es eine möglichkeit alle Marker zu lsöchen und / oder einen spezifischen Ich finde irgendwie noch nicht das richtige
	Zitat

Gruber_Hans_12345 Delphi 2007 Professional	#277 30. Aug 2012, 12:33 Danke hat funktioniert
	Zitat