AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Object-Pascal / Delphi-Language Delphi Eine Generics TObjectList<T> als Parameter

Eine Generics TObjectList<T> als Parameter

Ein Thema von RWarnecke · begonnen am 30. Okt 2012 · letzter Beitrag vom 2. Dez 2012
Antwort Antwort
Seite 1 von 2  1 2   
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.408 Beiträge
 
Delphi XE8 Enterprise
 
#1

Eine Generics TObjectList<T> als Parameter

  Alt 30. Okt 2012, 11:39
Delphi-Version: XE2
Hallo zusammen,

ich habe eine generics ObjectList so definiert TCustomObjectList<T: class> = class(TObjectList<T>) und als Variable so definiert ZahlungsartList : TCustomObjectList<TZahlungsart>; . Das funktioniert auch wunderbar. Ich kann ja die Generic-ObjectList so wie ich Sie als Variable deklariert habe übergeben : procedure foobar(liste: CustomObjectList<TZahlungsart>); . Wie kann ich auch das <TZahlungsart> als Parameter definieren in dem Procedure-Kopf ?
Rolf Warnecke
App4Mission
  Mit Zitat antworten Zitat
daywalker9

Registriert seit: 1. Jan 2010
Ort: Leer
594 Beiträge
 
Delphi XE3 Professional
 
#2

AW: Eine Generics TObjectList<T> als Parameter

  Alt 30. Okt 2012, 12:20
Delphi-Quellcode:
type
  TFoo = class
    procedure bar<T>(meineList:Tobjectlist<T>);
  end;
Meinst Du sowas?
Lars
  Mit Zitat antworten Zitat
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.408 Beiträge
 
Delphi XE8 Enterprise
 
#3

AW: Eine Generics TObjectList<T> als Parameter

  Alt 30. Okt 2012, 12:50
Nein, ich möchte in einer externen eigenständigen Funktion auf Werte von den Generics-ObjectListen zugreifen. In dieser Funktion soll dann anhand der übergebenen Liste entschieden werden, was gemacht werden soll.

Der Pseudocode soll zeigen, was ich machen möchte :
Delphi-Quellcode:
interface

type
  TZahlungsart = class
  private
    {...}
  public
    {...}
  end;

  TPostleitzahlen = class
  private
    {...}
  public
    {...}
  end;

  TCustomObjectList<T: class> = class(TObjectList<T>)
  private
    {...}
  public
    {...}
  end;

var
  ZahlungsartList : TCustomObjectList<TZahlungsart>;
  Postleitzahlen : TCustomObjectList<TPostleitzahlen>;

implementation

procedure Test(ObjectList: ??????);
var
  tmpName : string;
begin
  tmpName := ObjectList.Items[Counter].<Feld>;
end:
Der Aufruf aus der Form soll dann zum Beispiel so aussehen :
Delphi-Quellcode:
procedure TForm1.Button1Click(Sender: TObject);
begin
  procedure Test(ZahlungsartList);
end;
Statt Zahlungsart kann da auch Postleitzahlen stehen.
Rolf Warnecke
App4Mission
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe
Online

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#4

AW: Eine Generics TObjectList<T> als Parameter

  Alt 30. Okt 2012, 13:47
Als globale Prozedur wird das nicht gehen, lediglich als Methode eines Records oder einer Klasse:

Delphi-Quellcode:
  TDummy = record
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>); static;
  end;


  TDummy.Test<TZahlungsart>(ZahlungsartList);
  TDummy.Test<TPostleitzahlen>(Postleitzahlen);
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.017 Beiträge
 
Delphi 12 Athens
 
#5

AW: Eine Generics TObjectList<T> als Parameter

  Alt 30. Okt 2012, 14:05
oder so, wem das besser gefällt (kommt aber, von der Verwendung her, auf's Selbe raus ... ich find Record auch schöner, aber Klasse ist ableitbar/erweiterbar)
Delphi-Quellcode:
  TDummy = class abstract // ältere Delphis: wenn's nicht geht, dann abstract einfach weglassen
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>); static;
  end;

Schade das emba nicht auf mich hört und bei generischen Funktionen einfach eine DummyKlasse/Record drumzupacken, wenn die es nicht schaffen es ihrem Compiler beizubringen, dßa es generische Funktion gibt.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.408 Beiträge
 
Delphi XE8 Enterprise
 
#6

AW: Eine Generics TObjectList<T> als Parameter

  Alt 30. Okt 2012, 14:10
Hm, das ist nicht ganz das was ich wollte. Aber ok, dann muss ich ein bisschen umkoordinieren.
Rolf Warnecke
App4Mission
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
4.007 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#7

AW: Eine Generics TObjectList<T> als Parameter

  Alt 30. Okt 2012, 15:06
Da wir einen Typconstraint auf class haben, können wir davon ausgehen dass jedes T eine Klasse ist.
Somit können wir auch gefahrlos einen Hardcast auf TCustomObjectList<TObject> machen (Stichwort: Kovarianz).

Bei der Instanzierung einer Liste, merken wir uns, von welchem Typ T ist.
Dies muss auf Instanzebene gespeichert werden, damit wir auch nach dem zuvor erwähnten Hardcast noch die richtige Klasse herausbekommen.

Delphi-Quellcode:
type
  TCustomObjectList<T: class> = class(TObjectList<T>)
  private
    FItemClass: TClass;
  public
    constructor Create(AOwnsObjects: Boolean = True); overload;
    function AsNonGeneric: TCustomObjectList<TObject>;
    property ItemClass: TClass read FItemClass;
  end;

  TCustomObjectList = TCustomObjectList<TObject>;

function TCustomObjectList<T>.AsNonGeneric: TCustomObjectList<TObject>;
begin
  Result := TCustomObjectList<TObject>(Self);
end;

constructor TCustomObjectList<T>.Create(AOwnsObjects: Boolean);
begin
  inherited Create(AOwnsObjects);
  FItemClass := T;
end;

procedure Test(ObjectList: TCustomObjectList);
begin
  Writeln(objectList.ItemClass.ClassName);
end;

var
  ZahlungsartList: TCustomObjectList<TZahlungsart>;
  Postleitzahlen: TCustomObjectList<TPostleitzahlen>;
begin
  ZahlungsartList := TCustomObjectList<TZahlungsart>.Create;
  Postleitzahlen := TCustomObjectList<TPostleitzahlen>.Create;

  Test(ZahlungsartList.AsNonGeneric);
  Test(Postleitzahlen.AsNonGeneric);
end.
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight
  Mit Zitat antworten Zitat
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.408 Beiträge
 
Delphi XE8 Enterprise
 
#8

AW: Eine Generics TObjectList<T> als Parameter

  Alt 1. Dez 2012, 20:54
Als globale Prozedur wird das nicht gehen, lediglich als Methode eines Records oder einer Klasse:

Delphi-Quellcode:
  TDummy = record
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>); static;
  end;


  TDummy.Test<TZahlungsart>(ZahlungsartList);
  TDummy.Test<TPostleitzahlen>(Postleitzahlen);
Kann ich die Test-Procedure auch überladen ? Wenn ja, wie geht das ? Wo kann ich das nachlesen ?
Rolf Warnecke
App4Mission
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.017 Beiträge
 
Delphi 12 Athens
 
#9

AW: Eine Generics TObjectList<T> als Parameter

  Alt 1. Dez 2012, 21:13
Was willst du denn überladen?

Aber ja, "overload" funktioniert wie mit jeder normalen Methode auch.


PS: Man kann sich auch aussuchen wo man den generischen Typen deklariert.
Delphi-Quellcode:
  TDummy = record // oder class macht keinen großen Unterschied
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>); static;
  end;

  TDummy.Test<TZahlungsart>(ZahlungsartList);
  TDummy.Test<TPostleitzahlen>(Postleitzahlen);

  TDummy<T:class> = record // oder class macht keinen großen Unterschied
    class procedure Test(ObjectList: TCustomObjectList<T>); static;
  end;

  TDummy<TZahlungsart>.Test(ZahlungsartList);
  TDummy<TPostleitzahlen>.Test(Postleitzahlen);
Letzeres hat einen Vorteil, wenn man eine Funktion mit einem bestimmten Typen oft aufruft.
Ersteres, wenn man viele Verschiedene Typen nutzt.
Und es läßt sich beliebig kombinieren.

Delphi-Quellcode:
type ZahlDummy = TDummy<TZahlungsart>;

ZahlDummy.Test(ZahlungsartList);
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.408 Beiträge
 
Delphi XE8 Enterprise
 
#10

AW: Eine Generics TObjectList<T> als Parameter

  Alt 1. Dez 2012, 21:20
Was willst du denn überladen?
Wenn ich inder Procedure noch einen weiteren Parameter einfüge und den zum Beispiel einmal als String und einmal als Integer haben möchte. Beispiel :
Delphi-Quellcode:
  TDummy = record
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>; ID: Integer); static;
    class procedure Test<T:class>(ObjectList: TCustomObjectList<T>; ID: string); static;
  end;


  TDummy.Test<TZahlungsart>(ZahlungsartList, 1);
  TDummy.Test<TZahlungsart>(ZahlungsartList, '1');
So wie ich es im Beispiel angegeben habe, funktioniert es nicht mit static oder overload. Dieses soll nur ein Beispiel sein um das Überladen zu verstehen.
Rolf Warnecke
App4Mission
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 12:08 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz