AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Delphi-PRAXiS - Lounge Klatsch und Tratsch Shutdown nach Ende der Programmausführung

Shutdown nach Ende der Programmausführung

Ein Thema von mschaefer · begonnen am 5. Jul 2011 · letzter Beitrag vom 5. Jul 2011
Antwort Antwort
Benutzerbild von mschaefer
mschaefer

Registriert seit: 4. Feb 2003
Ort: Hannover
1.999 Beiträge
 
Delphi XE3 Enterprise
 
#1

Shutdown nach Ende der Programmausführung

  Alt 5. Jul 2011, 13:34
Vieleicht gibt es etwas fertiges: Suche ein Tool das einen Rechner nach einer gewissen Zeit herunterfährt, wenn Virtualbox beendet wurde, also das Gastsystem heruntergefahren ist. Hat da jemand eine Idee?
Martin Schaefer
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
26.824 Beiträge
 
Delphi 10.3 Rio
 
#2

AW: Shutdown nach Ende der Programmausführung

  Alt 5. Jul 2011, 13:37
Ginge das nicht per Batch-Datei?
Code:
start /wait VirtualBox (Parameter)
shutdown /s
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.232 Beiträge
 
Delphi 2006 Professional
 
#3

AW: Shutdown nach Ende der Programmausführung

  Alt 5. Jul 2011, 13:42
Das funktioniert aber nur als Administrator. Mit eingeschränkten Benutzerrechten hat man nicht die Möglichkeit shutdown.exe auszuführen.

Aber ein Konsolenprogramm welches den Rechner runterfährt mittels ExitWindowsEx ist ja schnell geschrieben.
Michael
Ein Teil meines Codes würde euch verunsichern.

Geändert von Luckie ( 5. Jul 2011 um 13:47 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von mschaefer
mschaefer

Registriert seit: 4. Feb 2003
Ort: Hannover
1.999 Beiträge
 
Delphi XE3 Enterprise
 
#4

AW: Shutdown nach Ende der Programmausführung

  Alt 5. Jul 2011, 13:48
Sag mal, das gilt aber dann auch für ein Delphiprogramm, das den Shutdown ausführen soll ?
Martin Schaefer
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.232 Beiträge
 
Delphi 2006 Professional
 
#5

AW: Shutdown nach Ende der Programmausführung

  Alt 5. Jul 2011, 13:51
Wenn es die Shutdown.exe aufruft und auch mit eingeschränkten Benutzerrechten gestartet wurde dann ja. Aber eine Lösung habe ich dir ja genannt.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von mleyen
mleyen

Registriert seit: 10. Aug 2007
609 Beiträge
 
FreePascal / Lazarus
 
#6

AW: Shutdown nach Ende der Programmausführung

  Alt 5. Jul 2011, 14:20
Hab da auch noch was, einfach den Prozessnamen oder die PID als Parameter übergeben:

Delphi-Quellcode:
program ShutDownOnProcessClosed;

uses
  Windows, TlHelp32;

function ShutdownWindows: Boolean;
const
  cSE_SHUTDOWN_NAME = 'SeShutdownPrivilege';
var
  OSVersionInfo: TOSVersionInfo;
  hToken: THandle;
  hProcess: THandle;
  TokenPriv: TTokenPrivileges;
  ReturnLength: DWORD;
begin
  Result := False;
  OSVersionInfo.dwOSVersionInfoSize := SizeOf (OSVersionInfo);
  if not GetVersionEx(OSVersionInfo) then
    Exit;
  if OSVersionInfo.dwPlatformId = VER_PLATFORM_WIN32_NT then
  begin
    hProcess := GetCurrentProcess;
    if not OpenProcessToken (hProcess, TOKEN_ADJUST_PRIVILEGES, hToken) then
      Exit;
    if not LookupPrivilegeValue (nil, cSE_SHUTDOWN_NAME, TokenPriv.Privileges[0].Luid) then
      Exit;
    TokenPriv.PrivilegeCount := 1;
    TokenPriv.Privileges [0].Attributes := SE_PRIVILEGE_ENABLED;
    if not AdjustTokenPrivileges (
        hToken, False, TokenPriv, 0, PTokenPrivileges (nil)^, ReturnLength)
    then
      Exit;
    CloseHandle (hToken);
  end;
  Result := ExitWindowsEx(EWX_SHUTDOWN or EWX_POWEROFF, $FFFFFFFF);
end;

function LowerCase(const Value: string): string;
var
  Ch : Char;
  L : Integer;
  Source: PChar;
  Dest : PChar;
begin
  L := Length(Value);
  SetLength(Result, L);
  Source := Pointer(Value);
  Dest := Pointer(Result);
  while L <> 0 do
  begin
    Ch := Source^;
    if (Ch >= 'A') and (Ch <= 'Z') then
      Inc(Ch, 32);
    Dest^ := Ch;
    Inc(Source);
    Inc(Dest);
    Dec(L);
  end;
end;

function getProcessID(const Exename: string): Cardinal;
var
  hProcSnap: THandle;
  ProcEntry: TProcessEntry32;
begin
  Result := 0;
  hProcSnap := CreateToolHelp32SnapShot(TH32CS_SNAPPROCESS, 0);
  if hProcSnap <> INVALID_HANDLE_VALUE then
  begin
    ProcEntry.dwSize := SizeOf(ProcessEntry32);
    if Process32First(hProcSnap, ProcEntry) = true then
      while Process32Next(hProcSnap, ProcEntry) = true do
        if LowerCase(Exename) = LowerCase(ProcEntry.szExeFile) then
        begin
          Result := ProcEntry.th32ProcessID;
          Break;
        end;
    CloseHandle(hProcSnap);
  end;
end;

function ProcessExist(const PID: Cardinal): Boolean;
var
  ContinueLoop: BOOL;
  FSnapshotHandle: THandle;
  FProcessEntry32: TProcessEntry32;
begin
  FSnapshotHandle := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  FProcessEntry32.dwSize := SizeOf(FProcessEntry32);
  ContinueLoop := Process32First(FSnapshotHandle, FProcessEntry32);
  Result := False;
  while Integer(ContinueLoop) <> 0 do
  begin
    if FProcessEntry32.th32ProcessID = PID then
    begin
      Result := True;
      Break;
    end;
    ContinueLoop := Process32Next(FSnapshotHandle, FProcessEntry32);
  end;
  CloseHandle(FSnapshotHandle);
end;

function CharToUInt(const AChar: Char): Cardinal; {$IFDEF Inln}inline;{$ENDIF}
begin
  Result := Ord(AChar)-ord('0');
end;

function TryCharToUInt(const AChar: Char; out AInt: Cardinal): Boolean; {$IFDEF Inln}inline;{$ENDIF}
begin
  AInt := CharToUInt(AChar);
  Result := AInt <= 9;
end;

function TryStrToUInt(const AStr: string; out AUInt: Cardinal): Boolean; {$IFDEF Inln}inline;{$ENDIF}
var
  i, tmp: Cardinal;
begin
  for i := 1 to Length(AStr) do
  begin
    if TryCharToUInt(AStr[i], tmp) then
      AUInt := AUInt * 10 + tmp
    else
    begin
      Result := false;
      Exit;
    end;
  end;
  Result := AStr <> '';
end;

var
  PID: Cardinal;
begin
  if ParamCount <> 1 then
    Exit;

  if not TryStrToUInt(ParamStr(1), PID) then
    PID := getProcessID(ParamStr(1));

  if PID <> 0 then
    while ProcessExist(PID) do
      Sleep(100);

  ShutdownWindows;
end.
Angehängte Dateien
Dateityp: zip ShutDownOnProcessClosed.zip (10,2 KB, 3x aufgerufen)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 12:24 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf