AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

TPanel sizeable machen?

Ein Thema von smart · begonnen am 17. Jan 2011 · letzter Beitrag vom 17. Jan 2011
Antwort Antwort
Benutzerbild von smart
smart

Registriert seit: 19. Dez 2004
Ort: Bochum
1.266 Beiträge
 
Delphi 2007 Professional
 
#1

TPanel sizeable machen?

  Alt 17. Jan 2011, 19:17
Hallo Alle,

kann man ein TPanel sizeable machen?
Heike Kretschmann
Viele Grüße aus Bochum

kaum denkt man alles ist fertig, da fängt man wieder von Vorn an.
  Mit Zitat antworten Zitat
Benutzerbild von haentschman
haentschman

Registriert seit: 24. Okt 2006
Ort: Seifhennersdorf / Sachsen
4.795 Beiträge
 
Delphi 10.1 Berlin Professional
 
#2

AW: TPanel sizeable machen?

  Alt 17. Jan 2011, 19:22
Hallo...
meinst du so richtig mit verändertem Cursor auf den Ecken / Kanten, wie ein Fenster ?
Prinzipiell sollte so etwas machbar sein. Allerdings wirst du alles Händisch programmieren dürfen.
  Mit Zitat antworten Zitat
Benutzerbild von Björn Ole
Björn Ole

Registriert seit: 11. Jul 2008
166 Beiträge
 
Delphi XE Professional
 
#3

AW: TPanel sizeable machen?

  Alt 17. Jan 2011, 19:47
Sehr rudimentär, auf jeden Fall noch ausbaufähig:
Delphi-Quellcode:
procedure TForm1.Panel1MouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
var
  panel: TPanel;
  point: TPoint;
begin
  panel := Sender as TPanel;
  point := panel.ScreenToClient(Mouse.CursorPos);
  panel.Tag := Integer((point.X > panel.Width - 10) or (point.Y > panel.Height - 10));
end;

procedure TForm1.Panel1MouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
var
  panel: TPanel;
  point: TPoint;
begin
  panel := Sender as TPanel;
  if Boolean(panel.Tag) then
  begin
    point := panel.ScreenToClient(Mouse.CursorPos);
    panel.Width := point.X;
    panel.Height := point.Y;
  end;
end;

procedure TForm1.Panel1MouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
var
  panel: TPanel;
begin
  panel := Sender as TPanel;
  panel.Tag := Integer(false);
end;
  Mit Zitat antworten Zitat
Benutzerbild von Bummi
Bummi

Registriert seit: 15. Jun 2010
Ort: Augsburg Bayern Süddeutschland
3.470 Beiträge
 
Delphi XE3 Enterprise
 
#4

AW: TPanel sizeable machen?

  Alt 17. Jan 2011, 20:26
grade mal aus einer Komponente von mir herauskopiert
Delphi-Quellcode:

Procedure TSQLCreator2.MoveControl(ControlHandle:Integer);
begin
  releasecapture;
  sendmessage(ControlHandle, WM_NCLBUTTONDOWN, 2, 0);
end;



Procedure TSQLCreator2.SizeControl(ControlHandle:Integer);
begin
  releasecapture;
  sendmessage(ControlHandle, WM_syscommand, SC_size+6,-1);
end;

Procedure TSQLCreator2.SizeControlW(ControlHandle:Integer);
begin
  releasecapture;
  sendmessage(ControlHandle, WM_syscommand, SC_size+2,-1);
end;

Procedure TSQLCreator2.SizeControlB(ControlHandle:Integer);
begin
  releasecapture;
  sendmessage(ControlHandle, WM_syscommand, SC_size+8,-1);
end;

EDIT und noch ein Beispieleinsatz
Delphi-Quellcode:
procedure TSQLCreator2.TBLVorMouseDown(Sender: TObject;Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
    if y < TPanel(Sender).Height -10 then
       begin
       SizeControlW(TPanel(Sender).Handle);
       //RepaintLink;
       end
    else if (y > TPanel(Sender).Height -4) and (x > TPanel(Sender).Width -4) then
       begin
       SizeControlB(TSqlBox2(Sender).Handle);
      // RepaintLink;
       end
    else
       begin
       SizeControl(TSqlBox2(Sender).Handle);
     // RepaintLink;
       end;
end;
Thomas Wassermann H₂♂
Das Problem steckt meistens zwischen den Ohren
DRY DRY KISS
H₂ (wenn bei meinen Snipplets nichts anderes angegeben ist Lizenz: WTFPL)
  Mit Zitat antworten Zitat
Benutzerbild von Fussball-Robby
Fussball-Robby

Registriert seit: 22. Okt 2007
Ort: Nähe Köln
1.063 Beiträge
 
Delphi 7 Enterprise
 
#5

AW: TPanel sizeable machen?

  Alt 17. Jan 2011, 20:44
Ein anderer Ansatz:
Delphi-Quellcode:
type
  TPanel = class(ExtCtrls.TPanel)
    procedure WMNCHitTest(var Message: TWMNCHitTest); message WM_NCHITTEST;
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  end;

{....}

procedure TPanel.CreateParams(var Params: TCreateParams);
begin
  //Damit wird dein Panel sizeable
  inherited CreateParams(Params);
  Params.Style := Params.Style or WS_SIZEBOX;
end;

procedure TPanel.WMNCHitTest(var Message: TWMNCHitTest);
begin
  //Damit kann man es zusaätzlich verschieben
  inherited;
  if Message.Result = htClient then
    Message.Result := htCaption;
end;
Du Kannst beide Methoden unabhängig voneinander benutzen. Viele Grüße
Robert L.
Der folgende Satz ist richtig!
Der vorherige Satz ist falsch!

Paradox
  Mit Zitat antworten Zitat
Benutzerbild von smart
smart

Registriert seit: 19. Dez 2004
Ort: Bochum
1.266 Beiträge
 
Delphi 2007 Professional
 
#6

AW: TPanel sizeable machen?

  Alt 17. Jan 2011, 21:57
Vielen Dank an Euch. Wieder was dazu gelehrnt.
Heike Kretschmann
Viele Grüße aus Bochum

kaum denkt man alles ist fertig, da fängt man wieder von Vorn an.
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +2. Es ist jetzt 01:52 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf