Den Delegaten nachträglich ändern - Unterschiedliches Verhalten

[Der schöne Günther]

Nein, was mich wundert ist die Tatsache dass ich entweder eine Referenz auf den Delegaten oder eine Referenz auf die "äußere" Klasse (TContainerClass) bekomme. Was ich nun bekommen werde kann ich nicht sehen. Denn das hängt davon ab, ob die "gefragte" Instanz (TContainerClass) nun intern an eine Klasse oder ein Interface delegiert.

Ich gehe der Idee mit einem "Zwischen-Delegat" mal weiter. Ich habe in so ziemlich jedem Bereich gewaltige Bildungslücken: Das Stellvertreter-Pattern kenne ich nur vom Namen her. Ich glaube, so etwas schwebt mir vor...

// Habe ich's?

• Die äußere Klasse (TContainerclass) delegiert an ein Interface. Somit liefert Supports eine Referenz auf den Delegaten und nicht TContainerClass
• TContainerClass weiß, dass sie ihren Delegaten möglicherweise ändern wird. Also delegiert sie nicht direkt an die gewünschte Instanz, sondern einen Proxy
• Ich habe keine Ahnung ob man das nun "Proxy" nennen darf oder ich hier Dinge durcheinander werfen
• Wenn die äußere Klasse nun den wirklichen Delegaten ändern will, injiziert sie auf ihrem Proxy einfach eine andere Instanz.
• Supports liefert weiterhin nur Referenzen auf den Proxy
• Der Proxy implementiert zwar alle Interface-Methoden nochmal manuell, aber das soll mir recht sein. Das ist schließlich auch genau seine Aufgabe und ich mülle mir mit so etwas nicht meine TContainerClass zu.

Die äußere Klasse

Delphi-Quellcode:

   IProxy<T:IInterface> = interface
   ['{AF691ABC-D561-4E5D-BFF1-AC30D97F007A}']
      procedure setDelegate(const delegate: T);
      function getDelegate(): T;
   end;

   TSomeInterfaceProxy = class(TInterfacedObject, ISomeInterface, IProxy<ISomeInterface>)
      private var
         myDelegate: ISomeInterface;

      public
          constructor Create(const realDelegate: ISomeInterface); overload;

         // ISomeInterface
         procedure someProc();

         // IProxy<ISomeInterface>
            procedure setDelegate(const delegate: ISomeInterface);
            function getDelegate(): ISomeInterface;
   end;

[Sir Rufo]

Häh, bei beiden gezeigten Varianten wird das Interface an die interne Instanz weitergeleitet.
Also immer TMessager (nicht eher TMessenger ?)

[Der schöne Günther]

Ja, "Messenger" nicht "Messager". Ich bin wohl schon zu lange wach.

(Meinen letzten Beitrag habe ich in der Zwischenzeit aktualisiert)

Ja, weitergeleitet wird das Interface immer. Der Punkt ist dass ich in einem Fall direkt die Referenz auf den Delegaten bekomme. Das äußere Objekt könnte ich in der Zwischenzeit sogar freigeben. Das kann sogar gewollt sein.
Im anderen Fall zeigt meine Referenz NICHT auf den Delegaten - Er zeigt auf die äußere Klasse. Ändert die Klasse ihren Delegaten, spreche ich mit meiner Referenz immer den aktuellen Delegaten der Klasse an. Das finde ich toll! Das hat aber den Schwachpunkt, dass die Klasse ihren Delegaten intern als Klasse (und nicht als Interface) referenzieren muss.

Und nun glaube ich (mit dem Zwischen-Delegaten) eine Lösung zu haben.

[Sir Rufo]

Fast ... so sollte das gehen

Delphi-Quellcode:

  ISomeInterface = interface
    ['{A06F92AD-9E22-4EA9-9770-3B02C2AE8E5A}']
    procedure SomeProc( );
  end;

  IProxy<T : IInterface> = interface
    //['{AF691ABC-D561-4E5D-BFF1-AC30D97F007A}'] nicht bei Generics!
    procedure setDelegate( const delegate : T );
    function getDelegate( ) : T;
  end;

  TSomeInterfaceProxy = class( TInterfacedObject, ISomeInterface, IProxy<ISomeInterface> )
  private
    myDelegate : ISomeInterface;
  private
    constructor Create( const realDelegate : ISomeInterface );

    // ISomeInterface Delegate
    procedure DelegateSomeProc( );
    procedure ISomeInterface.SomeProc = DelegateSomeProc;

    // IProxy<ISomeInterface>
    procedure setDelegate( const delegate : ISomeInterface );
    function getDelegate( ) : ISomeInterface;
  public
    class function Construct( const realDelegate : ISomeInterface ) : ISomeInterface;
    class function ConstructProxy( const realDelegate : ISomeInterface ) : IProxy<ISomeInterface>;
  end;

{ TSomeInterfaceProxy }

class function TSomeInterfaceProxy.Construct( const realDelegate : ISomeInterface ) : ISomeInterface;
begin
  Result := TSomeInterfaceProxy.Create( realDelegate );
end;

class function TSomeInterfaceProxy.ConstructProxy( const realDelegate : ISomeInterface ) : IProxy<ISomeInterface>;
begin
  Result := TSomeInterfaceProxy.Create( realDelegate );
end;

constructor TSomeInterfaceProxy.Create( const realDelegate : ISomeInterface );
begin
  inherited Create;
  myDelegate := realDelegate;
end;

procedure TSomeInterfaceProxy.DelegateSomeProc;
begin
  getDelegate.SomeProc;
end;

function TSomeInterfaceProxy.getDelegate : ISomeInterface;
begin
  Result := myDelegate;
end;

procedure TSomeInterfaceProxy.setDelegate( const delegate : ISomeInterface );
begin
  myDelegate := delegate;
end;

und dann so benutzen

Delphi-Quellcode:

var
  LProxy : IProxy<ISomeInterface>;
  LSome : ISomeInterface;

LProxy := TSomeInterfaceProxy.Construct( TSome.Create );
Supports( LProxy, ISomeInterface, LSome );

LSome.SomeProc; // TSome.SomeProc
LProxy.setDelegate( TSomeOther.Create );
LSome.SomeProc; // TSomeOther.SomeProc

[Der schöne Günther]

Fantastisch! *händereib*

Spontan und nach kurzem Durchtesten würde ich sagen, das ist exakt, was ich wollte!

Ich würde weiterhin noch sagen, die Method Resolution Clause ist nicht nötig, gesetzt man hat keine Namenskonflikte und kann die Methode "DelegateSomeProc" im Proxy gleich "someProc" nennen.
Letztendlich könnte man sich jetzt noch Gedanken machen, was das sinnvollste wäre, wollte man eine leere Referenz injizieren.

Großartig, ich freue mich wirklich! Ich war anfangs ziemlich überrumpelt als ich gesehen habe, dass man unter Umständen direkt eine Referenz auf den Delegaten bekommt!

[Uwe Raabe]

Bei Verwendung von implements muss das implementierende Objekt entweder das besagte Interface bereitstellen (mittels QueryInterface) oder das Interface implementieren (sprich: die Methoden bereitstellen). Im ersten Fall bekommt man einen Interface-Zeiger auf den Implementer, im anderen auf den Container.

Wenn der Implementer von TAggregatedObject abgeleitet wird ohne das ein Interfacename in der Deklaration auftaucht, dann auch wird kein Interface-Zeiger zurückgegeben. Andernfalls würde das schon geschehen, aber durch die Implementierung von QueryInterface gelangt man für weitere Interfaces doch wieder zum Controller/Container.

Beim ersten Ansatz (TAggregatedObject ohne Interface-Deklaration) reicht es auch, wenn nur Teile des Interfaces von der Implementor-Klasse bereitgestellt werden, solange die fehlenden Methoden vom Container implementiert werden.

Delphi-Quellcode:

type
  IMyInterface = interface
    [<GUID>]
    procedure Foo;
    procedure Bar;
  end;

  TMyImplementor = class(TAggregatedObject)
    procedure Foo;
  end;

  TMyContainer = class(TInterfacedObject, IMyInterface)
  ...
  protected
    procedure Bar;
    property MyImplementor: TMyImplementor read GetMyImplementor implements IMyInterface;
  end;

[Stevie]

Tja, man lernt jeden Tag was neues. Das Verhalten beim Delegieren an ein Objekt war mir neu, aber sehr interessantes und u.U. nützliches Verhalten.

@Günther
In deinem Beispiel im Eingangspost hast du übrigens ein Speicherleck (bzw verfrühte Freigabe einer Instanz).

Der Supports Aufruf auf container führt dazu, dass danach deine container Instanz freigegeben wird. Auch hier sollte container schon ein Interface sein, damit da nix schief geht.

Keine Ahnung, was der XE5 Debugger anzeigt, aber bei mir (XE) zeigt er im Fall, dass die Eigenschaft TMessage zurückgibt nur Pointer(...) as IMessageInterface an. Ein (messageIntf as TObject).ClassName liefert mir dann TMessager.

Ich kann also die Aussage

Zitat:

Nach dem Aufruf von Supports(..) haben wir in unserer Interface-Variable eine Referenz auf die TContainerClass -Instanz!

nicht nachvollziehen.