AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) Delphi Probleme mit SHQueryRecycleBin in einer 64Bit Anwendung

Probleme mit SHQueryRecycleBin in einer 64Bit Anwendung

Ein Thema von RWarnecke · begonnen am 6. Mai 2012 · letzter Beitrag vom 6. Mai 2012
Antwort Antwort
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.408 Beiträge
 
Delphi XE8 Enterprise
 
#1

Probleme mit SHQueryRecycleBin in einer 64Bit Anwendung

  Alt 6. Mai 2012, 12:22
Hallo zusammen,

ich benutze die folgenden zwei Funktionen in einer 32Bit-Anwendung um die Größe des Papierkorbes zu ermitteln :
Delphi-Quellcode:
type
  //
  // Declarations for the infos about the recycle bin
  //
  PSHQueryRBInfo = ^TSHQueryRBInfo;
  TSHQueryRBInfo = packed record
    cbSize: DWORD;
    i64Size: Int64;
    i64NumItems: Int64;
  end;

function SHQueryRecycleBin(szRootPath: PAnsiChar; SHQueryRBInfo: PSHQueryRBInfo): HResult;
  stdcall; external 'shell32.dllName 'SHQueryRecycleBinA';

{...}

function GetDllVersion(FileName: string): Integer;
var
  InfoSize, Wnd: DWORD;
  VerBuf: Pointer;
  FI: PVSFixedFileInfo;
  VerSize: DWORD;
begin
  Result := 0;
  InfoSize := GetFileVersionInfoSize(PChar(FileName), Wnd);
  if InfoSize <> 0 then
  begin
    GetMem(VerBuf, InfoSize);
    try
      if GetFileVersionInfo(PChar(FileName), Wnd, InfoSize, VerBuf) then
        if VerQueryValue(VerBuf, '\', Pointer(FI), VerSize) then
          Result := FI.dwFileVersionMS;
    finally
      FreeMem(VerBuf);
    end;
  end;
end;

function RecycleBinInfo(const Drive: PAnsiChar; out BinSize, FileCount: Int64): Boolean;
var
  DllVersion : integer;
  SHQueryRBInfo : TSHQueryRBInfo;
  r : HResult;
begin
  Result := true;
  BinSize := 0;
  FileCount := 0;
  DllVersion := GetDllVersion(PChar('shell32.dll'));
  if DllVersion >= $00040048 then
  begin
    FillChar(SHQueryRBInfo, SizeOf(TSHQueryRBInfo), #0);
    SHQueryRBInfo.cbSize := SizeOf(TSHQueryRBInfo);
    R := SHQueryRecycleBin(Drive, @SHQueryRBInfo);
    if r = s_OK then
    begin
      BinSize := SHQueryRBInfo.i64Size;
      FileCount := SHQueryRBInfo.i64NumItems;
    end
    else
      Result := false;
  end;
end;
Die Ermittlung der Größe des Papierkorbes und die Anzahl der Dateien funktioniert in einer 32Bit Anwendung hervorragend. Bei einer 64Bit Anwendung wird mir aber lediglich nur 0 für die Größe und für die Anzahl der Dateien ausgegeben. Was muss ich ändern, damit die Funktion in einer 64Bit Anwendung funktinoinert ?
Rolf Warnecke
App4Mission
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#2

AW: Probleme mit SHQueryRecycleBin in einer 64Bit Anwendung

  Alt 6. Mai 2012, 13:03
Delphi-Quellcode:
type
  //
  // Declarations for the infos about the recycle bin
  //
  PSHQueryRBInfo = ^TSHQueryRBInfo;
  TSHQueryRBInfo = packed record
    cbSize: DWORD;
    i64Size: Int64;
    i64NumItems: Int64;
  end;

function SHQueryRecycleBin(szRootPath: PAnsiChar; SHQueryRBInfo: PSHQueryRBInfo): HResult;
  stdcall; external 'shell32.dllName 'SHQueryRecycleBinA';

{...}

function GetDllVersion(FileName: string): Integer;
var
  InfoSize, Wnd: DWORD;
  VerBuf: Pointer;
  FI: PVSFixedFileInfo;
  VerSize: DWORD;
begin
  Result := 0;
  InfoSize := GetFileVersionInfoSize(PChar(FileName), Wnd);
  if InfoSize <> 0 then
  begin
    GetMem(VerBuf, InfoSize);
    try
      if GetFileVersionInfo(PChar(FileName), Wnd, InfoSize, VerBuf) then
        if VerQueryValue(VerBuf, '\', Pointer(FI), VerSize) then
          Result := FI.dwFileVersionMS;
    finally
      FreeMem(VerBuf);
    end;
  end;
end;

procedure RecycleBinInfo(const Drive: PAnsiChar; out BinSize, FileCount: Int64);
var
  DllVersion : integer;
  SHQueryRBInfo : TSHQueryRBInfo;
  r : HResult;
begin
  DllVersion := GetDllVersion(PChar('shell32.dll'));
  if DllVersion >= $00040048 then
  begin
    FillChar(SHQueryRBInfo, SizeOf(TSHQueryRBInfo), #0);
    SHQueryRBInfo.cbSize := SizeOf(TSHQueryRBInfo);
    R := SHQueryRecycleBin(Drive, @SHQueryRBInfo);
    if r = s_OK then
    begin
      BinSize := SHQueryRBInfo.i64Size;
      FileCount := SHQueryRBInfo.i64NumItems;
    end
    else
      RaiseLastOSError();
  end;
end;

procedure TForm2.Button1Click(Sender: TObject);
var
  CountFiles, BinSize: Int64;
begin
  try
    RecycleBinInfo('c:', BinSize, CountFiles);
    ShowMessage(IntToStr(CountFiles));
  except
    on E: Exception do
      ShowMessage(E.Message);
  end;
end;
Geht: BDS2006, Windows 7 64-Bit.
Michael
Ein Teil meines Codes würde euch verunsichern.

Geändert von Luckie ( 6. Mai 2012 um 13:06 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Zacherl
Zacherl

Registriert seit: 3. Sep 2004
4.629 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#3

AW: Probleme mit SHQueryRecycleBin in einer 64Bit Anwendung

  Alt 6. Mai 2012, 13:40
@Luckie: Ich glaube Rolf bezog sich eher auf die Architektur des Programms selbst, als auf die Systemarchitektur.

Ändere mal das Info Struct folgendermaßen ab:
Delphi-Quellcode:
type
  PSHQueryRBInfo = ^TSHQueryRBInfo;
  TSHQueryRBInfo = packed record
    cbSize: NativeUInt;
    i64Size: Int64;
    i64NumItems: Int64;
  end;
Damit funkioniert es für mich sowohl als 32, als auch als 64 bit Kompilat.
Projekte:
- GitHub (Profil, zyantific)
- zYan Disassembler Engine ( Zydis Online, Zydis GitHub)
  Mit Zitat antworten Zitat
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.408 Beiträge
 
Delphi XE8 Enterprise
 
#4

AW: Probleme mit SHQueryRecycleBin in einer 64Bit Anwendung

  Alt 6. Mai 2012, 15:07
Hallo Zacherl,

danke für Deine Antwort. Es funktioniert so wie Du es beschrieben hast. Ich habe durch das DWord den Befehl so zusagen auf eine 32Bit Architektur beschränkt, wenn ich die Hilfe richtig verstanden habe. Danke, habe wieder etwas dazu gelernt.
Rolf Warnecke
App4Mission
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 17:04 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz