AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein GUI-Design mit VCL / FireMonkey / Common Controls Modales Form finden, auf welches die Anwendung gerade wartet

Modales Form finden, auf welches die Anwendung gerade wartet

Ein Thema von DSCHUCH · begonnen am 12. Feb 2012 · letzter Beitrag vom 12. Feb 2012
Antwort Antwort
DSCHUCH

Registriert seit: 6. Jun 2007
Ort: Dresden
182 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#1

Modales Form finden, auf welches die Anwendung gerade wartet

  Alt 12. Feb 2012, 11:26
Hallo,

wie schon im Thema beschrieben ist mein Ziel das Handle der Modalen Form zu ermitteln, welches gerade die Anwendung blockt. Jeder kennt sicher das problem das in bestimmten Konstellationen dieses Form in der Z-Order verschwindet, insb. wenn es keine Delphi-Form sondern zB ein Windows-Dialog ist.

Kleiner Hinweis: es kann mehrere Modale Fenster übereinander geben. Sonst wäre es ja auch zu einfach.

Daniel.

Geändert von DSCHUCH (12. Feb 2012 um 11:31 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.100 Beiträge
 
Delphi 2006 Professional
 
#2

AW: Modales Form finden, auf welches die Anwendung gerade wartet

  Alt 12. Feb 2012, 11:30
Ähm du rufst es doch selber auf. Merk es dir doch einfach. Aber davon abgesehen, was willst du dann mit der Informationen machen?
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
34.931 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#3

AW: Modales Form finden, auf welches die Anwendung gerade wartet

  Alt 12. Feb 2012, 11:39
Screen.ActiveForm gibt die aktive TForm zurück ... das könnte/müßte dann die aktive Modale sein.
Eventuell noch fsModal in Screen.ActiveForm.FormState prüfen.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.100 Beiträge
 
Delphi 2006 Professional
 
#4

AW: Modales Form finden, auf welches die Anwendung gerade wartet

  Alt 12. Feb 2012, 11:41
Das funktioniert aber nur in einem separaten Thread, weil das modale Fenster ja den aufrufenden Thread blockiert.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von jaenicke
jaenicke

Registriert seit: 10. Jun 2003
Ort: Berlin
7.160 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#5

AW: Modales Form finden, auf welches die Anwendung gerade wartet

  Alt 12. Feb 2012, 12:03
Das funktioniert aber nur in einem separaten Thread, weil das modale Fenster ja den aufrufenden Thread blockiert.
Nein, es wird nur die Prozedur blockiert, aus der der Aufruf passierte. Es werden aber weiterhin Messages usw. im selben Thread verarbeitet. Man kann also problemlos in Timern oder anderen Windows Messages weiterarbeiten. (Sonst könnte das modale Fenster ja auch nicht mehr neu gezeichnet werden und würde nicht auf Eingaben reagieren können.)

Zum Thema:
In Screen.SaveFocusedList findest du die modalen Formulare wobei an Position 0 das zuletzt angezeigte steht.
Sebastian Jänicke
Alle eigenen Projekte sind eingestellt, ebenso meine Homepage, Downloadlinks usw. im Forum bleiben aktiv!
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.100 Beiträge
 
Delphi 2006 Professional
 
#6

AW: Modales Form finden, auf welches die Anwendung gerade wartet

  Alt 12. Feb 2012, 12:10
Ah, OK. Klingt logisch.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
26.778 Beiträge
 
Delphi 10.3 Rio
 
#7

AW: Modales Form finden, auf welches die Anwendung gerade wartet

  Alt 12. Feb 2012, 12:12
Delphi-Quellcode:
function GetModalWindow(SomeWindow: HWnd): HWnd;
var
  WindowList: TList;
  hThread: DWORD;

  function EnumFunc(aWnd: HWnd; List: lParam): Boolean; stdcall;
  begin
    if ((GetWindowLong(aWnd, GWL_EXSTYLE) and WS_EX_MDICHILD) = 0) and
       IsWindowEnabled(aWnd) and IsWindowVisible(aWnd) then
      TList(List).Add(Pointer(aWnd));
    Result := true;
  end;

begin
  Result := 0;
  if SomeWindow <> 0 then
    begin
      WindowList := TList.Create;
      try
        hThread := GetWindowThreadProcessID(SomeWindow);
        EnumThreadWindows(hThread, @EnumFunc, lParam(WindowList));
        if WindowList.Count = 1 then
          Result := HWnd(WindowList[0]);
      finally
        WindowList.Free;
      end;
    end;
end;

function IsThreadTopWindow(aWnd: HWnd): Boolean;
var
  NextWnd: HWnd;
  aThreadID, NextThreadID: DWORD;
begin
  Result := true;
  if aWnd <> 0 then
    begin
      aThreadID := GetWindowThreadProcessID(aWnd);
      NextWnd := GetWindow(aWnd, GW_HWNDPREV);
      while Result and (NextWnd <> 0) do
        begin
          NextThreadID := GetWindowThreadProcessID(NextWnd);
          if (NextThreadID = aThreadID) and IsWindowVisible(NextWnd) then
            Result := false
          else
            NextWnd := GetWindow(NextWnd, GW_HWNDPREV);
        end;
    end;
end;

function BringToForeground(aWnd: HWnd): Boolean;
const
  DRAWFLAGS = RDW_ERASE or RDW_INVALIDATE or RDW_UPDATENOW or RDW_ALLCHILDREN;
  MOVEFLAGS = SWP_NOMOVE or SWP_NOSIZE;
  SHOWMOVEFLAGS = MOVEFLAGS or SWP_SHOWWINDOW;
begin
  Result := true;
  if (aWnd <> 0) and IsWindowVisible(aWnd) then
    begin
      Result := SetWindowPos(aWnd, HWND_TOPMOST, 0, 0, 0, 0, MOVEFLAGS) and
                SetWindowPos(aWnd, HWND_NOTOPMOST, 0, 0, 0, 0, MOVEFLAGS) and
                SetWindowPos(aWnd, HWND_TOP, 0, 0, 0, 0, SHOWMOVEFLAGS);
      if Result then
        RedrawWindow(aWnd, nil, 0, DRAWFLAGS);
    end;
end;
Damit klappt das (bislang) auch bei fremden Anwendungen. Für die eigene wäre so etwas denkbar (Prozedur ist Applicaton.OnIdle zugewiesen):
Delphi-Quellcode:
procedure TFrmMain.DoOnIdle(Sender: TObject; var Done: Boolean);
var
  ModalWnd: HWnd;
begin
  ModalWnd := GetModalWindow(Handle);
  if (ModalWnd <> 0) and not IsThreadTopWindow(ModalWnd) then
    BringToForeground(ModalWnd);
  Done := true;
end;
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
DSCHUCH

Registriert seit: 6. Jun 2007
Ort: Dresden
182 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#8

AW: Modales Form finden, auf welches die Anwendung gerade wartet

  Alt 12. Feb 2012, 12:14
nimm einfach eine exception an, die ruft man nicht selbst auf. oder zb dialoge vom dbnavigator. etc.

modale formen durchlaufen nutzt nix, da gibt es ja mehrere. ich weiß trotzdem nicht welches die ist, welche gerade die aktive sein sollte.

wenn ich nach diesem thread gehe, könnte man es finden indem man zusätzlich auf enabled prüft:
http://www.delphipraxis.net/159994-t...-anzeigen.html

bestimmte modale dialogforms verschwinden immerwieder hinter fsStayOnTop Forms. das nervt gewaltig...

beobachten kann man dies allerdings in diversen delphiapplications. so zB auch der speichern-dialog im finalbuilder, der is auch manchmal einfach hinter dem hauptfenster und man kann nur noch mit trick 17 arbeiten.

Zitat:
Screen.SaveFocusedList
schaue ich mir gleich mal an.

Zitat:
DeddyH.....
ebenso, danke - damit habe ich sicher erstmal paar stunden zu testen.
  Mit Zitat antworten Zitat
DSCHUCH

Registriert seit: 6. Jun 2007
Ort: Dresden
182 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#9

AW: Modales Form finden, auf welches die Anwendung gerade wartet

  Alt 12. Feb 2012, 12:32
ich habe hier mal ein bsp zusammengeklickt, funktioniert aber in dem kleinen bsp nur mit eurekalog.

der dialog, welchen eurekalog öffnet liegt hier im hintergrund. man kann diesen schön hinter die TopMostForm schieben, dann geht nur noch mit tastaturbedienung irgendwas zu machen.
man kann das in diesem fall umgehen, indem man den dialog mittels options auch als stayontop erstellen läßt, aber andere dialoge haben zT gleiche effekte.

daniel.
Miniaturansicht angehängter Grafiken
dialogimhintergrund.png  
Angehängte Dateien
Dateityp: rar CheckZOrder.rar (95,5 KB, 12x aufgerufen)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 08:33 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf