WordBreak innerhalb eines Wortes

[Popov]

Ich hab mal was geschrieben, ist aber schon lange her, so dass ich es dir nicht erklären kann. Gedacht ist es so, dass ein beliebiger Text einer StringList so umbrochen wird, dass er von der Breite in eine von der Breite vordefinierte Bitmap passt. Die Höhe der Bitmap sollte dann auch noch neu definiert werden bevor gezeichnet wird:

Delphi-Quellcode:

//Bricht die Textzeilen eines Textes in StringList so, dass sie in einer
//Bitmap passen. Diese Prozedur bricht nur die Zeilen, zeichnet nicht.
//Der Bitmap-Parameter dient nur zur Größenbestimmungen: Font, Width, usw.
//List enthällt den Text der umbrochen werden soll.
procedure TextToBitmap2(AList: TStrings; ATarget: TBitmap);
var
  i, k, LastSpace: Integer;
  Line, s: String;
begin
  if AList.Count = 0 then Exit;
  if ATarget.Width = 0 then Exit;

  i := 0;

  repeat
    LastSpace := 0;

    for k := 1 to Length(AList[i]) do
    begin
      Line := AList[i];

      if (ATarget.Canvas.TextWidth(Copy(Line, 1, k))) <= (ATarget.Width) then
      begin
        if {Line[k]} Copy(Line, k, 1) = ' ' then LastSpace := k;
      end
        else
      begin
        if LastSpace = 0 then
        begin
          if k > 0 then
          begin
            s := Copy(Line, k, Length(Line));
              //Schneidet ab letzten gültigen Zeichen ab
            System.Delete(Line, k, Length(Line));
          end;
        end
          else
        begin
            //Mit +1 wird das Leerzeichen nicht übernommen, da es sonst als
            //erstes Zeichen in der Zeile vorkommt
          s := Copy(Line, LastSpace+1, Length(Line));
            //Mit +1 bleibt das Leerzeichen an der aktuellen Zeile,
            //was bei Übertragung in Grafik nicht wichtig ist.
            //Mit +0 (oder Nichts) wird auch das Leerzeichen gelöscht
          System.Delete(Line, LastSpace+1, Length(Line));
        end;

        AList[i] := Line;
        AList.Insert(i + 1, s);
      end;
    end;

    Inc(i);
  until i > (AList.Count - 1);
end;

[shmia]

Ich würde anstatt einem Bitmap einen Canvas und die Breite übergeben; das ist einfach flexibler.
Weil dann auch der Prozedurname nicht mehr passt würde ich vorschlagen:

Delphi-Quellcode:

procedure LimitLineWidths(AList: TStrings; Canvas:TCanvas; Width:Integer);
var
  ...

[Popov]

Das Ergebnis landete bei mir direkt in einer Bitmap, deshalb die Lösung. Technisch gesehen kann man es auch mit Canvas machen. Width kann man aus ClipRect.Right - ClipRect.Left ermitteln.

[shmia]

Zitat von Popov:

Das Ergebnis landete bei mir direkt in einer Bitmap, deshalb die Lösung. Technisch gesehen kann man es auch mit Canvas machen. Width kann man aus ClipRect.Right - ClipRect.Left ermitteln.

Nicht immer soll der mehrzeilige Text so breit sein wie das Ziel (Bitmap bzw. Canvas) und das Ziel muss nicht unbedingt ein Bitmap sein (könnte auch der Canvas von TPrinter sein).
Vielleicht möchte man links und rechts einen Rand freihalten oder gar 2-spaltig ausgeben.

Mit meinem Vorschlag hält man sich alle Möglichkeiten offen...

[SittingDuck]

Danke schon mal für Euren Input. Ich habe es nun folgendermaßen gelöst:

Delphi-Quellcode:

var n, t: String;  r: TRect; ts: TSize; 
    a, h: Integer; TempList: TStringList;

n := 'Normaler Text und DerSuperlangeTextDerUmgebrochenWerdenMuss';
r := Rect(0, 0, 180, 0); // über 180 Pixel wird umgebrochen 
h := DrawText(Image32.Bitmap.Handle, PChar(n), Length(n), r, DT_WORDBREAK or DT_NOPREFIX or DT_CALCRECT);

if r.Right > 180 then begin // ein einzelnes Wort ging über 180 Pixel hinaus
  TempList.Text := WrapText(n, 10); // alles was länger ist als 10 Zeichen bekommt eine eigene TStringGrid-Zeile
  for a := 0 to Pred(TempList.Count) do begin 
    t := TempList[a]; // Text zeilenweise untersuchen
    DrawText(Image32.Bitmap.Handle, PChar(t), Length(t), r, DT_WORDBREAK or DT_NOPREFIX or DT_CALCRECT);
    if r.Right > 180 then begin n := ''; // ein überlanges Wort wurde gefunden
      while Length(t) > 0 do begin
        GetTextExtentExPoint(Image32.Bitmap.Handle, PChar(t), Length(t), 180, @h, nil, ts);
        n := n + Copy(t, 1, h) + ' '; Delete(t, 1, h);
      end; 
      TempList[a] := n;
    end; 
    r := Rect(0, 0, 180, 0);
  end;
  n := StringReplace(Trim(TempList.Text), #13#10, '', [rfReplaceAll]); // nicht ausführen falls CRs gewünscht
  h := DrawText(Image32.Bitmap.Handle, PChar(n), Length(n), r, DT_WORDBREAK or DT_NOPREFIX or DT_CALCRECT);
end;
Image32.Textout(r, DT_WORDBREAK or DT_NOPREFIX, n);

Vielleicht hilft es ja dem ein oder anderen. Das Image32 aus der GR32 kann natürlich auch ein normales Bitmap sein.