AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

ClickHandler mehrmals benutzten?

Ein Thema von Crocotronic · begonnen am 25. Jan 2014 · letzter Beitrag vom 2. Feb 2014
Antwort Antwort
Crocotronic

Registriert seit: 9. Mai 2013
258 Beiträge
 
#1

ClickHandler mehrmals benutzten?

  Alt 25. Jan 2014, 13:53
Hallo,
ich versuche gerade, einen NavBarClickHandler mehrmals zu benutzten, was ja sehr sinnvoll ist. Wenn ich jetzt z.B. auf einem ViewController 2 Buttons in der Leiste hab, dann will ich ja nicht extra 2 Klassen schreiben, sondern lieber sowas machen:
Delphi-Quellcode:
type
  IUINavBarClickHandler = interface(NSObject)
  ['{6D8473BD-461C-479D-ADF6-59F933EDA57B}']
    procedure Click; cdecl;
  end;

  TUINavBarClickHandler = class(TOCLocal)
  private
   FKind: Integer;
  protected
   function GetObjectiveCClass: PTypeInfo; override;
  public
   procedure Click; cdecl;
  end;
Beim Kreieren setzt ich dann das FKind. Beim Klicken führt er dann abhängig von FKind eine Funtkion aus. Nur leider ist das Attribut entweder 0 oder ein zufällig Zahl.
Warum kann ich das so nicht machen? Hat jemand eine Lösung für mein Problem?

Viele Grüße
Croco
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.519 Beiträge
 
Delphi 12 Athens
 
#2

AW: ClickHandler mehrmals benutzten?

  Alt 25. Jan 2014, 14:25
Dein TUINavBarClickHandler implementiert wirklich nicht das Inferface IUINavBarClickHandler?

Zitat:
Warum kann ich das so nicht machen? Hat jemand eine Lösung für mein Problem?
Hab keine wirkliche Idee, aber da sonst alle wichtigen Infos fehlen, ist das auch kein Wunder.
Zitat:
Beim Kreieren setzt ich dann das FKind.
Wie?
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Crocotronic

Registriert seit: 9. Mai 2013
258 Beiträge
 
#3

AW: ClickHandler mehrmals benutzten?

  Alt 25. Jan 2014, 15:05
Ich hab mir das ganze von TMS abgeguckt (aus TMSNativeUIToolbar). Dort steht folgendens:
Delphi-Quellcode:
  {$IFDEF IOS}
  IUIToolBarEventHandler = interface(NSObject)
  ['{1ACF3DFA-A90B-4F06-ACF1-8A40076BC9ED}']
    procedure Click(Sender: Pointer); cdecl;
  end;

  TUIToolBarEventHandler = class(TOCLocal)
  private
    FControl: TTMSFMXNativeUIToolBar;
  protected
    function GetObjectiveCClass: PTypeInfo; override;
  public
    //IUIToolBarEventHandler
    procedure Click(Sender: Pointer); cdecl;
  end;
  {$ENDIF}
und das Kreieren:
Delphi-Quellcode:
  FToolBarEventHandler := TUIToolBarEventHandler.Create;
  FToolBarEventHandler.FControl := Self;
Dachte ich kann das gleiche mit einem Integer machen, aber scheinbar war der Gedanke falsch

Meine Anwendung für das Ding sieht so aus:
Delphi-Quellcode:
 ToolbarItem1:= FMX.TMSNativeUICore.TUIBarButtonItem.Create;
 ToolBarClickHandler:= TUIToolBarClickHandler.Create;
 ToolBarClickHandler.FKind:= 2;
 ToolbarItem1.initWithBarButtonSystemItem(UIBarButtonSystemItemRefresh, ToolBarClickHandler.GetObjectID, sel_getUid('Click'));
 bis[0]:= (ToolbarItem1 as ILocalObject).GetObjectID;

 arr:= TNSArray.Wrap(TNSArray.OCClass.arrayWithObjects(@bis[0], Length(bis)));
 VPlanView.ViewController.navigationItem.setRightBarButtonItems(arr);
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#4

AW: ClickHandler mehrmals benutzten?

  Alt 25. Jan 2014, 15:07
Geb der Instanz doch eine anonyme Methode mit, dann hast etwas Universelles
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Crocotronic

Registriert seit: 9. Mai 2013
258 Beiträge
 
#5

AW: ClickHandler mehrmals benutzten?

  Alt 25. Jan 2014, 15:30
Was dann so aussehen würde?
Delphi-Quellcode:
type
  IUIToolbarClickHandler = interface(NSObject)
  ['{6D8473BD-461C-479D-ADF6-59F933EDA57B}']
    procedure Click; cdecl;
  end;

  THandlerProc = reference to procedure;

  TUIToolBarClickHandler = class(TOCLocal)
  private
   FMyProc: THandlerProc;
  protected
   function GetObjectiveCClass: PTypeInfo; override;
  public
   procedure Click; cdecl;
  end;


function TUIToolBarClickHandler.GetObjectiveCClass;
begin
 Result:= TypeInfo(IUIToolbarClickHandler);
end;

procedure TUIToolBarClickHandler.Click;
begin
 FMyProc;
end;
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#6

AW: ClickHandler mehrmals benutzten?

  Alt 25. Jan 2014, 15:47
Jo, obwohl, so ist es schöner zu benutzen
Delphi-Quellcode:
type
  IUIToolbarClickHandler = interface(NSObject)
  ['{6D8473BD-461C-479D-ADF6-59F933EDA57B}']
    procedure Click; cdecl;
  end;

  THandlerProc = reference to procedure;

  TUIToolBarClickHandler = class(TOCLocal)
  private
    FHandler: THandlerProc;
  protected
    function GetObjectiveCClass: PTypeInfo; override;
    constructor Create( Handler : THandlerProc );
  public
    class function Construct( Handler : THandlerProc ) : IUIToolbarClickHandler;
    procedure Click; cdecl;
  end;

class function TUIToolBarClickHandler.Construct( AHandler : THandlerProc ) : IUIToolbarClickHandler;
begin
  Result := Self.Create( AHandler );
end;

constructor TUIToolBarClickHandler.Create( AHandler : THandlerProc );
begin
  inherited Create;
  FHandler := AHandler;
end;

function TUIToolBarClickHandler.GetObjectiveCClass;
begin
 Result:= TypeInfo(IUIToolbarClickHandler);
end;

procedure TUIToolBarClickHandler.Click;
begin
  if Assigned( FHandler ) then
    FHandler(); // mit Klammern ist auf jeden Fall die procedure gemeint und nicht der Variablenwert ;o)
end;
und dann nur noch
Delphi-Quellcode:
var
  HelloWorldHandler : IUIToolbarClickHandler;

HelloWorldHandler := TUIToolBarClickHandler.Construct(
  procedure
  begin
    ShowMessage( 'Hello World' );
  end );
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)

Geändert von Sir Rufo (25. Jan 2014 um 15:50 Uhr)
  Mit Zitat antworten Zitat
Crocotronic

Registriert seit: 9. Mai 2013
258 Beiträge
 
#7

AW: ClickHandler mehrmals benutzten?

  Alt 25. Jan 2014, 16:11
Sobald ich das dann in sowas hier rein packe und das ToolbarItem klicke, ist das Attribut null (bzw assigned = false)
Delphi-Quellcode:
 ToolbarItem:= TUIBarButtonItem.Create;
 ToolBarClickHandler := TUIToolBarClickHandler.Construct(
  procedure
  begin
   showmessage('Test');
  end );

 ToolbarItem.initWithBarButtonSystemItem(UIBarButtonSystemItemRefresh, ToolBarClickHandler.GetObjectID, sel_getUid('Click'));
 VPlanView.ViewController.navigationItem.setRightBarButtonItem(ToolbarItem,false);
  Mit Zitat antworten Zitat
Crocotronic

Registriert seit: 9. Mai 2013
258 Beiträge
 
#8

AW: ClickHandler mehrmals benutzten?

  Alt 2. Feb 2014, 12:22
Es funktioniert doch...der Handler muss nur ein Attribut von der Klasse sein (-> FToolBarClickHandler)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 10:14 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz