AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Pattern: Visitor

Ein Thema von implementation · begonnen am 18. Okt 2011 · letzter Beitrag vom 19. Okt 2011
Antwort Antwort
Seite 1 von 4  1 23     Letzte » 
Benutzerbild von implementation
implementation

Registriert seit: 5. Mai 2008
940 Beiträge
 
FreePascal / Lazarus
 
#1

Pattern: Visitor

  Alt 18. Okt 2011, 17:29
Hallo liebe Forumsgenossen,

so manch einer von euch ist sicherlich schonmal in folgende Situation geraten:

Ihr habt sehr viele Klassen, die alle eine neue gemeinsame Methode bekommen sollen, die sich aber nicht zentral im Vorfahren einfügen lässt (bspw. weil sich jede Unterklasse anders verhalten soll).
Nun könntet ihr die Methode in jeder dieser Klasse einzeln einführen. Dann hättet ihr die Methoden der jeweiligen Klasse immer schön beieinander.
Delphi-Quellcode:
type
  TClass1 = class
    procedure AndereMethode;
    procedure BlubbNochMehr;
    // ...
    procedure TuWasBesonderes;
  end;
  TClass2 = class
    procedure IchKannWas;
    procedure GanzAnderes;
    // ...
    procedure TuWasBesonderes;
  end;

// TClass1
procedure TClass1.AndereMethode;
begin
  MachWas;
  MachNochMehr;
end;
...
procedure TClass1.TuWasBesonderes;
begin
  Writeln('Ich bin Klasse 1');
end;

// TClass2
procedure TClass2.IchKannWas;
begin
  MachIrgendwas;
  GuckBloed;
end;
...
procedure TClass2.TuWasBesonderes;
begin
  Writeln('Ich bin Klasse 2');
end;
Nun könnt ihr im Nachhinein schön jede Klasse an sich überblicken.

Nun mag manchmal aber etwas anderes viel sinnvoller sein:
Wäre es nicht viel schöner, alle TuWasBesonderes() auf einmal an einer zentralen Stelle im Blick zu haben?

Die Viererbande hat sich dazu ein schönes Pattern ausgedacht: Den Visitor.
Delphi-Quellcode:
// Unit A
type
  IVisitor = interface
    procedure Visit(const x: TClass1); overload;
    procedure Visit(const x: TClass2); overload;
  end;
  TClass1 = class
    // viele Methoden...
    procedure TuWasBesonderes(const v: IVisitor);
  end;
  TClass2 = class
    // viele Methoden...
    procedure TuWasBesonderes(const v: IVisitor);
  end;

procedure TClass1.TuWasBesonderes(const v: IVisitor);
begin
  v.Visit(self);
end;

procedure TClass2.TuWasBesonderes(const v: IVisitor);
begin
  v.Visit(self);
end;
Delphi-Quellcode:
// Unit B
uses UnitA;

type
  TVisitorA = class (TInterfacedObject, IVisitor)
    procedure Visit(const x: TClass1); overload;
    procedure Visit(const x: TClass2); overload;
  end;
  TVisitorB = class (TInterfacedObject, IVisitor)
    procedure Visit(const x: TClass1); overload;
    procedure Visit(const x: TClass2); overload;
  end;

procedure TVisitorA.Visit(const x: TClass1);
begin
  Writeln('Visitor A mit Klasse 1');
end;

procedure TVisitorA.Visit(const x: TClass2);
begin
  Writeln('Visitor A mit Klasse 2');
end;

procedure TVisitorB.Visit(const x: TClass1);
begin
  Writeln('Visitor B mit Klasse 1');
end;

procedure TVisitorB.Visit(const x: TClass2);
begin
  Writeln('Visitor B mit Klasse 2');
end;
Und da können wir auch noch mehr Vorteile sehen:
  • Wir können nicht nur einen Visitor schreiben, sondern gleich mehrere! Dadurch hat der Aufrufer von TuWasBesonderes() auch eine bessere Möglichkeit, den Ablauf zu beeinflussen. Neue Visitoren lassen sich schnell dazuergänzen, überlegen Sie mal, wie schnell es nun ginge, noch einen Visitor C hinzuzufügen.
  • Es lassen sich auch schnell neue Klassen ergänzen. Angenommen wir führen nun eine neue Klasse 3 ein, müssen wir sie nur IVisitor.Visit() aufrufen lassen, und sie in den Visitoren ergänzen.
  • Wir können damit die gesamte TuWasBesonderes()-Funktionalität in eine eigene Unit auslagern.

Mfg und in der Hoffnung, geholfen zu haben,
implementation

Kritik ist erwünscht, also scheut euch nicht
  Mit Zitat antworten Zitat
Benutzerbild von stahli
stahli

Registriert seit: 26. Nov 2003
Ort: Halle/Saale
4.336 Beiträge
 
Delphi 11 Alexandria
 
#2

AW: Pattern: Visitor

  Alt 18. Okt 2011, 18:27
Ok vielen Dank für die Vorlage!

Ich habe auch hier schon des öfteren reingesehen und obwohl es deutsch beschrieben ist, wirbelt mein interner Visitor die Inhalte immer wieder durcheinander.
Irgendwie bin ich an der gleichen Stelle wie damals, als ich "objektorientierte Programmierung" verstehen wollte.

Darf ich mal Dein Beispiel gedanklich erweitern?
Deine Klassen haben ein Value als Integer.

Dann will ich zwei Methoden Add und Del, die Value jeweils erhöhen bzw. verringern und den Wert ausgeben. In Klasse 2 analog und plus und minus 2.
Als Methode ist das ja kein Problem. Ich implementiere insgesamt 4 Methoden und fertig.

Wie macht man das mit Visitorn und was ist der Vorteil?

Und was tut man, wenn man eine Methode Change(X: Integer) als Visitor realisieren will, die Value den Parameter hinzuadiert?
Stahli
http://www.StahliSoft.de
---
"Jetzt muss ich seh´n, dass ich kein Denkfehler mach...!?" Dittsche (2004)
  Mit Zitat antworten Zitat
Benutzerbild von s.h.a.r.k
s.h.a.r.k

Registriert seit: 26. Mai 2004
3.159 Beiträge
 
#3

AW: Pattern: Visitor

  Alt 18. Okt 2011, 18:34
Hm, an der Stelle könnte man auch mit class helper weiter kommen. Blöd an diesem Pattern finde ich, dass gewisser Code, den ich logisch in die Klasse gepackt hatte, auf einmal außerhalb befindet. Interessanter wird das Pattern erst, wenn du eine Basisklasse hast, von der n Klassen abgeleitet wurden und nicht alle n Klassen diese ein besondere TuWas() Methode kommen soll. Wobei man an dieser Stelle auch eine abstrakte Ableitung generieren könnte und die entsprechenden Klassen dann von dieser neuen abstrakten Klasse ableiten könnte.
»Remember, the future maintainer is the person you should be writing code for, not the compiler.« (Nick Hodges)
  Mit Zitat antworten Zitat
SebE

Registriert seit: 31. Jul 2004
Ort: Chemnitz
316 Beiträge
 
Delphi 7 Personal
 
#4

AW: Pattern: Visitor

  Alt 18. Okt 2011, 18:45
Eine schöne Verwendung für den Visitor, die mir immer sofort einfällt, wenn ich einen sehe:
Man möchte seine Business-Objekte persistieren (in eine andere Form bringen, um diese ablegen zu können).
Jetzt hat man 20 Objekte, die nicht unterschiedlicher sein könnten und immer den Gendanken im Kopf, dass das Speichern von Objekten nicht Aufgabe der Objekte selbst ist.

Hier legt man sich einen Visitor an, der für das Ablegen jedes einzelnen Objektes verantwortlich ist.
Sebastian
  Mit Zitat antworten Zitat
Benutzerbild von geskill
geskill

Registriert seit: 17. Feb 2007
Ort: NRW
420 Beiträge
 
Delphi 2010 Professional
 
#5

AW: Pattern: Visitor

  Alt 18. Okt 2011, 18:45
@stahli, würde es so machen:
Delphi-Quellcode:
type
  TVisitorAddiere = class (TInterfacedObject, IVisitor)
  private
    FValue: Integer;
  public
    constructor Create(AValue: Integer);
    procedure Visit(const x: TClass1); overload;
    procedure Visit(const x: TClass2); overload;
  end;

//...

constructor TVisitorAddiere.Create(AValue: Integer);
begin
  FValue := AValue;
end;

procedure TVisitorAddiere.Visit(const x: TClass1);
begin
  x.Wert := x.Wert + FValue;
end;

procedure TVisitorAddiere.Visit(const x: TClass2);
begin
  x.Wert := x.Wert + FValue;
end;
Beispielaufruf:
Delphi-Quellcode:
var
  VisitorAddiere: TVisitorAddiere;

begin
  VisitorAddiere := TVisitorAddiere.Create(100); // wenn man 102 addieren will muss man eben neuen VisitorAddiere erstellen mit Parameter 102

  Class1.TuWasBesonderes(VisitorAddiere);

  VisitorAddiere.Free;
end;
Sebastian
  Mit Zitat antworten Zitat
Benutzerbild von stahli
stahli

Registriert seit: 26. Nov 2003
Ort: Halle/Saale
4.336 Beiträge
 
Delphi 11 Alexandria
 
#6

AW: Pattern: Visitor

  Alt 18. Okt 2011, 19:14
@shark
class helper würde ich nur alt "Notlösung" ansehen. Sofern man eigene Klassen definiert sollte man m.E. darauf verzichten.

@SebE
Dafür kann man aber noch einfacher einen Serialisierer (Prozedur oder Klasse) nutzen, dem man die Objekte zum Speichern übergibt. M.E. hätte man damit das selbe Ergebnis.

@geskill
So etwa hatte ich mir das gedacht. Man erzeugt also ein VisitorObjekt (VO), definiert beliebige Eigenschaften, übergibt es dann dem Objekt (O), das dann VO.Visit(O) aufruft, wo Eigenschaften in O und VO geändert werden können. Vor dem anschließenden Freigeben von VO könnte man ggf. dort noch Rückgabewerte auswerten.
Ein sinnvollerer Procedurname als "TuWasBesonderes" könnte dann wohl "Do", "DoVisit" oder "Visit" sein. Oder wie macht Ihr das üblicherweise?

Also verstanden habe ich es jetzt (mutmaßlich ) - jedenfalls die Funktionsweise.

Ob es aber zu einer einfacheren Arbeitsweise beiträgt, da bin ich mir nicht sicher.
O.Add(100); sieht erst mal einfacher aus. Und ob die Methodenauslagerung in andere Units praktisch etwas bringt, müsste man sicher eine Weile testen.
Stahli
http://www.StahliSoft.de
---
"Jetzt muss ich seh´n, dass ich kein Denkfehler mach...!?" Dittsche (2004)
  Mit Zitat antworten Zitat
SebE

Registriert seit: 31. Jul 2004
Ort: Chemnitz
316 Beiträge
 
Delphi 7 Personal
 
#7

AW: Pattern: Visitor

  Alt 18. Okt 2011, 19:23
@stahli:
Was machst du wenn weit und breit keinen "Serialisierer" findest, der dir helfen möchte?
Selbst ist der Mann!

Es sollte nur ein Beispiel sein, welches - in meinen Augen - den Visitor perfekt in seiner Tätigkeit beschreibt.
Dass man Objekte auf 1000 verschiedenen Wegen auf die Platte bekommt, mindert den Wert meines Beispiels in keiner Weise.

Es ist ein Muster. Jeder muss selbst für sich herausfinden, ob und wofür er es verwenden möchte.
Sebastian
  Mit Zitat antworten Zitat
Benutzerbild von implementation
implementation

Registriert seit: 5. Mai 2008
940 Beiträge
 
FreePascal / Lazarus
 
#8

AW: Pattern: Visitor

  Alt 18. Okt 2011, 20:19
Soweit es so gewünscht ist, kann man den Wert ja auch der Methode einfach übergeben:
Delphi-Quellcode:
type
  TKlasse = class;
  IVisitor = interface
    procedure Visit(const x: TKlasse; const v: Integer);
  end;
  TKlasse = class
  protected
    FWert: Integer;
  public
    procedure Add(const vis: IVisitor; const val: Integer);
    property Wert: Integer read FWert write FWert;
  end;
  TVisitor = class(TInterfacedObject, IVisitor)
    procedure Visit(const x: TKlasse; const v: Integer);
  end;

procedure TKlasse.Add(const vis: IVisitor; const val: Integer);
begin
  vis.Visit(self,val);
end;

procedure TVisitor.Visit(const x: TKlasse; const val: Integer);
begin
  x.Wert := x.Wert + val;
end;
  Mit Zitat antworten Zitat
Benutzerbild von implementation
implementation

Registriert seit: 5. Mai 2008
940 Beiträge
 
FreePascal / Lazarus
 
#9

AW: Pattern: Visitor

  Alt 18. Okt 2011, 20:21
Blöd an diesem Pattern finde ich, dass gewisser Code, den ich logisch in die Klasse gepackt hatte, auf einmal außerhalb befindet.
Das kommt natürlich ganz auf die Situation an.
Manchen Code kann man natürlich besser bei der Klasse behalten, aber gar nicht so selten kommt es eben auch vor, dass es einfach übersichtlicher ist, wenn man bestimmte Codestellen auslagert.
  Mit Zitat antworten Zitat
Benutzerbild von implementation
implementation

Registriert seit: 5. Mai 2008
940 Beiträge
 
FreePascal / Lazarus
 
#10

AW: Pattern: Visitor

  Alt 18. Okt 2011, 20:25
Ein sinnvollerer Procedurname als "TuWasBesonderes" könnte dann wohl "Do", "DoVisit" oder "Visit" sein. Oder wie macht Ihr das üblicherweise?
Am sinnvollsten ist es natürlich, sie nach dem zu benennen, was sie machen soll
"Visit" nennt man üblicherweise die Methoden des Visitors. Die Methode in der Klasse, die ich hier "TuWasBesonderes" genannt habe, heißt in der Literatur zumeist "Accept".
In der Praxis gibt man ihr aber lieber einen aussagekräftigeren Namen.
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 15:29 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz