AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

32 Bit Wert verschieden interpretieren

Ein Thema von zeras · begonnen am 17. Mai 2012 · letzter Beitrag vom 17. Mai 2012
Antwort Antwort
Seite 2 von 2     12
zeras

Registriert seit: 11. Mär 2007
Ort: Saalkreis
1.556 Beiträge
 
Delphi 11 Alexandria
 
#11

AW: 32 Bit Wert verschieden interpretieren

  Alt 17. Mai 2012, 18:20
Ich habs nun mal so gemacht. Muss nur noch testen. Das Array ar4 enthält dann die 4 Bytes, unabhängig, ob es Single, LongWord oder LongInt ist.

Delphi-Quellcode:
Function WriteToSvr(Address: Longword; dValue: Longword): Boolean; overload;
var
  Adr1 : Longword;
  Wert : Longword;
  ar: ar4 absolute Wert;

begin
  Result := False;
  Adr1 := Address;
  Wert := dValue;

  If WriteToSvr3(Adr1, ar) then begin
    Result := True;
  end;
end;

Function WriteToSvr(Address: Longword; dValue: LongInt): Boolean; overload;
var
  Adr1 : Longword;
  Wert : LongInt;
  ar: ar4 absolute Wert;

begin

  Result := False;
  Adr1 := Address;
  Wert := dValue;

  If WriteToSvr3(Adr1, ar) then begin
    Result := True;
  end;
end;


Function WriteToSvr(Address: Longword; dValue: Single): Boolean; overload;
var
  Adr1 : Longword;
  Wert : Single;
  ar: ar4 absolute Wert;

begin
  Result := False;
  Adr1 := Address;
  Wert := dValue;

  If WriteToSvr3(Adr1, ar) then begin
    Result := True;
  end;
end;
Matthias
Es ist nie falsch das Richtige zu tun!
- Mark Twain
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.459 Beiträge
 
Delphi 11 Alexandria
 
#12

AW: 32 Bit Wert verschieden interpretieren

  Alt 17. Mai 2012, 18:33
Mit einem varianten Record sollte das aber auch funktionieren, und zwar kürzer.
Delphi-Quellcode:
type
  TConvRec = record
    case integer of
      0: (d: double);
      1: (i: LongInt);
      2: (w: LongWord);
      3: (LoLo, HiLo, LoHi, HiHi: Byte);
  end;

procedure TForm1.Button1Click(Sender: TObject);
var
  Rec: TConvRec;
begin
  Rec.i := -2147483647;
  ShowMessage(Format('%d, %d, %d, %d', [Rec.HiHi, Rec.LoHi, Rec.HiLo, Rec.LoLo]));
  Rec.w := 4294967295;
  ShowMessage(Format('%d, %d, %d, %d', [Rec.HiHi, Rec.LoHi, Rec.HiLo, Rec.LoLo]));
  Rec.d := 1.7e308;
  ShowMessage(Format('%d, %d, %d, %d', [Rec.HiHi, Rec.LoHi, Rec.HiLo, Rec.LoLo]));
end;
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Benutzerbild von jaenicke
jaenicke

Registriert seit: 10. Jun 2003
Ort: Berlin
8.504 Beiträge
 
Delphi 10.4 Sydney
 
#13

AW: 32 Bit Wert verschieden interpretieren

  Alt 17. Mai 2012, 18:34
Für mich hört sich das sehr danach an als ob du z.B. einen varianten Record suchst... ungetestetes Beispiel, das sollte mit Delphi 2009 schon gehen:
Delphi-Quellcode:
type
  TMy4ByteData = packed record
    type
      TDataType = (dtSingle, dtInteger, dtLongWord);
    class operator implicit(const Value: TMy4ByteData): TArray<Byte>;
    case DataType: TDataType of
      dtSingle:
        (ValueAsSingle: Single);
      dtInteger:
        (ValueAsInteger: Integer);
      dtLongWord:
        (ValueAsLongWord: LongWord);
  end;

// ...

class operator TMy4ByteData.implicit(const Value: TMy4ByteData): TArray<Byte>;
begin
  SetLength(Result, 4);
  CopyMemory(Pointer(Result), @Value.ValueAsInteger, 4);
end;

procedure Example(const AValue: TMy4ByteData);
begin
  case AValue.DataType of
    dtSingle:
      ShowMessage('Single: ' + FloatToStr(AValue.ValueAsSingle));
    dtInteger:
      ShowMessage('Integer: ' + IntToStr(AValue.ValueAsInteger));
    dtLongWord:
      ShowMessage('LongWord: ' + IntToStr(AValue.ValueAsLongWord));
  end;
end;

var
  Value: TMy4ByteData;
  ValueData: TArray<Byte>;
  CurrentByte: Byte;
begin
  Value.DataType := dtSingle;
  Value.ValueAsSingle := 4.5;
  Example(Value);
  ValueData := Value;
  for CurrentByte in ValueData do
    ShowMessage(IntToStr(CurrentByte));
end;
Ich sehe schon die rote Box, aber ich poste wegen dem Operator mal trotzdem...
Sebastian Jänicke
Alle eigenen Projekte sind eingestellt, ebenso meine Homepage, Downloadlinks usw. im Forum bleiben aktiv!
  Mit Zitat antworten Zitat
Popov
(Gast)

n/a Beiträge
 
#14

AW: 32 Bit Wert verschieden interpretieren

  Alt 17. Mai 2012, 19:03
Wieso das
Delphi-Quellcode:
  If WriteToSvr3(Adr1, ar) then begin
    Result := True;
  end;
nicht so?

  Result := WriteToSvr3(Adr1, ar);
  Mit Zitat antworten Zitat
zeras

Registriert seit: 11. Mär 2007
Ort: Saalkreis
1.556 Beiträge
 
Delphi 11 Alexandria
 
#15

AW: 32 Bit Wert verschieden interpretieren

  Alt 17. Mai 2012, 19:12
Wieso das
Delphi-Quellcode:
  If WriteToSvr3(Adr1, ar) then begin
    Result := True;
  end;
nicht so?

  Result := WriteToSvr3(Adr1, ar);
Gute Idee.
Ich hatte in dem Zweig ursprünglich noch etwas anderes drin. Aber jetzt nicht mehr. So könnte ich den Code noch ein wenig schlanker machen.
Matthias
Es ist nie falsch das Richtige zu tun!
- Mark Twain
  Mit Zitat antworten Zitat
Popov
(Gast)

n/a Beiträge
 
#16

AW: 32 Bit Wert verschieden interpretieren

  Alt 17. Mai 2012, 19:14
Dann kannst du auch Result := False; entfernen.
  Mit Zitat antworten Zitat
zeras

Registriert seit: 11. Mär 2007
Ort: Saalkreis
1.556 Beiträge
 
Delphi 11 Alexandria
 
#17

AW: 32 Bit Wert verschieden interpretieren

  Alt 17. Mai 2012, 19:18
Mit einem varianten Record sollte das aber auch funktionieren, und zwar kürzer.
Danke für die Info.
Das mit den varianten Records muss ich mir mal später genauer anschauen.
Vielleicht kann das später in mein Projekt mit reinwachsen.
Matthias
Es ist nie falsch das Richtige zu tun!
- Mark Twain
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 11:01 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf