AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

stringgrid speichern

Ein Thema von Hartfrid Krause · begonnen am 8. Nov 2011 · letzter Beitrag vom 8. Nov 2011
Antwort Antwort
Hartfrid Krause

Registriert seit: 20. Feb 2007
90 Beiträge
 
Delphi XE6 Professional
 
#1

stringgrid speichern

  Alt 8. Nov 2011, 14:57
Wie kann ich strings, die in einer stringgrid angezeigt werden als textdatei speichern.
Gibt es eine einfachere Möglichkeit jenseuits von filestreams?
  Mit Zitat antworten Zitat
Benutzerbild von Bummi
Bummi

Registriert seit: 15. Jun 2010
Ort: Augsburg Bayern Süddeutschland
3.470 Beiträge
 
Delphi XE3 Enterprise
 
#2

AW: stringgrid speichern

  Alt 8. Nov 2011, 15:17
nur als Vorschlag, in der Formatierung könntest Du es auch per Copy und Paste in Excel einfügen

Delphi-Quellcode:
Procedure SaveStringGrid(sg:TStringgrid;const fn:String);
const
 C_ZBr=#13#10;
 C_Tab=#9;
var
  Y,X:Integer;
  s:String;
  sl:TStringlist;
 Function GetDelim:String;
  begin
    if x < (sg.Rows[Y].Count - 1) then Result := C_Tab else Result := C_ZBr;
  end;
begin
  for Y := 0 to sg.RowCount -1 do
     begin
     For x := 0 to sg.Rows[Y].Count - 1 do s := s + sg.Rows[Y][X] + GetDelim;
     end;
  sl:=TStringlist.Create;
  try
    sl.Text := s;
    sl.SaveToFile(fn);
  finally
    sl.Free;
  end;
end;


Procedure LoadStringGrid(sg:TStringgrid;const fn:String);
const
 C_ZBr=#13#10;
 C_Tab=#9;
var
  sl:TStringList;
  y,x:Integer;
begin
  sl:=TStringlist.Create;

  try
    sl.LoadFromfile(fn);
    sg.RowCount := sl.Count;
    for y := 0 to sl.Count -1 do
        begin
           sg.Rows[y].Text := StringReplace(sl[y],C_Tab,C_ZBr,[rfReplaceAll]);
        end;
  finally
    sl.Free;
  end;
end;
Thomas Wassermann H₂♂
Das Problem steckt meistens zwischen den Ohren
DRY DRY KISS
H₂ (wenn bei meinen Snipplets nichts anderes angegeben ist Lizenz: WTFPL)

Geändert von Bummi ( 8. Nov 2011 um 15:33 Uhr)
  Mit Zitat antworten Zitat
Steku

Registriert seit: 12. Mai 2008
177 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#3

AW: stringgrid speichern

  Alt 8. Nov 2011, 15:25
Hatte ich mal hier gefunden:

http://www.swissdelphicenter.ch/de/showcode.php?id=941

Gruß,
Steku


Nachtrag: Wenn ich mich recht erinnere, hat das JVCL Stringgrid sogar die Methoden Load/SaveToFile, bzw. Load/SaveToStream
mit an Board...

Geändert von Steku ( 8. Nov 2011 um 15:28 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.463 Beiträge
 
Delphi 11 Alexandria
 
#4

AW: stringgrid speichern

  Alt 8. Nov 2011, 17:00
Das sollte auch funktionieren:
Delphi-Quellcode:
procedure SaveStringGrid(Grid: TStringGrid; Filename: TFilename);
var
  List, Zeile: TStringlist;
  i: integer;
begin
  Assert(Assigned(Grid));
  List := TStringlist.Create;
  try
    Zeile := TStringlist.Create;
    try
      for i := 0 to Grid.RowCount - 1 do
        begin
          Zeile.Assign(Grid.Rows[i]);
          Zeile.Delimiter := #255;
          List.Add(Zeile.DelimitedText);
        end;
    finally
      Zeile.Free;
    end;
    List.SaveToFile(Filename);
  finally
    List.Free;
  end;
end;

procedure LoadStringGrid(Grid: TStringGrid; Filename: TFilename);
var
  List, Zeile: TStringlist;
  i: integer;
begin
  Assert(Assigned(Grid));
  List := TStringlist.Create;
  try
    List.LoadFromFile(Filename);
    if Grid.RowCount < List.Count then
      Grid.RowCount := List.Count;
    Zeile := TStringlist.Create;
    Zeile.Delimiter := #255;
    Zeile.StrictDelimiter := true;
    try
      for i := 0 to List.Count - 1 do
        begin
          Zeile.DelimitedText := List[i];
          if Grid.ColCount < Zeile.Count then
            Grid.ColCount := Zeile.Count;
          Grid.Rows[i].Assign(Zeile);
        end;
    finally
      Zeile.Free;
    end;
  finally
    List.Free;
  end;
end;
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 09:43 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf