Suche String->Hex Funktion

[Bernhard Geyer]

Zitat von DeddyH:

Meinst Du so etwas?
Format('%.2x', [Ord('A')])

Wenn schon dann %.4x - Unser String ist ja schon seit 4 Versionen standardmäßig Unicode-Fähig

[DeddyH]

Zitat von Bernhard Geyer:

Zitat von DeddyH:

Meinst Du so etwas?
Format('%.2x', [Ord('A')])

Wenn schon dann %.4x - Unser String ist ja schon seit 4 Versionen standardmäßig Unicode-Fähig

So besser?

Delphi-Quellcode:

function StrToHex(const s: string): string;
var
  CharWidth, i: integer;
  FormatStr: string;
begin
  CharWidth := SizeOf(Char) * 2;
  FormatStr := Format('%%.%dx', [CharWidth]);
  for i := 1 to Length(s) do
    Result := Result + Format(FormatStr, [Ord(s[i])]);
end;

[Sir Rufo]

@DeddyH

Warum so umständlich?

Delphi-Quellcode:

function StrToHex( const s: string ): string;
var
  i : integer;
begin
  for i := 1 to Length( s ) do
    Result := Result + Format( '%.*x', [SizeOf( Char ) * 2, Ord( s[i] )] );
end;

[Coffeecoder]

Zitat von Sir Rufo:

@DeddyH

Warum so umständlich?

Delphi-Quellcode:

function StrToHex( const s: string ): string;
var
  i : integer;
begin
  Result := ''; // <----
  for i := 1 to Length( s ) do
    Result := Result + Format( '%.*x', [SizeOf( Char ) * 2, Ord( s[i] )] );
end;

Muss nicht noch vorher Result initialisiert werden?

[DeddyH]

Bei Strings nicht, aber Du darfst das natürlich tun.

[Coffeecoder]

Zitat von DeddyH:

Bei Strings nicht, aber Du darfst das natürlich tun.

Gut dann packe ich einige Funktionen aus, wo ich das immer gemacht habe

[DeddyH]

Lass es doch drin, und wenn es nur dem besseren Verständnis dient

[himitsu]

Zu 99% geht es auch ohne Initialisierung, aber darauf verlaß dich besser mal nicht.

Das Result ist leider ein ganz blöder Sonderfall, denn die automatisch Initialisierung von String, dyn. Array und Interface liegt nicht in der Methode, so wie bei den lokalen Variablen, sondern beim Aufrufer und da gibt es ganz nette Seiteneffekte, welche dafür sorgen, daß das Result nicht mit '' vorbelegt sein könnte.

[gammatester]

99% scheint mir eine mutige Schätzung, gerade für Delphi 6, denn

Delphi-Quellcode:

function dummy: string;
begin
  result := result + ' oder so';
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  s: string;
begin
  s := '42';
  s := dummy;
  showmessage(s);
end;

zeigt zB zuverlässig '42 oder so' an. Und im Assembler ist nix zu sehen vom Vorherlöschen.