AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) Delphi WNetENumResource -> Unterschiede auf Win7 und Win 8 / 8.1

WNetENumResource -> Unterschiede auf Win7 und Win 8 / 8.1

Ein Thema von ChrisE · begonnen am 22. Okt 2013 · letzter Beitrag vom 13. Nov 2013
Antwort Antwort
Benutzerbild von ChrisE
ChrisE

Registriert seit: 15. Feb 2006
Ort: Hechingen
504 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#1

WNetENumResource -> Unterschiede auf Win7 und Win 8 / 8.1

  Alt 22. Okt 2013, 14:24
Hallo Forum,

Aufgrund einer Randbemerkung hatte ich in diesem Thread meinen "vermeintlichen" Wissenstand geschrieben.

Kurz erklärt: UserA ist Mitglieder Administratorgruppe unter Windows 7 bzw. 8 und UAC ist aktiviert. Startet UserA das Programm ganz normal kann man per WNetEnumResource die Netzlaufwerke bestimmen, die immer wieder verbunden werden sollen / MSDN-Library durchsuchenRESOURCE_REMEMBERED. Startet UserA das Programm mit erhöhten Rechten - aber noch als er selber - liefert MSDN-Library durchsuchenWNetENumResource unter Windows 7 weiterhin die Liste der Netzlaufwerke. Unter Windows 8 bekommt man eine leere Liste. Daher meine Annahme, dass man jetzt unter Windows 8 die Netzlaufwerke im erhöhten Rechte-Kontext gar nicht mehr hat.

Jetzt zeigt sich, das mit MSDN-Library durchsuchenWNetGetConnection das ganze auch mit erhöhten Rechten funktioniert, wenn man einfach alle Laufwerksbuchstaben "durchprobiert".

Und hier die Frage:
Was ist an den Routinen falsch, wo habe ich den Fehler gemacht?

Unten der Quelltext der beiden Möglichkeiten und angehängt ein Beispielprojekt - erstellt mit XE2:
Delphi-Quellcode:
function GetAllNetDrivesPerEnum(LaufWerke_Lokal: TStrings; LaufWerke_Remote: TStrings): DWord;
const
  cbBuffer: DWord = 16384;
  cEntries: DWord = DWord(-1);
var
  dwResult: DWord;
  hEnum: THandle;
  lpnrDrv: array [0 .. 16384 div SizeOf(TNetResource)] of TNetResource; // pointer to enumerated structures
  i: Integer;
  lname: string;
  rname: string;
begin
  result := NO_ERROR;
  dwResult := WNetOpenEnum(RESOURCE_REMEMBERED, RESOURCETYPE_ANY, 0, nil, hEnum);

  if (dwResult <> NO_ERROR) then
  begin
    result := dwResult;
    Exit;
  end;
  
  repeat
    FillChar(lpnrDrv, length(lpnrDrv) * SizeOf(TNetResource), #0);
    cEntries := DWord(-1);
    dwResult := WNetEnumResource(hEnum, cEntries, @lpnrDrv, cbBuffer);
    if (dwResult = NO_ERROR) then
    begin
      for i := 0 to cEntries - 1 do
      begin
        if (lpnrDrv[i].lpLocalName <> nil) and // Lokaler Name ist da (X: Y: Z: etc.)
          (lpnrDrv[i].lpRemoteName <> nil) and // Remote Name ist da (\\Server\Freigabe)
          (lpnrDrv[i].dwType = RESOURCETYPE_DISK) and // Die Resource ist vom Typ Disk
          (lpnrDrv[i].dwDisplayType = RESOURCEDISPLAYTYPE_SHARE) then // Die Resource sollte lauf Windows im Bereich Shares angezeigt werden
        begin
          lname := lpnrDrv[i].lpLocalName;
          lname := Trim(lname);
          rname := lpnrDrv[i].lpRemoteName;
          rname := Trim(rname);
          if (lname <> '') and (rname <> '') then
          begin
            if LaufWerke_Lokal.IndexOf(lname) = -1 then
            begin
              LaufWerke_Lokal.Add(lpnrDrv[i].lpLocalName);
              LaufWerke_Remote.Add(lpnrDrv[i].lpRemoteName);
            end;
          end;
        end;
      end;
    end else if dwResult <> ERROR_NO_MORE_ITEMS then
    begin
      result := dwResult;
      break;
    end;
  until (dwResult = ERROR_NO_MORE_ITEMS);
  WNetCloseEnum(hEnum);
  if dwResult = ERROR_NO_MORE_ITEMS then
    result := NO_ERROR;
end;

function GetAllNetDrivesPerDirectTest(LaufWerke_Lokal: TStrings; LaufWerke_Remote: TStrings): Boolean;
var
  c: Char;
  laufwerk: PChar;
  remotename: PChar;
  bufs: DWord;
  res: DWord;
begin
  GetMem(laufwerk, MAX_PATH * SizeOf(Char));
  GetMem(remotename, MAX_PATH * SizeOf(Char));
  try
    try
      for c in ['a' .. 'z'] do
      begin
        bufs := MAX_PATH * SizeOf(Char);
        FillChar(laufwerk[0], bufs , #0);
        FillChar(remotename[0], bufs, #0);

        laufwerk[0] := c;
        laufwerk[1] := ':';
        res := WNetGetConnection(@laufwerk[0], @remotename[0], bufs);
        if (res = ERROR_SUCCESS) (*or (res = ERROR_NOT_CONNECTED)*) or (res = ERROR_CONNECTION_UNAVAIL) then
        begin
          LaufWerke_Lokal.Add(trim(laufwerk));
          LaufWerke_Remote.Add(trim(remotename));
        end;
      end;
    finally
      FreeMem(remotename);
      FreeMem(laufwerk);
    end;
  except
    result := FALSE;
  end;
end;
Angehängte Dateien
Dateityp: zip Projekt20.zip (619,6 KB, 15x aufgerufen)
Christian E.
Es gibt 10 Arten von Menschen, die die Binär lesen können und die die es nicht können

Delphi programming rules
  Mit Zitat antworten Zitat
Benutzerbild von ChrisE
ChrisE

Registriert seit: 15. Feb 2006
Ort: Hechingen
504 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#2

AW: WNetENumResource -> Unterschiede auf Win7 und Win 8 / 8.1

  Alt 23. Okt 2013, 13:46
- PUSH -
Christian E.
Es gibt 10 Arten von Menschen, die die Binär lesen können und die die es nicht können

Delphi programming rules
  Mit Zitat antworten Zitat
Benutzerbild von ChrisE
ChrisE

Registriert seit: 15. Feb 2006
Ort: Hechingen
504 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#3

AW: WNetENumResource -> Unterschiede auf Win7 und Win 8 / 8.1

  Alt 4. Nov 2013, 08:02
Hallo Miteinander,

ich versuche nochmal ganz vorsichtig einen Push. Vielleicht stolpert ja jemand drüber

Gruß, Chris
Christian E.
Es gibt 10 Arten von Menschen, die die Binär lesen können und die die es nicht können

Delphi programming rules
  Mit Zitat antworten Zitat
Kyro

Registriert seit: 16. Aug 2005
Ort: Wien
45 Beiträge
 
Delphi XE2 Professional
 
#4

AW: WNetENumResource -> Unterschiede auf Win7 und Win 8 / 8.1

  Alt 10. Nov 2013, 12:35
Das Verhalten von "WNetEnumResource" ist aus meiner Sicht genau so wie es sein soll (auch unter Windows 8)

Vorsicht:
Unter Windows 8 hat sich der Zugriff zwischen UAC-elevated bzw. non-elevated verbundenen Netzlaufwerken und UAC-elevated bzw. non-elevated Prozesse offensichtlich geändert...

Hier zum Verständnis...

unter Windows 7 (mit aktivierter UAC)...
1) "Normale" CMD -> net use R: \\meinserver\freigabe1
2) "Normale" CMD -> net use S: \\meinserver\freigabe2
3) "Als Admin ausgeführte" CMD -> net use T: \\meinserver\freigabe3
4!) In einer "Normalen" NOTEPAD (Speichern unter...) hast du Zugriff auf R:, S: und T: (Das Laufwerke T: ist jedoch nicht auf Anhieb verbunden)
5!) In einer "Als Admin ausgeführten" NOTEPAD (Speichern unter...) hast du Zugriff auf R:, S: und T: (Die Laufwerke R: und S: sind jedoch nicht auf Anhieb verbunden)
6) "Normale" CMD -> net use
7) "Als Admin ausgeführte" CMD -> net use

unter Windows 8 (mit aktivierter UAC)...
1) "Normale" CMD -> net use R: \\meinserver\freigabe1
2) "Normale" CMD -> net use S: \\meinserver\freigabe2
3) "Als Admin ausgeführte" CMD -> net use T: \\meinserver\freigabe3
4!) In einer "Normalen" NOTEPAD (Speichern unter...) hast du nur Zugriff auf R: und S:
5!) In einer "Als Admin ausgeführten" NOTEPAD (Speichern unter...) hast nur Zugriff auf T:
6) "Normale" CMD -> net use
7) "Als Admin ausgeführte" CMD -> net use

Spätestens bei Punkt 6 und 7 solltest du das unterschiedliche Verhalten zwischen Windows 7 und Windows 8 erkennen
Unter Windows 7 kann man "alle" Netzlaufwerke auflisten -> Jedoch sind nur die "eigenen" Netzlaufwerke verbunden -> Der "Trick" hierbei ist, dass man auf ein "nicht verbundenes" Netzlaufwerk zugreift wird es auch im derzeit verwendeten UAC-Kontext sofort verbunden. (Was auch funktioniert sofern die Berechtigungen es zulassen).

Unter Windows 8 siehst du nur jene Laufwerke die im jeweiligen UAC-Kontext (Heißt das so?) verbunden wurden.

Ich bin mir ziemlich sicher dass es die Möglichkeit gibt um dieses Verhalten zwecks Abwärtskompatibilität zu steuern. (Policies od. Registry)

Nachtrag:
Ja gibt es...
HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Windows/CurrentVersion/Policies/System [EnableLinkedConnections (DWORD) = 1]
(Anschließend PC neu starten, dann klappt's auch mit deinem Programm wieder)

Zu deinem Problem -> siehe auch http://support.microsoft.com/kb/2019185

Geändert von Kyro (10. Nov 2013 um 13:03 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von ChrisE
ChrisE

Registriert seit: 15. Feb 2006
Ort: Hechingen
504 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#5

AW: WNetENumResource -> Unterschiede auf Win7 und Win 8 / 8.1

  Alt 12. Nov 2013, 12:30
Hallo Kyro,

vielen Dank - du hast damit genau das beschrieben, was ich mir schon gedacht habe. Danke für Deine Ausführung. Leider, ändert das nichts an der Problematik, dass man bis Windows 7 mit WNetEnumResource sehr zuverlässige die Netzlaufwerke unabhängig vom Account / UAC festellen konnte und ab Windows 8 nur dann wenn die Registry angepasst wurde. Nur passiert diese Anpassung viel zu selten im freien Umfeld da draußen. Ergo - kann ich mit nicht mehr auf diese API-Funktion verlassen :-/

[Schmipf AN]Wenn ich doch mehr Rechte habe als eval. Process des selben Benutzers, warum sehe ich dann nicht was nicht eval. Prozesse sehen[Schimpf AUS]

Auf jeden Fall ist erstmal die Alternative klar -> wenn Windows 8 oder höher und ProcessHasAdminRights -> Durchprobieren der Laufwerksbuchstaben anstatt WNetEnumResource - zumindest ist das mein Fazit daraus.

Dir - Kryo - nochmals danke für die Aufarbeitung und Bestätigung.

Gruß und eine schöne Woche,

Chris
Christian E.
Es gibt 10 Arten von Menschen, die die Binär lesen können und die die es nicht können

Delphi programming rules
  Mit Zitat antworten Zitat
Kyro

Registriert seit: 16. Aug 2005
Ort: Wien
45 Beiträge
 
Delphi XE2 Professional
 
#6

AW: WNetENumResource -> Unterschiede auf Win7 und Win 8 / 8.1

  Alt 12. Nov 2013, 22:41
Ich muss meine vorherige Info leicht abändern - denn das Verhalten hat sich nicht mit Windows 8 geändert...
Das Verhalten gab es schon mit Windows Vista und auch mit Windows 7. Es dürfte also mehr Faktoren geben als nur dem Registry Key und eine aktivierte UAC wann es sich so verhält wie du es bereits von Windows 8/8.1 kennst!
Ich würde jedenfalls davon abraten dem ganzen einem Windows 8 Check o.ä. zu verpassen.

Aus meiner Sicht arbeitet "WNetEnumResource" nach wie vor wie es sein soll (Es listet nämlich die Netzlaufwerke genauso auf wie es z.B.: ein TFileOpenDialog machen würde)

Anderes Szenario - gleiches Problem...
UserA ist kein Administrator, und er macht einen rechtsklick auf dein Programm -> "Als Administrator ausführen..." -> nun gibt er die Credentials von UserB (der Administrator ist) ein -> Das Programm startet mit den Rechten von UserB -> In dem Fall wirst du die Laufwerke von UserA ebenfalls nicht sehen - es sei denn du berücksichtigst exakt dieses Szenario.

Unabhängig von dem Problem, wirst du noch in ganz andere Probleme mit UAC laufen wenn du nicht im vorhinein UAC-Aware programmierst.

Falls du ausschließlich die Laufwerke des Benutzers anzeigen lassen willst (und nicht darauf mit dem Laufwerksbuchstaben zugreifen musst) könntest du folgende Quick&Dirty Routine verwenden:

Code:
procedure GetUserNetDrivesPerReg(var LaufWerke_Lokal: TStrings; LaufWerke_Remote: TStrings);
var i: Integer;
var Reg: TRegistry;
var ValidEntry: Boolean;
begin
  Reg := TRegistry.Create(KEY_READ or KEY_WOW64_64KEY);
  try
    Reg.RootKey := HKEY_CURRENT_USER;
    if Reg.OpenKey('Network',False) then begin
      Reg.GetKeyNames(LaufWerke_Lokal);
      Reg.CloseKey;
      for i := Pred(LaufWerke_Lokal.Count) downto 0 do begin
        ValidEntry := False;
        if Reg.OpenKey('Network\'+LaufWerke_Lokal[i],False) then begin
          if Reg.ValueExists('RemotePath') then begin
            LaufWerke_Remote.Add(Reg.ReadString('RemotePath'));
            LaufWerke_Lokal[i] := LaufWerke_Lokal[i]+':';
            ValidEntry := True;
          end;
          Reg.CloseKey;
        end;
        if not ValidEntry then LaufWerke_Lokal.Delete(i);
      end;
    end;
  finally
    Reg.Free;
  end;
end;
  Mit Zitat antworten Zitat
Benutzerbild von ChrisE
ChrisE

Registriert seit: 15. Feb 2006
Ort: Hechingen
504 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#7

AW: WNetENumResource -> Unterschiede auf Win7 und Win 8 / 8.1

  Alt 13. Nov 2013, 06:21
Ich muss meine vorherige Info leicht abändern - denn das Verhalten hat sich nicht mit Windows 8 geändert...
Das Verhalten gab es schon mit Windows Vista und auch mit Windows 7. Es dürfte also mehr Faktoren geben als nur dem Registry Key und eine aktivierte UAC wann es sich so verhält wie du es bereits von Windows 8/8.1 kennst!
Ich würde jedenfalls davon abraten dem ganzen einem Windows 8 Check o.ä. zu verpassen.
Hmm - sehe ich nicht so. Meine Testprogramm liefert eben unter Windows Vista und 7 mit WNetEnumResource von UserA immer die Netzlaufwerke - unabhängig ob er es normal oder priviligiert ausführt. Erst ab Windows 8 verändert sich das. Einen Unterschied beim priviligierten Prozess ist ja nur die Tatsache, dass das Netzlaufwerk "noch" nicht verbunden ist - im Explorer z.B. ein rotes Kreuz hätte. Aber es läßt sich auflisten.

Aus meiner Sicht arbeitet "WNetEnumResource" nach wie vor wie es sein soll (Es listet nämlich die Netzlaufwerke genauso auf wie es z.B.: ein TFileOpenDialog machen würde)
Hmm - sehe ich auch anders, da sich bei vermeintlich gleichen Verhalten von außen unterschiedliche Ergebnisse präsentieren (Windows 7 vs. 8 bei selben User der ein Programm jeweils mit und ohne Privilegien ausführt)

Anderes Szenario - gleiches Problem...
UserA ist kein Administrator, und er macht einen rechtsklick auf dein Programm -> "Als Administrator ausführen..." -> nun gibt er die Credentials von UserB (der Administrator ist) ein -> Das Programm startet mit den Rechten von UserB -> In dem Fall wirst du die Laufwerke von UserA ebenfalls nicht sehen - es sei denn du berücksichtigst exakt dieses Szenario.
Aus meiner Sicht völlig andere Problemstellung, da hier ein Programm in einem völlig anderen User-Kontext ausgeführt wird und nicht nur in einem anderem "Rechtekontext". Das UserB die Netzlaufwerke nicht sieht von UserA ist logisch und nachvollziehbar und schon viele Windowsversionen so. Es liegt hier keine unterschiedliches Verhalten einer API-Funktion vor wie bei meiner Ursprünglichen Fragestellung. (BTW: Userkonten sind meiner Meinung nach genau für diesen Fall da - unterschiedliche Einstellungen und Rechte - UserB muss/soll nicht sehen was UserA gemacht/eingestellt hat)

Unabhängig von dem Problem, wirst du noch in ganz andere Probleme mit UAC laufen wenn du nicht im vorhinein UAC-Aware programmierst.
Das wird zwar Offtopic, aber mich würde schon interessieren was du da so an Links im Angebot hättest zum nachlesen. Ich habe nämlichn ie wirklich darauf geachtet :-/ - also bewusst. Bisher bin ich auf keine Probleme gestoßen mit aktivierter UAC. Vielleicht mache ich aber auch zu wenig systemnahe Dinge in meinem Programmen.

Gruß, Chris
Christian E.
Es gibt 10 Arten von Menschen, die die Binär lesen können und die die es nicht können

Delphi programming rules
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 13:04 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz