AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein Delphi FormularArray den richtigen Create aufrufen! Wie?

FormularArray den richtigen Create aufrufen! Wie?

Ein Thema von Mavarik · begonnen am 30. Jan 2014 · letzter Beitrag vom 5. Feb 2014
Antwort Antwort
Seite 1 von 5  1 23     Letzte » 
Benutzerbild von Mavarik
Mavarik

Registriert seit: 9. Feb 2006
Ort: Stolberg (Rhld)
4.123 Beiträge
 
Delphi 10.3 Rio
 
#1

FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 13:19
Neuer Versuch!

Gegeben sein TForm42,TForm43

Delphi-Quellcode:
type
   TF : Array[1..2] of TForm;
Um jetzt ein Formular zu erzeugen, fehlt mir aber der Typ (TForm32.Create(Self)). Den bekomme ich doch sicher aus der RTTI oder?

Habe es jetzt umgesetzt mit:
Delphi-Quellcode:
type
  TShowForm = reference to Function(Owner : TComponent):TForm;
var
  F : Array [1..2] of TShowForm;
begin
  F[1] := Function(Owner:TComponent):TForm
            begin
              Result := TForm42.Create(Owner);
            end;
  F[2] := Function(Owner:TComponent):TForm
            begin
              result := TForm43.Create(Owner);
            end;
  F[1](self).Show;
end;
Jemand ne schönere Idee?

Mavarik

Geändert von Mavarik (30. Jan 2014 um 13:29 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.014 Beiträge
 
Delphi 12 Athens
 
#2

AW: FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 13:45
Delphi-Quellcode:
var
  F : Array [1..2] of TFormClass;
begin
  F[1] := TForm42;
  F[2] := TForm43;
  F[1].Create(Self).Show;
end;
So?

Nja, und wie du schon erkannt hasst:
Via TRTTI die Klasse suchen, als TFormClass casten und dann F.Create(Self).Show; .
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#3

AW: FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 13:47
Delphi-Quellcode:
var
  F : Array [1..2] of TFormClass;
begin
  F[1].Create( Self ).Show;
end;
Und wenn du deine Forms registrierst mit Delphi-Referenz durchsuchenRegisterClass oder Delphi-Referenz durchsuchenRegisterClassAlias dann kannst du dir die über den Namen suchen Delphi-Referenz durchsuchenFindClass
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)

Geändert von Sir Rufo (30. Jan 2014 um 13:50 Uhr)
  Mit Zitat antworten Zitat
Jumpy

Registriert seit: 9. Dez 2010
Ort: Mönchengladbach
1.733 Beiträge
 
Delphi 6 Enterprise
 
#4

AW: FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 13:48
Geht das nicht irgendwie in Richtung factory patterns? Quasi eine "Formfactory"?


Edit: Wahrsch. hab ich die Frage nicht verstanden, dann vergesst den ganzen Rest.


Sowas hab ich mit Tips von hier mal für Frames gemacht.

Delphi-Quellcode:
unit uFrameFactory;

interface

uses Projekt,
     fBaseFrame, fLAFrame, fKSTFrame, fSTOFrame,
     Controls, Classes, ADODB;

Type TBaseFrameClass = class of TBaseFrame;

Type TBaseFrameClassRec = record
  Name:String;
  Header:String;
  Klasse:TBaseFrameClass;
  end;

const FrameClassList: Array[0..8{ggf. erhöhen}] of TBaseFrameClassRec =
      (
       (Name: 'LA'; Header: 'Lohnarten'; Klasse: TLAFrame),
       (Name: 'KST'; Header: 'Kostenstellen'; Klasse: TKSTFrame),
       //...
      );

Type
  TFrameFactory = class
    private
      fParent : TWinControl;
      fOwner : TComponent;
      fCon : TADOConnection;
      //...
      function GetClassFromName(FrameName:String):TBaseFrameClass;
      function GetHeaderFromName(FrameName:String):String;
    public
      constructor create(Owner:TWinControl);overload;
      property Owner:TComponent read fOwner;
      property Parent:TWinControl read fParent write fParent;
      property Con:TADOConnection read fCon write fCon;
      function GetFrame(FrameName:String):TBaseFrame;
  end;


implementation

{ TFrameFactory }

constructor TFrameFactory.create(Owner: TWinControl);
begin
  inherited create;
  fOwner:=Owner;
end;

function TFrameFactory.GetClassFromName(FrameName: String): TBaseFrameClass;
var
  i: Integer;
begin
  Result:=nil;
  for i := 0 to High(FrameClassList) do
    if FrameClassList[i].Name = FrameName then
      begin
      Result := FrameClassList[i].Klasse;
      break;
      end;
end;

function TFrameFactory.GetHeaderFromName(FrameName: String): String;
var
  i: Integer;
begin
  Result:='';
  for i := 0 to High(FrameClassList) do
    if FrameClassList[i].Name = FrameName then
      begin
      Result := FrameClassList[i].Header;
      break;
      end;
end;

function TFrameFactory.GetFrame(FrameName: String): TBaseFrame;
var f:TBaseFrame;
begin
  f:=GetClassFromName(FrameName).Create(Owner);
  f.Parent:=Parent;
  f.Align:=alClient;
  f.Con:=Con;
  f.Header:=GetHeaderFromName(FrameName);
  //...
  Result:=f;
end;


end.
Ralph
  Mit Zitat antworten Zitat
Benutzerbild von Bummi
Bummi

Registriert seit: 15. Jun 2010
Ort: Augsburg Bayern Süddeutschland
3.470 Beiträge
 
Delphi XE3 Enterprise
 
#5

AW: FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 13:48
Delphi-Quellcode:
uses unit4,unit5;
{$R *.dfm}


type
  TShowForm = Reference to Function(Owner : TComponent):TForm;
const
  FC: Array [1..2] of TFormClass=(Tform4,Tform5);
var
  F : Array [1..2] of TShowForm;




procedure TForm3.Button1Click(Sender: TObject);
var
 s:TShowForm;
begin
    s := F[2];
    s(self).Show;
end;

procedure TForm3.FormCreate(Sender: TObject);
begin
F[1] := Function(Owner:TComponent):TForm
              begin
              Result := FC[1].Create(Owner);
              end;
F[2] := Function(Owner:TComponent):TForm
              begin
              Result := FC[2].Create(Owner);
              end

end;
Thomas Wassermann H₂♂
Das Problem steckt meistens zwischen den Ohren
DRY DRY KISS
H₂ (wenn bei meinen Snipplets nichts anderes angegeben ist Lizenz: WTFPL)
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#6

AW: FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 13:52
@Jumpy

Warum nicht Delphi-Referenz durchsuchenRegisterClass bzw. Delphi-Referenz durchsuchenRegisterClassAlias und Delphi-Referenz durchsuchenFindClass?
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Medium

Registriert seit: 23. Jan 2008
3.679 Beiträge
 
Delphi 2007 Enterprise
 
#7

AW: FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 13:54
Kann man Konstruktoren nicht ggf. virtuell deklarieren? Das wäre ja quasi ein Paradebeispiel. (Oder sind sie es eventuell sogar schon? Kann's grad nicht selber prüfen.)

Edit: Ansonsten halt über eine virtuelle Init-Methode, die jede Form-Klasse selbst implementiert.
"When one person suffers from a delusion, it is called insanity. When a million people suffer from a delusion, it is called religion." (Richard Dawkins)
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#8

AW: FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 13:55
Kann man Konstruktoren nicht ggf. virtuell deklarieren? Das wäre ja quasi ein Paradebeispiel. (Oder sind sie es eventuell sogar schon? Kann's grad nicht selber prüfen.)
Ab Delphi-Referenz durchsuchenTComponent ist der auf jeden Fall virtual
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Medium

Registriert seit: 23. Jan 2008
3.679 Beiträge
 
Delphi 2007 Enterprise
 
#9

AW: FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 14:06
Dann sollte ein Aufruf des Konstruktors über eine Basisklasse ab TComponent immer den richtigen liefern, wie Sir Rufo es oben schon hingeschrieben hat.
"When one person suffers from a delusion, it is called insanity. When a million people suffer from a delusion, it is called religion." (Richard Dawkins)
  Mit Zitat antworten Zitat
Benutzerbild von Mavarik
Mavarik

Registriert seit: 9. Feb 2006
Ort: Stolberg (Rhld)
4.123 Beiträge
 
Delphi 10.3 Rio
 
#10

AW: FormularArray den richtigen Create aufrufen! Wie?

  Alt 30. Jan 2014, 14:33
SUPER! Danke...

TFormClass kannte ich bisher noch nicht...

Hab das bis heute auch noch nie gebraucht...

Danke auf für das FormFactry Beispiel. Soll so was ähnliches werden.

Grüsse Mavarik
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 11:46 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz