JWSCL: Prozess von Dienst starten im Benutzerkontext

[Zacherl]

Zitat von Luckie:

Falsche Beutzerordner, falscher Registry Hive, falsche Benutzerrechte, ... Eben alles was dir mit einem falschen Benutzer passiert.

Okay dann muss ich auf jeden Fall eine andere Lösung finden. Irgendwie muss es ja schließlich möglich sein den Prozess zwar UAC elevated aber im richtigen Benutzerkontext zu starten.

[rollstuhlfahrer]

Also die angegebenen Funktionen bringen bei mir eine Anwendung zu Tage, die (WinXP) als Administrator (bin ich) läuft aus einem Dienst, der eindeutig unter System läuft. Außerdem stimmt bei mir auch der Environment-Block (Dienst schreibt den nämlich richtig in eine Log-Datei). Den Reg-Hive hab ich noch nicht getestet, aber da das auch unter Win7 läuft, denke ich mal, dass mein Code funktioniert hat.

Zitat von Zacherl:

Irgendwie muss es ja schließlich möglich sein den Prozess zwar UAC elevated aber im richtigen Benutzerkontext zu starten.

Das sollte das schwerere sein. Hat die Anwendung das richtige Manifest?


Bernhard

[Zacherl]

Bei mir unter Win 7 64 Bit ist sowohl der Service als auch der neue Prozess unter SYSTEM im Taskmanager angezeigt. Der Child Prozess gibt SYSTEM auch bei GetUserName() zurück. Das Benutzerverzeichnis wird korrekt verwendet, der Registry Hive ist allerdings komplett falsch gesetzt, also unbrauchbar für mich.

Das ganze soll ohne Manifest und ohne Dialog ablaufen.

Ich habe gelesen, dass ein normales Token ab Vista immer ein LinkedToken besitzt. Wenn man dieses an CreateProcessAsUser() übergibt, SOLLTE der Prozess elevated gestartet werden. Das Problem ist nur, dass folgender Code:

Delphi-Quellcode:

Result := WTSQueryUserToken(WTSGetActiveConsoleSessionId, hUserToken);
  if (not Result) then Exit;
  Result := GetTokenInformation(hUserToken, TokenLinkedToken, @hLinkedToken,
    SizeOf(hLinkedToken), ReturnLength);

jedes Mal mit FehlerCode 1312 "A specified logon session does not exist. It may already have been terminated." abbricht. Eventuell liegt es daran, dass ich die UAC deaktiviert habe? Ich teste das gleich mal auf ner VM. Bin für weitere Vorschläge dankbar!

[rollstuhlfahrer]

Leider kann ich das Problem nicht nachvollziehen. Alle Programme, die MEIN Dienst startet, sagen mir auch, dass sie unter dem aktuellen Benutzernamen laufen (höhere Rechte hab ich jetzt nicht geprüft).
Hast du vielleicht einen Fehler in deinem Code? - Hat CreateProcessAsUser das UNICODE-Flag? - Dump mal den Environment-Block. Steht da wenigstens alles richtig drin?

Bernhard

PS: Mit aktueller Benutzername ist auch gemeint, dass sowohl ProcessExplorer, TaskManager als auch GetUserName() das gleiche Ergebnis liefern.

[Zacherl]

Fuuuuu Ich hätts wissen müssen. Das Ermitteln des LinkedTokens schlägt nur deshalb fehl, weil ich die UAC aus habe. Trotzdem vielen Dank an den aussagekräftigen Fehlercode Windows

Ich poste gleich mal einen funktionierenden Code mit ordentlicher Überprüfung:
http://www.delphipraxis.net/160355-s...xt-starten.htm

[rollstuhlfahrer]

Zitat von Zacherl:

... weil ich die UAC aus habe.

Schäme dich dafür. ^^

Bernhard

[Zacherl]

Habe aus Spaß an der Freude noch ein kleines Workaround verfasst, wenn man seinen Prozess wirklich mit SYSTEM Rechten laufen lassen will (Sinn sei dahingestellt), aber trotzdem Aktionen im Benutzerkontext durchführen will. Ist vielleicht ganz nützlich, wenn man ein eigentlich fertiges Programm vom Service aus starten will. Statt alles umzuschreiben, kann man dann einfach einmalig am Start die Funktion ImpersonateProcess() aufrufen. Der Hook sorgt dann von selbst dafür, dass sämtliche Threads direkt beim Start impersoniert werden. Zusätzlich wird mit RegOverwritePredefKey der HKEY_CURRENT_USER Key gradegebogen. Benutzerprofilpfade, etc. dürften dank des angepassten Environments nicht verfälscht werden.

Delphi-Quellcode:

function QueryTokenSID(hToken: THandle): String;
var
  ConvertSidToStringSidW: function(Sid: PSID;
    var StringSid: PWideChar): BOOL; stdcall;
var
  Buffer: PTokenUser;
  ReturnLength: DWord;
  StringSid: PWideChar;
begin
  Result := '';
  @ConvertSidToStringSidW := GetProcAddress(LoadLibrary('advapi32.dll'),
    'ConvertSidToStringSidW');
  if (not Assigned(ConvertSidToStringSidW)) then Exit;
  if (not GetTokenInformation(hToken, TokenUser, nil, 0, ReturnLength))
    and (GetLastError <> ERROR_INSUFFICIENT_BUFFER) then Exit;
  GetMem(Buffer, ReturnLength);
  try
    if (not GetTokenInformation(hToken, TokenUser, Buffer, ReturnLength,
      ReturnLength)) then Exit;
    if ConvertSidToStringSidW(Buffer^.User.Sid, StringSid) then
    try
      Result := StringSid;
    finally
      LocalFree(Cardinal(StringSid));
    end;
  finally
    FreeMem(Buffer);
  end;
end;

function ImpersonateThread(hToken: THandle): Boolean;
var
  hNewHKey: HKEY;
begin
  Result := false;
  if (not ImpersonateLoggedOnUser(hToken)) then Exit;
  if (RegOpenKeyEx(HKEY_USERS, PChar(QueryTokenSID(hToken)), 0,
    KEY_ALL_ACCESS, hNewHKey) = ERROR_SUCCESS) then
  try
    Result := RegOverridePredefKey(HKEY_CURRENT_USER, hNewHKey) =
      ERROR_SUCCESS;
  finally
    RegCloseKey(hNewHKey);
  end;
end;

type
  PThreadParam = ^TThreadParam;
  TThreadParam = packed record
    UserToken: THandle;
    Thread: Pointer;
    Param: Pointer;
  end;
  TThreadFunction = function(lpParam: Pointer): DWord; stdcall;

var
  UserToken: THandle;

var
  O_CreateThread: function(lpThreadAttributes: Pointer;
    dwStackSize: DWORD; lpStartAddress: TFNThreadStartRoutine;
    lpParameter: Pointer; dwCreationFlags: DWORD;
    var lpThreadId: DWORD): THandle; stdcall = nil;

function C_CreateThread(lpThreadAttributes: Pointer;
  dwStackSize: DWORD; lpStartAddress: TFNThreadStartRoutine;
  lpParameter: Pointer; dwCreationFlags: DWORD;
  var lpThreadId: DWORD): THandle; stdcall;

function LocalThread(lpParam: PThreadParam): DWord; stdcall;
begin
  ImpersonateThread(lpParam^.UserToken);
  Result := TThreadFunction(lpParam^.Thread)(lpParam^.Param);
  Dispose(lpParam);
end;

var
  ThreadParam: PThreadParam;
begin
  New(ThreadParam);
  ThreadParam^.UserToken := UserToken;
  ThreadParam^.Thread := lpStartAddress;
  ThreadParam^.Param := lpParameter;
  Result := O_CreateThread(lpThreadAttributes, dwStackSize, @LocalThread,
    ThreadParam, dwCreationFlags, lpThreadId);
end;

function ImpersonateProcess(hToken: THandle): Boolean;
begin
  Result := false;
  if (not Assigned(O_CreateThread)) then
  begin
    UserToken := hToken;
    Result := ImpersonateThread(hToken) and
      InstallInlineHook(GetProcAddress(LoadLibrary('kernel32.dll'),
      'CreateThread'), @C_CreateThread, @O_CreateThread);
  end;
end;

Möglicher Aufruf wäre beispielsweise (ohne Win2000 Kompatibilität):

Delphi-Quellcode:

var
  WTSGetActiveConsoleSessionId: function: DWord; stdcall;
  WTSQueryUserToken: function(SessionId: ULONG;
    var phToken: THandle): BOOL; stdcall;
var
  hToken: THandle;
begin
  @WTSGetActiveConsoleSessionId :=
    GetProcAddress(LoadLibrary('kernel32.dll'), 'WTSGetActiveConsoleSessionId');
  @WTSQueryUserToken :=
    GetProcAddress(LoadLibrary('wtsapi32.dll'), 'WTSQueryUserToken');
  if (not Assigned(WTSGetActiveConsoleSessionId)) or 
    (not Assigned(WTSQueryUserToken)) then Exit;

  if not WTSQueryUserToken(WTSGetActiveConsoleSessionId, hToken) then
    RaiseLastOSError;

  ImpersonateProcess(hToken);
end;