AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Neue Klasse erstellen mit 2 Klassen als Attribute

Ein Thema von Coffeecoder · begonnen am 8. Dez 2011 · letzter Beitrag vom 8. Dez 2011
Antwort Antwort
Seite 1 von 2  1 2   
Benutzerbild von Coffeecoder
Coffeecoder

Registriert seit: 27. Apr 2011
242 Beiträge
 
Delphi 6 Enterprise
 
#1

Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 09:07
Hallo Leute,

Ich mache mir seit ein paar Tagen Gedanken um eine Klasse zu erstellen.
Ich weiss, dass Delphi wie auch in Java keine Mehrfachvererbung unterstützt!

Ich habe die zwei Klassen TComPort und TComTerminal vom Autor Dejan Crnila.
Zuerst einmal zu meinem Vorhaben, ich brauche die Attribute wie Baudrate, ComPort, Flow Control von der Klasse TComPort und die Methode StrReceive von der Klasse TComTerminal.
In meiner Klasse will ich noch ein paar Methoden und Attribute ergänzen.

Mein erster Ansatz war beide Klasse TComPort und TComTerminal als Attribut in meiner neuen Klassen zu deklarieren und dann im Konstruktor zu erstellen. Würdet Ihr das auch so machen?

Mein anderer Ansatz war von der Klasse TComPort oder von TComTerminal erben und dann die andere Klasse als Attribut ergänzen? Oder ganz anders?

Wenn Ihr mehr Informationen braucht, einfach Bescheid geben

Danke im Voraus.
Coffeecoder
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.459 Beiträge
 
Delphi 11 Alexandria
 
#2

AW: Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 09:15
Es kommt ein wenig auf die Beziehungen dieser 2 oder 3 Klassen zueinander an. Ein schneller Gedankenansatz meinerseits wäre:
- Eine Oberklasse mit den beiden Objekten als private Felder
- Die beiden Objekte werden vollständig verborgen, Zugriffe darauf geschehen indirekt über Properties bzw. Methoden.
- Das bedeutet, dass die Kommunikation mit der Außenwelt ausschließlich über die Oberklasse abgewickelt wird.

Auf diese Weise könnte man später nötigenfalls die enthaltenen Klassen gegen andere austauschen, ohne dass man das von außen mitbekommt.
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von Coffeecoder
Coffeecoder

Registriert seit: 27. Apr 2011
242 Beiträge
 
Delphi 6 Enterprise
 
#3

AW: Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 09:46
@DeddyH: Danke schon mal für dein Vorschlag

Ich gebe hier noch kurz eine Beschreibung zur der Klasse die ich erstellen will:

Sie beinhaltet Methoden die die Befehle an die ComPort sendet um mit dem Gerät zu kommunizieren.
Sie bearbeitet/formatiert die Werte um in : YYYYMMDD#hh:mm#Wert und speichert nachher in einer separaten Datei ab.

Das ist der Zusammenhang der Klassen.
Coffeecoder
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.459 Beiträge
 
Delphi 11 Alexandria
 
#4

AW: Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 10:01
Ja gut, das spricht meinem Vorschlag ja nicht zuwider. Der einzige Nachteil, den ich bei meiner Lösung sehe, ist etwas Tippaufwand, da man ja mindestens für jede Property, die man "durchreichen" will, einen Getter und einen Setter braucht. Das könnte dann etwa so aussehen:
Delphi-Quellcode:
type
  TSubClass1 = class
  private
    FProp1: SomeType;
  public
    function SomeFunc: SomeOtherType;
    property Prop1: SomeType read FProp1 write FProp1;
  end;
  
  TSubClass2 = class
  private
    FProp2: SomeType;
  public
    procedure SomeProc;
    property Prop2: SomeType read FProp2 write FProp2;
  end;
  
  TMainClass = class
  private
    FClass1: TSubClass1;
    FClass2: TSubClass2;
    function GetProp1: SomeType;
    function GetProp2: SomeType;
    procedure SetProp1(const value: SomeType);
    procedure SetProp2(const value: SomeType);
  public
    function SomeFunc: SomeOtherType;
    procedure SomeProc;
    property Prop1: SomeType read GetProp1 write SetProp1;
    property Prop2: SomeType read GetProp2 write SetProp2;
  end;
  
function TMainClass.GetProp1: SomeType;
begin
  Result := FClass1.Prop1;
end;

function TMainClass.GetProp2: SomeType;
begin
  Result := FClass2.Prop2;
end;

procedure TMainClass.SetProp1(const value: SomeType);
begin
  FClass1.Prop1 := value;
end;

procedure TMainClass.SetProp2(const value: SomeType);
begin
  FClass2.Prop2 := value;
end;

function TMainClass.SomeFunc: SomeOtherType;
begin
  Result := FClass1.SomeFunc;
end;

function TMainClass.SomeProc;
begin
  FClass2.SomeProc;
end;
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen

Geändert von DeddyH ( 8. Dez 2011 um 10:17 Uhr) Grund: Eine Prozedur hat keinen Rückgabewert, korrigiert *g*
  Mit Zitat antworten Zitat
Benutzerbild von Coffeecoder
Coffeecoder

Registriert seit: 27. Apr 2011
242 Beiträge
 
Delphi 6 Enterprise
 
#5

AW: Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 10:15
Gut das ist schon der Ansatz, den ich auch hatte.
Der Nachteil sehe ich auch darin, dass der Tippaufwand gross wird für alle Setter/Getter

Auf jeden Fall, danke für deine Tips DeddyH
Ich werde bei der nächsten Gelegenheit deinen Vorschlag testen.

Danke
Coffeecoder
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#6

AW: Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 10:26
Man kann sich natürlich einiges an Tipparbeit sparen, wenn es viele gleiche DatenTypen gibt:
Delphi-Quellcode:
unit uMyClass;

interface

type
  TMyBase1 = class
  private
    FMyStr : string;
    FMyInt : Integer;
  public
    property MyStr : string read FMyStr write FMyStr;
    property MyInt : Integer read FMyInt write FMyInt;
  end;

  TMyBase2 = class
  private
    FMyStr : string;
    FMyInt : Integer;
  public
    property MyStr : string read FMyStr write FMyStr;
    property MyInt : Integer read FMyInt write FMyInt;
  end;

  TMyClass = class
  private
    fMyBase1 : TMyBase1;
    fMyBase2 : TMyBase2;
    function GetString( const Index : Integer ) : string;
    procedure SetString( const Index : Integer; const Value : string );
    function GetInteger( const Index : Integer ) : Integer;
    procedure SetInteger( const Index, Value : Integer );
  public
    constructor Create;
    destructor Destroy; override;

    property FirstName : string index 1 read GetString write SetString;
    property LastName : string index 2 read GetString write SetString;

    property NameReadOnly : string index 1 read GetString;
    property NameWriteOnly : string index 1 write SetString;

    property Age : Integer index 1 read GetInteger write SetInteger;
    property Value : Integer index 2 read GetInteger write SetInteger;
  end;

implementation

{ TMyClass }

constructor TMyClass.Create;
begin
  inherited;
  fMyBase1 := TMyBase1.Create;
  fMyBase2 := TMyBase2.Create;
end;

destructor TMyClass.Destroy;
begin
  fMyBase1.Free;
  fMyBase2.Free;
  inherited;
end;

function TMyClass.GetInteger( const Index : Integer ) : Integer;
begin
  case Index of
    1 :
      Result := fMyBase1.MyInt;
    2 :
      Result := fMyBase2.MyInt;
  end;
end;

function TMyClass.GetString( const Index : Integer ) : string;
begin
  case Index of
    1 :
      Result := fMyBase1.MyStr;
    2 :
      Result := fMyBase2.MyStr;
  end;
end;

procedure TMyClass.SetInteger( const Index, Value : Integer );
begin
  case Index of
    1 :
      fMyBase1.MyInt := Value;
    2 :
      fMyBase2.MyInt := Value;
  end;
end;

procedure TMyClass.SetString( const Index : Integer; const Value : string );
begin
  case Index of
    1 :
      fMyBase1.MyStr := Value;
    2 :
      fMyBase2.MyStr := Value;
  end;
end;

end.
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.459 Beiträge
 
Delphi 11 Alexandria
 
#7

AW: Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 10:28
Wenn man die Klassenvervollständigung nutzt hält sich auch der Tippaufwand in erträglichen Grenzen
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von Coffeecoder
Coffeecoder

Registriert seit: 27. Apr 2011
242 Beiträge
 
Delphi 6 Enterprise
 
#8

AW: Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 10:30
Ich weiss dass unter Eclipse für Java mit Source > Generate Setter/Getter die ganze (unnötige) Tipparbeit einem erspart.

Gut zu wissen
Coffeecoder
  Mit Zitat antworten Zitat
shmia

Registriert seit: 2. Mär 2004
5.508 Beiträge
 
Delphi 5 Professional
 
#9

AW: Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 11:52
Mein erster Ansatz war beide Klasse TComPort und TComTerminal als Attribut in meiner neuen Klassen zu deklarieren und dann im Konstruktor zu erstellen. Würdet Ihr das auch so machen?
Nö.
Mal angenommen bei dem Zielgerät handelt es sich um eine Wetterstation, die über eine serielle Schnittstelle angesprochen wird.
Dann gibt es 2 Klassen:
* TWetterstation
* TComPort
Die Klasse TWetterstation benötigt keine Baudrate, Stopbits, usw sondern
sie benötigt lediglich ein fertig konfiguriertes TComPort-Objekt.
Die ganzen Details der seriellen Parameter interessieren die Klasse TWetterstation nicht.

Dieses TComPort-Objekt wird über den Konstruktor übergeben:
Delphi-Quellcode:
TWetterstation = class(TObject)
private
  FComport : TComport;
public
  constructor Create(comport:TComPort);
  procedure Reset;
  procedure ReadWetterdaten;
  property Temperatur:double;
  property Feuchtigkeit:double;
  property Luftdruck:double;
end;

constructor TWetterstation.Create(comport:TComPort);
begin
  inherited;
  FComport := comport;
end;
Sollte die Übergabe im Konstruktor nicht möglich sein, kann man das Comport-Objekt
auch über ein Property übergeben.
Andreas

Geändert von shmia ( 8. Dez 2011 um 11:55 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Coffeecoder
Coffeecoder

Registriert seit: 27. Apr 2011
242 Beiträge
 
Delphi 6 Enterprise
 
#10

AW: Neue Klasse erstellen mit 2 Klassen als Attribute

  Alt 8. Dez 2011, 13:13
Mein erster Ansatz war beide Klasse TComPort und TComTerminal als Attribut in meiner neuen Klassen zu deklarieren und dann im Konstruktor zu erstellen. Würdet Ihr das auch so machen?
Nö.
Mal angenommen bei dem Zielgerät handelt es sich um eine Wetterstation, die über eine serielle Schnittstelle angesprochen wird.
Dann gibt es 2 Klassen:
* TWetterstation
* TComPort
Die Klasse TWetterstation benötigt keine Baudrate, Stopbits, usw sondern
sie benötigt lediglich ein fertig konfiguriertes TComPort-Objekt.
Die ganzen Details der seriellen Parameter interessieren die Klasse TWetterstation nicht.

Dieses TComPort-Objekt wird über den Konstruktor übergeben:
Delphi-Quellcode:
TWetterstation = class(TObject)
private
  FComport : TComport;
public
  constructor Create(comport:TComPort);
  procedure Reset;
  procedure ReadWetterdaten;
  property Temperatur:double;
  property Feuchtigkeit:double;
  property Luftdruck:double;
end;

constructor TWetterstation.Create(comport:TComPort);
begin
  inherited;
  FComport := comport;
end;
Sollte die Übergabe im Konstruktor nicht möglich sein, kann man das Comport-Objekt
auch über ein Property übergeben.
Danke für deinen Vorschlag shmia.
Allerdings kommt mir da eine Frage auf: Vom TComTerminal brauch ich lediglich nur eine Methode onStrReceive, weil die TComPort Klasse nur die nötigen Parameter für die Kommunikation nötig sind.
Folglich muss ich in deinem Beispiel TWettersation doch noch die TComTerminal haben.

Dann habe ich:
Delphi-Quellcode:
TWetterstation = class(TObject)
private
  FComport : TComport;
  FComterminal :TComTerminal;
public
  constructor Create(comport:TComPort; comterminal : TComTerminal);
  procedure Reset;
  procedure ReadWetterdaten;
  property Temperatur:double;
  property Feuchtigkeit:double;
  property Luftdruck:double;
end;

constructor TWetterstation.Create(comport:TComPort; comterminal : TComTerminal);
begin
  inherited;
  FComport := comport;
  FComTerminal := comterminal;
end;

procedure TWettersation.ReadWetterdaten();
begin
     FComTerminal.onStrReceive();
end;
Das sollte so gehen? Ich habe im Moment kein Delphi auf dem Rechner hier drauf.
Coffeecoder
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 08:48 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf