FOR-Schleifen Problem

[delphinub23]

Danke für eure Hilfe! Ich probiere es mal mit dem Boolean-Array.

[Aphton]

Ich habe einen einfacheren und leichter nachvollziehbaren Vorschlag für dich:
Zuerst - du benutzt Random(16) - dh es wird ein Zufallswert zwischen 0 und 15 zurückgeliefert. Nennen wir diese Zahl X um alles variabel zu halten. (X=16)
Übrigens muss X >= Länge von rZahl sein, damit keine Zahl doppelt vorkommt! (dh es müssen genug Zahlen vorhanden sein)

- Erstelle ein dynamisches Array der Länge X
- Fülle diese mit den Indexwerten (Also DynArr[0] := 0; DynArr[1] := 1, ..)
- Gehe alle Elemente von rZahl durch (i)
- ermittle ein Zufallsindexwert j := Random(Length(DynArr))
- führe folgende Zuweisung durch: rZahl[i] := DynArr[j]
- Lösche Element j aus DynArr

[guinnes]

Das macht aber nur dann Sinn, wenn du x Zahlen aus y Möglichkeiten ziehen willst. Willst du jede Zahl einmal haben, ist der Vorschlag mit der Liste natürlich besser

[Aphton]

Wenn x = y dann hast du denselben Effekt!
Edit: Und in seinem Fall entspricht X (16) der Länge des Array rZahl (0..15 = 16)

[Sir Rufo]

Ist natürlich nicht wirklich performant.
So eine Zufallszahlen-Liste ist schneller mit einer zufälligen Sortierung erreicht.

Aber hier mal dein Ansatz komplettiert:

Delphi-Quellcode:

var
  rZahl :   array [0 .. 15] of Integer;
  temp, i : Integer;
  Unique :  Boolean;
  j :       Integer;
begin
  // Erste Zufalls-Zahl setzen (die ist per Definition auch einzigartig im Array)
  rZahl[ low( rZahl )] := Random( 16 );

  // Wir Starten mit dem 2. Array-Eintrag
  i := low( rZahl ) + 1;

  while i <= high( rZahl ) do
    begin

      repeat

        // Unique-Flag
        Unique := True;
        // Neue Zufallszahl ermitteln
        temp := Random( 16 );
        // mit allen bisherigen Zufallszahlen vergleichen
        for j := low( rZahl ) to i - 1 do
          // Wenn es die schon gibt, dann ...
          if rZahl[j] = temp
          then
            begin
              // ... ist die also nicht mehr einzigartig
              Unique := False;
              // und wir können diese For-Schleife auch schon verlassen
              Break;
            end;

        // solange wiederholen, bis wir eine einzigartige Zufallszahl erhalten haben
      until Unique;

      // Zufalls-Zahl dem Array zuweisen
      rZahl[i] := temp;

      // Ausgabe der Zahl
      txtRandoms.Text := txtRandoms.Text + IntToStr(rZahl[i]) + '; ';

      // und zum nächsten Array-Eintrag hüpfen :-)
      inc( i );
    end;
end;

[Aphton]

Da wir schon Snippets posten

Delphi-Quellcode:

var
  rZahl: Array[0..15] of Integer;
  i, j, k: Integer;
  a: Array of Integer;
begin
  SetLength(a, Length(rZahl));
  for i := 0 to High(a) do
    a[i] := i;
  k := Length(a);
  for i := 0 to High(rZahl) do
  begin
    j := Random(k);
    rZahl[i] := a[j];
    a[j] := a[k-1];
    dec( k );
    txtRandoms.Text := txtRandoms.Text + IntToStr( rZahl[i] ) + '; ';
  end;
end;

[rollstuhlfahrer]

Da finde ich die Listen-Variante doch besser, weil bei dieser (#15) Variante hier der Computer vor allem bei den letzten Feldern überproportional lange braucht (wirkt sich zwar erst bei viel viel mehr Zahlen aus, aber egal). Ein weiterer Punkt, der für die Listenvariante spricht ist, dass das Sortieren per Quicksort geschieht (also wunderbar schnell) und das Auftreten eventueller Fehler im Quelltext ist viel unwahrscheinlicher. Außerdem kann man bei einer Liste auch genau bestimmen, welche Elemente man haben will und welche nicht.

Bernhard

ADD: Dann auch ein Snippet von mir:

Delphi-Quellcode:

type
  TDasArray = array[0..15] of integer;

function Zufallsarray(): TDasArray;
  function RandomSort(Item1, Item2: Pointer): Integer;
  var
    DummyArray: array[0..1] of Integer; // Wird benötigt, da Delphi sonst nicht zurechtkommt (doppeldeutiger Funktionsaufruf)
  begin
    DummyArray := [-1, 1]; // Hoffe das geht so ;)
    Result := RandomFrom(DummyArray);
  end;

var
  Liste: TList;
  i: INteger;
begin
  Liste := TList.Create;
  try
    try
      // Füllen:
      for i := 0 to 15 do
        Liste.Add(Pointer(i+1));

      // "Sortieren"
      Liste.Sort(RandomSort);

      // Jetzt noch das Array füllen
      for i := 0 to 15 do
        Result[i] := Integer(Liste[i]);

    except
      on E: Exception do
      begin
        // Irgendwo ein Fehler passiert? - 0-Array zurückgeben
        ZeroMemory(@Result, SizeOf(Result));
        raise E; // Exception nach oben weiter geben (benötigt??)
      end;
    end;
  finally
    // Ganz wichtig: Nachher aufräumen!
    Liste.Free;
  end;
end;

Das ist jetzt auch mit Speicherschutzblöcken hoffentlich 100% korrekt.

[Aphton]

Erzeugt das Benutzen von Listen nicht mehr Overhead als ein dynamisches Array zu erstellen (siehe #16)?
Listen sind unnötig! Dessen Sortierung braucht man auch nicht!

[delphinub23]

Danke für alle Posts! Mir persönlich gefällt die Variante von Sir Rufo am besten.

[Aphton]

Diese Variante ist aber recht unperformant.
Mag dennoch verständlicher sein, als meine Variante!