Public-Variable exportieren und im Formular-FormCreate verwenden

[WM_CLOSE]

Wie wäre es so:

Delphi-Quellcode:

...
public
constructor Create(aOwner:TComponent; Ueberschrift:Byte);overload;
...

[FredlFesl]

Mach aus der Variable eine Eigenschaft und setze im Setter die Überschrift. Dann ist es egal, wann Du 'KompaktTyp' setzt.

Delphi-Quellcode:

Type
  TMyForm = Class (TForm)
  ...
    Property KompaktTyp : Byte Read fKompaktTyp Write SetKompaktTyp;
  End;

...

Procedure TMyForm.SetKompaktTyp (Value : Byte);
Begin
  If Value <> fKompaktTyp then begin
    fKompaktTyp := Value;
    Caption := KompaktTypFormUeberschrift[fKompaktTyp] // <<--- hier noch die Überschrift setzen
  End
End;

[EWeiss]

OT:
Kapiere nicht warum ihr für Getter immer 'f' anstelle von 'Get' für die Namensgebung wählt.
Irgendwie unlogisch.

gruss

[Ralf Kaiser]

Zitat von EWeiss:

OT:
Kapiere nicht warum ihr für Getter immer 'f' anstelle von 'Get' für die Namensgebung wählt.
Irgendwie unlogisch.

Wenn ein "F" vorangestellt ist bezieht sich das auf die Feldvariable.

Das "Get..." bezieht sich immer auf eine Funktion die als Rückgabewert den Wert des entsprechenden Feldes hat (oder auch nicht, der Wert kann bei einer Getter-Methode auch woanders herkommen)

[EWeiss]

Zitat:

Das "Get..." bezieht sich immer auf eine Funktion die als Rückgabewert den Wert des entsprechenden Feldes hat

So mache ich es ja.. deshalb war es mir unverständlich

In dem Fall hätte man dann auch anstelle von Set ebenfalls 'f' nehmen können.
Na ja war nur mal Interesse halber von mir angestoßen.

gruss

[fkerber]

Hi,

ich glaube, da liegt ein Missverständnis vor.

In dem Beispiel oben gibt es keine Getter-Funktion, sondern es wird direkt auf das Feld verwiesen (das dann eben mit f für Feld anfängt).
Da aber im Setter noch "Magie" passieren soll, wurde eine separate Funktion angelegt (bzw. eine Prozedur) und diese dann korrekt mit setXXX benannt.


LG, Frederic

[FredlFesl]

@fkerber: So isses, hätte das Codebeispiel wohl vollständig abgeben sollen. Nun gut, hier vollständig und etwas gepimpt:

Delphi-Quellcode:

Type
  TKompaktFormularUeberschrift = (kfuUndefiniert, kfuTyp1, kfuTyp2);

  TMyForm = Class (TForm)
  private
    fKompaktTyp : TKompaktFormularUeberschrift;
    Procedure SetKompaktTyp (Value : TKompaktFormularUeberschrift);
  public
    Property KompaktTyp : TKompaktFormularUeberschrift Read fKompaktTyp Write SetKompaktTyp;
  End;

Const
  KompaktTypFormUeberschrift : Array [TKompaktFormularUeberschrift] Of String = (
    'undefiniert',
    'Kompaakte Darstellung-Version 1',
    'Kompaakte Darstellung-Version 2'
    );
...
Procedure TMyForm.SetKompaktTyp (Value : TKompaktFormularUeberschrift);
Begin
  If Value <> fKompaktTyp then begin
    fKompaktTyp := Value;
    Caption := KompaktTypFormUeberschrift[fKompaktTyp]
  End
End;

Der Präfix 'f' des Feldnamens ist entsprechend der 'Standard'-Delphi Konvention für Nomenklaturen, analog zum Präfix 'T' für Typen, 'I' für Interfaces und 'E' für Exceptions... Gibt's noch mehr? Ach ja, vielleicht 'A' für Parameter (in welcher Sprache fängt 'Parameter' mit 'A' an?)