ShellexecuteEX problem

[Memnarch]

Guten abend. Ich habe gerade ein merkwürdiges problem:

Aus irgendeinem grund funktionier ShellexecuteEX bei mir nicht mehr.

Folgendes resultat fürt zu gar nichts:

Code:

LInfo.cbSize := SizeOf(ShellExecuteInfo);
  LInfo.lpFile := PChar('E:\Programme\GStudio8\acknex.exe');
  LInfo.lpDirectory := PChar('E:\Programme\GStudio8\');
  LInfo.lpParameters := PChar('E:\Delphi\GenesisPreCompiler\testfiles\TestProject\TestProject\Main.c');
  LInfo.fMask := SEE_MASK_DEFAULT;
  ShellExecuteEx(@LInfo);

Dieselben sachen in shellexecute funktionieren.

Das ist urplötzlich so, ich kanne s mir nicht erklären >.<.
Wahrscheinlich sehe ich den wald vor lauter bäumen nicht.

Die hardcoded strings sind jetzt zu testzwcken gewesen(weils nicht mehr klappt).
mit CreateProcess wiederum klappt auch alles o.O

[himitsu]

Wie wäre es, wenn du mal den Rückgabewert und Fehlercode von ShellExecuteEx auswertest?

[Memnarch]

Fehlercode 1155:
"No application is associated with the specified file for this operation."

Ursprünglich bekam ich diese meldung auch in nem Popup. BAer das ist seit nen paar stunden ebenfalls verschwunden >.<.
Seit gestern, nach nem neustart ist das so. Und ich kapier es nicht o.O

[Popov]

Nur informationshalber, was macht die normale ShellExecute? Auch Probleme?

Was steht bei dir in der Reg unter:
HKEY_CLASSES_ROOT\.exe

oder

HKEY_CLASSES_ROOT\exefile

Ist der Eintrag da?

Man kann sich einen netten Scherz erlauben, in dem die Einträge umbenennt. Dann kann keine Exe mehr gestartet werden.

[Luckie]

Und wie hat er dann Delphi oder das Programm gestartet?

[himitsu]

Spontaner Gedanke:

Schau mal, was dein Debugger zu LInfo.lpVerb sagt. (ich vermute mal ... Anhand der Fehlermeldung ... dort steht was "falsches" drin)

Es kann bestimmt nicht Schaden diese Variable (LInfo) vorher mal zu leeren (ZeroMemory oder FillChar).

[Memnarch]

Nö, Shellexecute arbeitet prächtig, genauso wie CreateProcess.

Beide einträge sind da nur unter exefile gibts einen knoten doppelt(zweimal selber name, zweimal nix drin, außer standard)

Was sollte den drin stehen?

@Himitsu: ACH VERDAMMT. es kann so einfach sein >.<. Hab zeromemory vergessen, es stand #6 drin. Und in der konsole kam nen Pic zeichen XD. jaja, erklärt auch das random problem. Daanke schön^^.

[sx2008]

Zitat von Memnarch:

... Hab zeromemory vergessen,...

Wieso verwendest du eigentlich keinen "Delphi Layer" um die API-Funktion herum?
Also ich meine , man sollte solche relativ komplexen API-Funktionen wie ShellExecuteEx() nicht direkt aufrufen, sondern in eine Funktion verpacken, damit es beim Aufruf in der Anwendung keine Probleme gibt.
Hier Beispielcode aus der JCL:

Delphi-Quellcode:

function ShellExec(const FileName: string; const Parameters: string;
  const Verb: string; CmdShow: Integer): Boolean;
var
  Sei: TShellExecuteInfo;
begin
  FillChar(Sei, SizeOf(Sei), #0);
  Sei.cbSize := SizeOf(Sei);
  Sei.fMask := SEE_MASK_DOENVSUBST or SEE_MASK_FLAG_NO_UI;
  Sei.lpFile := PChar(FileName);
  Sei.lpParameters := PCharOrNil(Parameters);
  Sei.lpVerb := PCharOrNil(Verb);
  Sei.nShow := CmdShow;
  Result := ShellExecuteEx(@Sei);
end;

//------------------------------------------------------------------------------

function ShellExecAndWait(const FileName: string; const Parameters: string;
  const Verb: string; CmdShow: Integer): Boolean;
var
  Sei: TShellExecuteInfo;
begin
  FillChar(Sei, SizeOf(Sei), #0);
  Sei.cbSize := SizeOf(Sei);
  Sei.fMask := SEE_MASK_DOENVSUBST or SEE_MASK_FLAG_NO_UI or SEE_MASK_NOCLOSEPROCESS;
  Sei.lpFile := PChar(FileName);
  Sei.lpParameters := PCharOrNil(Parameters);
  Sei.lpVerb := PCharOrNil(Verb);
  Sei.nShow := CmdShow;
  Result := ShellExecuteEx(@Sei);
  if Result then
  begin
    WaitForInputIdle(Sei.hProcess, INFINITE);
    WaitForSingleObject(Sei.hProcess, INFINITE);
    CloseHandle(Sei.hProcess);
  end;
end;

  function PCharOrNil(const AString: string): PChar;
  begin
    if AString = '' then
      Result := nil
    else
      Result := PChar(AString);
  end;

Indem man eine dünne Schicht um Windows API Funktionen legt erhält man folgende Vorteile:
* vereinfachter Aufruf
* Möglichkeit gezielt einen Breakpoint zu setzen oder Aufrufe zu loggen
* Vermeidung von Fehlern wie z.B. fehlendes ZeroMemory
Das heisst jetzt nicht, man soll JEDE Windows API-Funktion kapseln, aber bei ShellExecuteEx lohnt es sich definitiv.

[Memnarch]

@SX2008: das ist mir durchaus bewusst. Nur benötige ich es in meinem projekt nur wenig, und selbst hier habe ich es schon in einer funktion gekapselt . Nur das kapseln bringt mir nichts, wenn ich zeromemory vergesse

MFG
Memnarch