Google Maps über COM (Component Object Model)

[HJay]

Zitat von Thom:

Anders verhält es sich momentan mit den Options-Objekten - zum Beispiel TMarkerOptions. Diese können/sollten freigegeben werden - müssen aber nicht. Können/sollten deshalb, weil sie zwar bei Beendigung des Programmes automatisch abgeräumt werden, bis dahin aber unnötig Speicher belegen.

Ein TMarkerOptions-Objekt sollte wann genau freigegeben werden? Kann es schon freigegeben werden, direkt nachdem es verwendet wurde (scheint auf den ersten Blick zu funktionieren)? Oder erst, sobald der zugehörige Marker nicht mehr gebraucht wird?

Code:

    MarkerOptions := TMarkerOptions.Create;
    with MarkerOptions do begin
      Position := MyLatLng;
      Map := MyMap;
      Title := 'Hello World!';
    end;
    New(Google.Maps.Marker(MarkerOptions));
    MarkerOptions.Free; // hier schon?

[Thom]

Die Optionsobjekte werden nur während der Erstellung des eigentlichen Objektes benötigt und können deshalb so freigegeben werden, wie von Dir beschrieben.

Die Optionsobjekte kann man als eine Liste mit Name-Wert-Paaren ohne Methoden betrachten.

[HJay]

Bisher klappt alles sehr gut -- echt ein ganz tolles Framework! An dieser Stelle nochmals vielen Dank!

Ein Problem habe ich derzeit aber leider:

Ich führe in FormCreate die Initialisierung aus. Wenn ich dann direkt in Anschluss ebenfalls in FormCreate() oder auch in FormShow() einen Marker erzeugen will, dann scheitert dies mit einer Zugriffsverletzung (auf 000000).

Habe ich exakt die gleiche Routine aber auf Button1Click(), dann funktioniert alles prächtig. Hast Du irgendeine Idee dazu, woran das liegen könnte? Muss man irgendwas abwarten? Gibt es dazu ein Event?

Code:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, OleCtrls, SHDocVw,

  gmAPI, gmMap, gmBase, gmOverlaysMarker;

type
  TForm1 = class(TForm)
    WebBrowser1: TWebBrowser;
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    procedure InitMap(Sender: TObject);
    procedure MakeMarker;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  MakeMarker;  // läuft ohne Probleme!
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  if Script=nil then with TScript.Create(WebBrowser1) do LoadAPIAsync(InitMap);
//  MakeMarker;  // stürzt ab!
end;

procedure TForm1.InitMap(Sender: TObject);
  var MyOptions : TMapOptions;
begin
  with Sender as TScript do begin
    MyOptions := TMapOptions.Create;
    with MyOptions do begin
      Zoom := 12;
      Center := New(Google.Maps.LatLng(51.250249, 9.835209));
      StreetViewControl := False;
      MapTypeID := Google.Maps.MapTypeID.Roadmap;
    end;
    New(Google.Maps.Map(MyOptions));
  end;
end;

procedure TForm1.MakeMarker;
  var MarkerOptions : TMarkerOptions;
begin
  with Script(WebBrowser1) do begin
    MarkerOptions := TMarkerOptions.Create;
    with MarkerOptions do begin
      Position := New(Google.Maps.LatLng(51.250249, 9.835209));
      Map      := Maps[0];
    end;
    New(Google.Maps.Marker(MarkerOptions));
    MarkerOptions.Free;
  end;
end;

end.

[Thom]

Danke, das hört man gern!

Ja - das kann nicht funktionieren. Das API (genauer gesagt: die JavaScript-Bibliothek) muß erst von den Google-Servern geladen werden. Das dauert natürlich je nach Internetverbindung, Serverauslastung und Rechnergeschwindigkeit eine Weile.
Die Methode LoadAPIAsync() führt diesen Vorgang durch und ruft anschließend die Methode InitMapProc (die übergebene Callback-Methode) auf. Erst zu diesem Zeitpunkt wurde das API vollständig geladen und die (JavaScript-)Objekte Google und Maps angelegt. Vorher existieren sie nicht und der Zugriff darauf führt zu einer Zugriffsverletzung bzw. Exception.
Lädst Du das API asynchron, hat das den Vorteil, daß Deine Anwendung inzwischen weiter initialisiert und die Fenster angezeigt werden können.

Die zweite Möglichkeit besteht im blockierenden Laden des API's über die Methode LoadAPI() (also ohne Async). Diese Funktion kehrt erst nach der kompletten API-Initialisierung zurück und blockiert damit natürlich den Hauptthread. Das würde ich nicht empfehlen - deshalb wird in sämtlichen Demos die Methode LoadAPIAsync() verwendet.

Schreibst Du also

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  if Script=nil then with TScript.Create(WebBrowser1) do LoadAPI(InitMap);
  MakeMarker; 
end;

, dann sollte es funktionieren.

[jonathan]

Hi,
wie kann man die aktuelle GOOGLE Maps Kartenansicht ausdrucken?
Gibt es dafür eine Lösung direkt aus der API heraus?

Oder ist der Weg über die TWebPanel Komponente der geschicktere?
z.B. WebPanel.ControlInterface.ExecWB(OLECMDID_PRINT, OLECMDEXECOPT_PROMPTUSER, vIn, vOut) ...

[Thom]

Das Framework besitzt dafür keine integrierte Möglichkeit.

Du könntest natürlich einen Screenshot von der Anwendung machen (Alt+Druck) und den Inhalt der Zwischenablage über ein geeignetes Programm ausdrucken.
Programmtechnisch könntes Du den Inhalt des Formulars auch direkt in ein Bitmap zeichnen lassen.
Eine weitere Möglichkeit besteht darin, über Interfaces ein Bitmap vom Inhalt des Browsers abzufragen.

P.S.:
Ich habe gerade gesehen, daß Du Deinen Beitrag überarbreitet hast.
Ja: Das wäre wahrscheinlich auch eine Möglichkeit - habe ich allerdings noch nicht getestet.

[DelphiFan2008]

Hallo jonathan,

verwende die Funktion zum speichern des Inhaltes des WebBrowsers in einem JPG-File, hatte ich aus einem Beitrag hier im Forum

Delphi-Quellcode:

procedure WebBrowserScreenShot( const wb:TWebBrowser;const FileName:TFileName );
var viewObject : IViewObject;
    r          : TRect;
    Bitmap     : TBitmap;
begin
  if wb.Document <> nil then
  begin
    wb.Document.QueryInterface( IViewObject,viewObject );
    if Assigned( viewObject )then
    try
      Bitmap := TBitmap.Create;
      try
        r := Rect( 0,0,wb.Width,wb.Height );

        Bitmap.Height := wb.Height;
        Bitmap.Width  := wb.Width;

        viewObject.Draw( DVASPECT_CONTENT,1,nil,nil,Application.Handle,Bitmap.Canvas.Handle,@r,nil,nil,0 );

        with TJPEGImage.Create do
        try
          Assign( Bitmap ) ;
          SaveToFile( FileName ) ;
        finally
          Free;
        end;
        Clipboard.Assign( Bitmap );
      finally
        Bitmap.Free;
      end;
    finally
      viewObject._Release;
    end;
  end;
end;

dabei setze ich die Größe der Karte vorher auf eine virtuelle Größe die ich im Ziel haben will z.B. w:=4096,h:=4096

Delphi-Quellcode:

  
  WebBrowserMap.Align  := alNone;
  WebBrowserMap.Width  := w;
  WebBrowserMap.Height := h;

danach zentriere ich den Kartenauschnitt auf meinen gewünschten Bereich

MapCenter; // eigene Funktion mit Script.Maps[0].FitBounds( t ) etc. dann speichern.

  WebBrowserScreenShot( WebBrowserMap,APP_PATHTEMPFILES + '\Test.jpg' ); Wichtig ist hier, dass es abhängig von der Breite/Höhe dauert, bis die Karte aufgebaut ist. Beim zweiten mal deutlich schneller -> Cache.
Ich verwende derzeit eine Zeitschleife. Versuche mit WebBrowserMap.Busy=False und Map.OnTilesLoaded waren bisher nicht erfolgreich. Die Lösung mit der Zeitschleife ist für persönliche Belange ausreichend, für die Weitergabe der Applikation indiskutabel aber sie tut. Das Ergebis ist dann eine schöne Karte in einer tollen detailierten Auflösung. Optimal z.B. für die Grundlage einer Kamerafahrt über die Karte beim Videoschnitt -> Indiana Jones Effekt. (Lizenzbestimmungen beachten).

Danach Browser wieder in Client und Ausschnitt zentrieren

Delphi-Quellcode:

  WebBrowserMap.Align  := alClient;
  MapCenter;

Gruß DelphiFan2008