Mehrdimensionales dynamisches Array, Element löschen

[himitsu]

Achtung, alle nachvollgenden Kodes sind speziell auf diese spezifische Datenstruktur ausgelegt.
(abgesehn von Code 2, welcher da "etwas" flexibler ist)

Delphi-Quellcode:

type
  TIntArray = array of array of Integer;
procedure DeleteArrayElement(var AArray: TIntArray; const AIndex: Integer);
var
  i: Integer;
begin
  AArray[AIndex] := nil;  // daten löschen ... bei einem Einfachen Integer war das noch nicht wichtig
  Move(AArray[AIndex + 1], AArray[AIndex], SizeOf(AArray[0]) * (High(AArray) - AIndex));
  Pointer(AArray[High(AArray)]) := nil;  // leeres Feld initialisieren, da sonst eine falsche Referens drinnensteht.
  SetLength(AArray, Length(AArray) - 1);
end;

oder

Delphi-Quellcode:

type
  TIntArrayX = array of Integer;
  TIntArray = array of TIntArrayX;
procedure DeleteArrayElement(var AArray: TIntArray; const AIndex: Integer);
var
  i: Integer;
  Temp: TIntArrayX;
begin
  Temp := AArray[AIndex];  // zwischenspeichern
  Move(AArray[AIndex + 1], AArray[AIndex], SizeOf(AArray[0]) * (High(AArray) - AIndex));
  Pointer(AArray[High(AArray)]) := nil;  // leeres Feld initialisieren.
  AArray[High(AArray)] := Temp;  // zurückspeichern ... SetLength gibt es dann frei
  SetLength(AArray, Length(AArray) - 1);
end;

oder

Delphi-Quellcode:

type
  TIntArray = array of array of Integer;
procedure DeleteArrayElement(var AArray: TIntArray; const AIndex: Integer);
var
  i: Integer;
  Temp: Pointer;
begin
  Temp := Pointer(AArray[AIndex]);  // zwischenspeichern
  Move(AArray[AIndex + 1], AArray[AIndex], SizeOf(Pointer) * (High(AArray) - AIndex));
  Pointer(AArray[High(AArray)]) := Temp;  // zurückspeichern (quasi mit AArray[AIndex] getauscht)
  SetLength(AArray, Length(AArray) - 1);
end;

Man bedenke, daß array of Integer ein Typ ist, dessen Speicher von Delphi verwaltet wird, außerdem liegen alle Daten außerhalb der Arraystruktur des übergeordneten Arrays, darum muß man sehr gut aufpassen, daß man an der Speicherverwaltung nix kaputt macht, wenn man da rumfummelt und die automatische Speicherverwaltung dermaßen umgeht.

Also, eine TList oder gar TList<...> kann da optimaler/einfacher sein.

[schwa226]

Special THX to himitsu!

Ich habe die erste Methode probiert und sie geht ohne Probleme!
Hätte mir nicht gedacht das, dass so kompliziert werden würde!

Wenn sich aber mein TIntArray nochmal ändern sollte werde ich dann wahrscheinlich doch noch auf TList ausweichen.

[mleyen]

Doh, ja TList wär echt die bessere Wahl.
Bzw:

Delphi-Quellcode:

type
  TIntArray = array of Integer;
  PIntArr = ^TIntArray;
  TIntArrayArray = array of PIntArr;
  
  procedure DeleteArrayElement(var AArray: TIntArrayArray; const AIndex: Integer);
  begin        
    Dispose(AArray[AIndex]);
    Move(AArray[AIndex + 1], AArray[AIndex], SizeOf(AArray[0]) * (Length(AArray) - AIndex - 1)); //Dahinterliegende Daten aufrücken
    SetLength(AArray, Length(AArray) - 1); // Länge kürzen
  end;

[himitsu]

Zitat von mleyen:

Bzw:

Delphi-Quellcode:

type
  TIntArray = array of Integer;
  PIntArr = ^TIntArray;
  TIntArrayArray = array of PIntArr;
  
  procedure DeleteArrayElement(var AArray: TIntArrayArray; const AIndex: Integer);
  begin        
    Dispose(AArray[AIndex]);
    Move(AArray[AIndex + 1], AArray[AIndex], SizeOf(AArray[0]) * (Length(AArray) - AIndex - 1));
    FillChar(AArray[High(AArray)], SizeOf(AArray[0]), 0);  
    SetLength(AArray, Length(AArray) - 1);
  end;

FillChar/ZeroMemory nicht vergessen, da sonst das letzte Feld doppelt vorkommt, dann von SetLength freigegeben würde und somit das vorletzte (nun letzte) Feld auf nicht mehr existierende Daten zeigen könnte.

[mleyen]

SetLength gibt Sachen frei? Wär mir neu