AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Pointer aus SendMessage nicht dereferenzierbar?

Ein Thema von erik-17 · begonnen am 30. Aug 2011 · letzter Beitrag vom 31. Aug 2011
Antwort Antwort
erik-17

Registriert seit: 8. Apr 2010
51 Beiträge
 
Delphi 3 Professional
 
#1

Pointer aus SendMessage nicht dereferenzierbar?

  Alt 30. Aug 2011, 21:03
Delphi-Version: 5
Guten Abend

Ich versuche momentan einen Pointer, der auf einen Record zeigt, mithilfe von SendMessage/PostMessagen von einem Thread an die Main-Unit zu senden. Getestet ist es noch nicht, weil der Thread noch nicht vernünftig mit der Main-Unit läuft (bin da noch am programmieren). Wenn ich jetzt die Ereignisbearbeitungs-Methode (für die Message) schreiben will, dann möchte ich den Pointer ja dereferenzieren, damit ich an die Werte des Records rankomme.
Der Compiler spuckt mir immer Fehler aus...:

Delphi-Quellcode:
//Mein Record: (Sowohl im Thread als auch im Main bekannt)
TimeBinar = record
         Stunden : array[1..5] of boolean;
         Minuten : array[1..6] of boolean;
         Sekunden : array[1..6] of boolean;
end;

//Das Senden...
PostMessage(Form1.Handle,WM_TIME_ANNOUNCING,1,Integer(@PTimeBinar));
PostMessage(Form1.Handle,WM_TIME_ANNOUNCING,1,Integer(PTimeBinar)); //ohne "@" -> "Ungültige Typumwandlung"

//... und das Empfangen:
procedure TForm1.OnTimeAnnounce(var Msg: TMessage);
var p : TimeBinar;
begin
case Msg.WParam of
1 : begin
         p := TimeBinar(Msg.LParam^); //Zeigertyp erwartet
         p := TimeBinar(Msg.LParam); //Ungültige Typumwandlung
         p := Msg.LParam^; //Zeigertyp erwartet
         p := Msg.LParam; //Inkompatible Typen "TimeBinar" und "Integer"
...
Mach ich das soweit erstmal richtig (bin auf dem Gebiet noch Anfänger) oder muss man das ganz anders machen? Und wie komm ich schlussendlich an das Record ran?

Danke im voraus und guten Abend noch
  Mit Zitat antworten Zitat
Benutzerbild von Aphton
Aphton

Registriert seit: 31. Mai 2009
1.198 Beiträge
 
Turbo Delphi für Win32
 
#2

AW: Pointer aus SendMessage nicht dereferenzierbar?

  Alt 30. Aug 2011, 21:17
Delphi-Quellcode:
PTimeBinar = ^TTimeBinar;
TTimeBinar = record
  Stunden : array[1..5] of boolean;
  Minuten : array[1..6] of boolean;
  Sekunden : array[1..6] of boolean;
end;

PostMessage(Form1.Handle,WM_TIME_ANNOUNCING,1,Integer(@PTimeBinar));

procedure TForm1.OnTimeAnnounce(var Msg: TMessage);
var
  p : TTimeBinar;
begin
case Msg.WParam of
  1:
  begin
    p := PTimeBinar(Msg.LParam)^;
  end;
{..}

PTimeBinar(Msg.LParam)^ =
Interpretiere Msg.LParam als PTimeBinar - bei diesem Typ handelt es sich um nen Pointer, weswegen auch folgender Schritt möglich ist - und dereferenziere diesen nach p (heißt kopiere den Inhalt des Pointers in die lokale, nichtsaussagende Variable p)

Falls du keine Berechnungen damit durchführen musst bzw. wenn die Änderung auch die echten Daten betreffen darf, wäre es besser, direkt mit Pointern zu arbeiten - sprich du machst folgendes:
Delphi-Quellcode:
var
  p : PTimeBinar;
{..}
  p := PTimeBinar(Msg.LParam);
EDITH:
Übrigens, in Delphi gibts die Konvention, Typendeklarationen mit T zu beginnen wie korrigierterweise TTimeBinar.
Dasselbe gilt auch für Pointer zu den definierten Typen, die..
mit P wie in PTimeBinar begonnen werden und
direkt über die Typendeklaration ihren Platz zu suchen haben...

Warum ich dir das klar mache.. nun
  PostMessage(Form1.Handle,WM_TIME_ANNOUNCING,1,Integer(PTimeBinar)); Ne Variable, die nen Typnamen hat ("PTimeBinar"), ist verwirrend und irritierend =P

Edith, die Zweite; Potenzieller Bug:
Verwende keine Pointer auf lokale Variablen, da zur Laufzeit diese immer wieder überschrieben werden können (zB. durch ständiges aufrufen derselben Methode, wo sich die Daten, auf die gepointet wird, befinden)!
das Erkennen beginnt, wenn der Erkennende vom zu Erkennenden Abstand nimmt
MfG

Geändert von Aphton (30. Aug 2011 um 21:30 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#3

AW: Pointer aus SendMessage nicht dereferenzierbar?

  Alt 30. Aug 2011, 21:28
Delphi-Quellcode:
type
  TMyRecord = record
    MyInt: Integer;
    MyShortString: ShortString;
  end;
  PMyRecord = ^TMyRecord;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    MyRecord: PMyRecord;
  public
    { Public declarations }
    procedure WndProc(var Message: TMessage); override;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

const
  WM_PUFF = WM_USER + 1;

procedure TForm1.Button1Click(Sender: TObject);
begin
  MyRecord := new(PMyRecord);
  MyRecord.MyInt := 42;
  MyRecord.MyShortString := 'Keine Panik.';
  SendMessage(Form1.Handle, WM_PUFF, 0, Integer(MyRecord)); // Kein @. MyRecord ist schon ein Pointer.
end;

procedure TForm1.WndProc(var Message: TMessage);
var
  MyInt: Integer;
  MyShortString: ShortString;
begin
  inherited;
  case Message.Msg of
    WM_PUFF: begin
        MyInt := PMyRecord(Message.LParam).MyInt;
        MyShortString := PMyRecord(Message.LParam).MyShortString;
        ShowMessage(IntToStr(MyInt) + ' ' + MyShortString);
        Dispose(MyRecord);
      end;
  end;
end;
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.011 Beiträge
 
Delphi 12 Athens
 
#4

AW: Pointer aus SendMessage nicht dereferenzierbar?

  Alt 30. Aug 2011, 21:33
Und statt Integer(MyRecord) besser LPARAM(MyRecord) verwenden.
(Ja, es gibt für den Parameter lParam einen gleichnamigen Typen LPARAM )



Ich wisst doch, daß irgendwer auf die saublöde Idee kam den Integer nicht mit auf 64 Bit anwachsen zu lassen.



PS:
Integer(@PTimeBinar) ist ein Zeiger auf den Typen,
also kann man das nicht zu einer Variable dereverentieren, sondern nur wieder zu einem Typen.

Oder wie unbd wo ist PTimeBinar deklariert?

PSS:
PostMessage, bzw. das auszuführende Ereignis wird nicht sofort ausgeführt, sondern nur an die MessageQueue angehängt.
Wenn man nun den Zeiger auf eine lokale Variable übergibt, dann knallt es natürlich, wenn diese Variable inzischen freigeben ist, da die Prozedur beendet wurde.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests

Geändert von himitsu (30. Aug 2011 um 21:41 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Aphton
Aphton

Registriert seit: 31. Mai 2009
1.198 Beiträge
 
Turbo Delphi für Win32
 
#5

AW: Pointer aus SendMessage nicht dereferenzierbar?

  Alt 30. Aug 2011, 21:37
Zitat:
Ich wisst, doch, daß irgendwer auf die saublöde Idee kam den Integer nicht mit auf 64 Bit anwachsen zu lassen.
Ach, echt? Ironie?
Ich dachte immer, Integer sei ein generischer Typ und würde somit auch "mitwachsen"..
Falls Ironie - ist LPARAM nicht als Integer definiert? =P
das Erkennen beginnt, wenn der Erkennende vom zu Erkennenden Abstand nimmt
MfG
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#6

AW: Pointer aus SendMessage nicht dereferenzierbar?

  Alt 30. Aug 2011, 21:40
LPARAM ist als LongInt definiert.
LPARAM = Longint;
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.011 Beiträge
 
Delphi 12 Athens
 
#7

AW: Pointer aus SendMessage nicht dereferenzierbar?

  Alt 30. Aug 2011, 21:43
jupp, war früher mal so (LongInt).

Nun in D2010 ist es so
Delphi-Quellcode:
INT_PTR = Integer;
LPARAM = INT_PTR;
Und ich hoffe mal, Emba ist so schlau das INT_PTR auf 64 Bit anzupassen, wenn man für 64 bit kompiliert.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#8

AW: Pointer aus SendMessage nicht dereferenzierbar?

  Alt 30. Aug 2011, 21:47
Ok, war noch Delphi 7 (startet schneller als mein D2006 ).
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
erik-17

Registriert seit: 8. Apr 2010
51 Beiträge
 
Delphi 3 Professional
 
#9

AW: Pointer aus SendMessage nicht dereferenzierbar?

  Alt 31. Aug 2011, 18:19
Ok, danke für eure Antworten

Ich habs vorwiegend durch Luckie's Quellcode gelöst.

Die Lösung schaut nun so aus:

Delphi-Quellcode:
type
  PTimeBinar = ^TTimeBinar;
  TTimeBinar = record
         Stunden : array[1..5] of boolean;
         Minuten : array[1..6] of boolean;
         Sekunden : array[1..6] of boolean;
  end;

  TTimeThread = class(TThread)

  private
     TimeBinar : PTimeBinar;
  protected
    procedure Execute; override;
  end;

implementation
uses Unit1;

procedure TTimeThread.Execute;
begin
     TimeBinar := new(PTimeBinar);
     [...]
          SendMessage(Form1.Handle,WM_TIME_ANNOUNCING,0,LPARAM(TimeBinar));
end;

/// Quellcode der MainUnit:

procedure TForm1.OnTimeAnnounce(var Msg: TMessage);
var p : PTimeBinar;
begin
case Msg.WParam of
0 : begin
         p := PTimeBinar(Msg.LParam);
         TueEtwas(p);
    end;
Um das ganze Problem mal allgemein zu beschreiben: Ich will mir eine binäre Uhr bauen. Dazu lass ich einen Thread dauerhaft laufen, der mir die Zeit in die Binärfaktoren zerlegt und danach 100ms pausiert. Um dann nicht ständig mit einem Timer von der MainUnit aus die Werte auszulesen, sende ich aus dem Thread nach erfolgreicher Zerlegung die Message mit dem Pointer. Ist meiner Meinung nach viel eleganter
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 10:18 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz