AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

MyStrToHex extrem schnell

Ein Thema von PeterPanino · begonnen am 23. Dez 2012 · letzter Beitrag vom 25. Dez 2012
Antwort Antwort
Seite 1 von 3  1 23   
PeterPanino

Registriert seit: 4. Sep 2004
1.266 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#1

MyStrToHex extrem schnell

  Alt 23. Dez 2012, 23:15
Delphi-Version: XE2
Hallo! Ich möchte folgende Funktion auf extreme Geschwindigkeit optimieren:
Delphi-Quellcode:
function MyStrToHex(s: string): string;
var
  i: Integer;
begin
  Result := '';
  for i := 1 to Length(s) do
    Result := Result + IntToHex(Ord(s[i]), 4);
end;
Kennt jemand eine Assembler-Version davon?
  Mit Zitat antworten Zitat
Benutzerbild von Bernhard Geyer
Bernhard Geyer

Registriert seit: 13. Aug 2002
Ort: Oberreichenbach
16.473 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#2

AW: MyStrToHex extrem schnell

  Alt 23. Dez 2012, 23:20
Du brauchst keine Assembler um zu beschleunigen

1, Ergänze ein const beim Aufrufparameter
2, Verwende den Stringbuilder den es in neueren Delphiversionen gibt.
Windows Vista - Eine neue Erfahrung in Fehlern.
  Mit Zitat antworten Zitat
PeterPanino

Registriert seit: 4. Sep 2004
1.266 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#3

AW: MyStrToHex extrem schnell

  Alt 24. Dez 2012, 00:30
Meinst etwa so?:
Delphi-Quellcode:
function MyStrToHex(const s: TStringBuilder): TStringBuilder;
var
  i: Integer;
begin
  Result := TStringBuilder.Create;
  for i := 0 to s.Length - 1 do
    Result.Append(IntToHex(Ord(s.Chars[i]), 4));
end;

SB := TStringBuilder.Create;
SB.Append('Tᾯest');
SB := MyStrToHex(SB);
Self.Caption := SB.ToString;
SB.Free;
Aber damit scheint der Code nicht schneller, sondern eher langsamer geworden zu sein.

Außerdem mache ich mir Sorgen: Muss die in der Funktion MyStrToHex in Result erzeugte StringBuilder-Instanz nicht irgendwie freigegeben werden?
  Mit Zitat antworten Zitat
Medium

Registriert seit: 23. Jan 2008
3.479 Beiträge
 
Delphi 2007 Enterprise
 
#4

AW: MyStrToHex extrem schnell

  Alt 24. Dez 2012, 01:12
Wie wäre es damit:

Delphi-Quellcode:
function MyStrToHex(const s: string): string;
var
   i: Integer;
begin
   SetLength(Result, Length(s)*4);
   for i := 0 to Length(s)-1 do
     Move(IntToHex(Ord(s[i+1]), 4), Result[i*4+1], 4);
end;
Ich habe gerade kein Delphi zur Hand, eventuell ließe sich IntToHex() noch effizienter implementieren und inlinen.
"When one person suffers from a delusion, it is called insanity. When a million people suffer from a delusion, it is called religion." (Richard Dawkins)
  Mit Zitat antworten Zitat
Benutzerbild von Bernhard Geyer
Bernhard Geyer

Registriert seit: 13. Aug 2002
Ort: Oberreichenbach
16.473 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#5

AW: MyStrToHex extrem schnell

  Alt 24. Dez 2012, 08:31
Meinst etwa so?:
Für die Methodensignatur kannst du weiter Strings nehmen.
Nur beim Zusammenbauen des Strings den Stringbuilder nehmen:

Delphi-Quellcode:
function MyStrToHex(const s: String): String;
var
  i: Integer;
  StrBuilder: TStringBuilder;
begin
  StrBuilder := TStringBuilder.Create;
  try
    for i := 0 to s.Length - 1 do
      StrBuilder.Append(IntToHex(Ord(s[i]), 4));

    result := STrBuilder.ToString;
  finally
    StrBuilder.Free;
  end;
end;
Ansonsten probier Medium's Version.
Windows Vista - Eine neue Erfahrung in Fehlern.
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe
Online

Registriert seit: 20. Jan 2006
Ort: Lübbecke
6.894 Beiträge
 
Delphi 10.3 Rio
 
#6

AW: MyStrToHex extrem schnell

  Alt 24. Dez 2012, 09:08
Kein Assembler, aber trotzdem recht schnell:

Delphi-Quellcode:
function MyStrToHex(const s: string): string;
const
  hex: array[0..15] of WideChar = '0123456789ABCDEF';
var
  I: Integer;
  W: WordRec;
  P: PChar;
begin
  SetLength(Result, 4*Length(S));
  P := PChar(Result);
  for I := 1 to Length(S) do
  begin
    W := WordRec(S[I]);
    P[0] := hex[W.Hi shr 4];
    P[1] := hex[W.Hi and $F];
    P[2] := hex[W.Lo shr 4];
    P[3] := hex[W.Lo and $F];
    Inc(P, 4);
  end;
end;
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Furtbichler
(Gast)

n/a Beiträge
 
#7

AW: MyStrToHex extrem schnell

  Alt 24. Dez 2012, 09:09
IntToHex sollte sich optimieren lassen, z.B. über eine Lookuptabelle.
  Mit Zitat antworten Zitat
PeterPanino

Registriert seit: 4. Sep 2004
1.266 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#8

AW: MyStrToHex extrem schnell

  Alt 24. Dez 2012, 09:11
Meinst etwa so?:
Für die Methodensignatur kannst du weiter Strings nehmen.
Nur beim Zusammenbauen des Strings den Stringbuilder nehmen:

Delphi-Quellcode:
function MyStrToHex(const s: String): String;
var
  i: Integer;
  StrBuilder: TStringBuilder;
begin
  StrBuilder := TStringBuilder.Create;
  try
    for i := 0 to s.Length - 1 do
      StrBuilder.Append(IntToHex(Ord(s[i]), 4));

    result := STrBuilder.ToString;
  finally
    StrBuilder.Free;
  end;
end;
Ansonsten probier Medium's Version.
Du meintest wahrscheinlich so:
Delphi-Quellcode:
function MyStrToHex(s: string): string;
var
  i: Integer;
  SB: TStringBuilder;
begin
  Result := '';
  SB := TStringBuilder.Create;
  try
    for i := 1 to Length(s) do
      SB.Append(IntToHex(Ord(s[i]), 4));
    Result := SB.ToString;
  finally
    SB.Free;
  end;
end;
Vielen Dank für den Tipp! Gibt es aber eine Erklärung dafür, wieso TStringBuilder.Append schneller sein soll als das traditionelle Zusammenfügen von Strings mit dem Additionszeichen?
  Mit Zitat antworten Zitat
PeterPanino

Registriert seit: 4. Sep 2004
1.266 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#9

AW: MyStrToHex extrem schnell

  Alt 24. Dez 2012, 09:34
Kein Assembler, aber trotzdem recht schnell:

Delphi-Quellcode:
function MyStrToHex(const s: string): string;
const
  hex: array[0..15] of WideChar = '0123456789ABCDEF';
var
  I: Integer;
  W: WordRec;
  P: PChar;
begin
  SetLength(Result, 4*Length(S));
  P := PChar(Result);
  for I := 1 to Length(S) do
  begin
    W := WordRec(S[I]);
    P[0] := hex[W.Hi shr 4];
    P[1] := hex[W.Hi and $F];
    P[2] := hex[W.Lo shr 4];
    P[3] := hex[W.Lo and $F];
    Inc(P, 4);
  end;
end;
Vielen Dank für den Tipp! Diese Version ist tatsächlich noch schneller als die StringBuilder-Version!

Ich habe mir auch überlegt, ob man den Schleifeninhalt nicht etwa in eine inline-Funktion auslagern kann, um die Geschwindigkeit nochmal zu steigern, sehe aber keine Möglichkeit dafür.
  Mit Zitat antworten Zitat
PeterPanino

Registriert seit: 4. Sep 2004
1.266 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#10

AW: MyStrToHex extrem schnell

  Alt 24. Dez 2012, 09:47
Für die Umkehrfunktion verwende ich folgende Konstruktion:
Delphi-Quellcode:
function MyStrToIntSafe(const Value: string; const ExceptionResult: Integer): Integer; inline;
begin
  try
    Result := StrToInt(Value);
  except
    Result := ExceptionResult;
  end;
end;

function MyHexToChar(const s: string; const i: Integer): Char; inline;
begin
  Result := Chr(MyStrToIntSafe('$' + Copy(s, i, 4), 63));
end;

function MyHexToStr(s: string): string;
var
  i, L: Integer;
begin
  Result := '';
  L := Length(s);
  i := 1;
  while i < L do
  begin
    Result := Result + MyHexToChar(s, i);
    Inc(i, 4);
  end;
end;
Hier habe ich durch Auslagerung von Schleifeninhalten in inline-Funktionen nochmals eine Geschwindigkeitssteigerung erreicht.
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 3  1 23   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 08:53 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf