AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

String auf Tabulatoren prüfen

Ein Thema von Ajintaro · begonnen am 16. Aug 2014 · letzter Beitrag vom 18. Aug 2014
Antwort Antwort
Seite 1 von 2  1 2   
Benutzerbild von Ajintaro
Ajintaro

Registriert seit: 20. Okt 2004
Ort: Sankt Augustin
138 Beiträge
 
Delphi XE6 Starter
 
#1

String auf Tabulatoren prüfen

  Alt 16. Aug 2014, 21:07
Delphi-Version: XE5
Hallo DP !

Ich frage mich wie man die Anzahl der Tabulatoren eines Strings zählen kann. Ich habe eine Datei:

<TAB> Name: Horst
<TAB> Haustiere:
<TAB><TAB> Name: Fiffi
<TAB><TAB> Alter: 10
<TAB><TAB> Vorbesitzer
<TAB><TAB><TAB> Name: Manuel

Ich möchte alle gefundenen Namen in ein Treeview laden und dabei die Tabs als Level der Nodes nutzen. Ergebnis:

Code:
Horst
!-> Fiffi
 !-> Manuel
Mit Pos funktioniert es nicht:

Delphi-Quellcode:
if Open_file.Execute then memo1.Lines.LoadFromFile(Open_file.FileName);
for i := 0 to memo1.lines.count-1 do
begin

       //Root Name (Besitzer)
       iPos := Pos(#9+'"name":',memo1.Lines[i]);
       if (iPos > 0) then
       begin
         s := memo1.Lines[i];
          with tree_import.Items.AddFirst(nil,s) do
           begin
              Selected := true;
           end;
          iPos := 0;
          s := ''
       end;

       //1. Child Name (Haustier)
       iPos := Pos(#9+#9+'"name":',memo1.Lines[i]);
       if (iPos > 0) then
       begin
         s := memo1.Lines[i];
         tree_import.Items.AddChild(tree_import.selected,s);
       end;
   end;
Ich habe schon über eine Stinglist mit #9 als Delimiter eine Alternative nachgegrübelt, bin da aber auch nicht weiter gekommen. Wie kann ich denn die Vorkommen eines Tabulators effektiv zählen ?

Grüße,

JJ
Jaimy
DAoC 2.0 -> Camelot Unchained !
  Mit Zitat antworten Zitat
Faxe

Registriert seit: 10. Jan 2013
25 Beiträge
 
Delphi XE3 Professional
 
#2

AW: String auf Tabulatoren prüfen

  Alt 16. Aug 2014, 21:51
Probier doch mal:

iPos := Pos(chr(9)+'"name":',memo1.Lines[i]);

iPos ist die Anzahl Tabs.

Geändert von Faxe (16. Aug 2014 um 21:55 Uhr)
  Mit Zitat antworten Zitat
pertzschc

Registriert seit: 29. Jul 2005
Ort: Leipzig
305 Beiträge
 
Delphi 10.4 Sydney
 
#3

AW: String auf Tabulatoren prüfen

  Alt 16. Aug 2014, 21:54
Ich frage mich wie man die Anzahl der Tabulatoren eines Strings zählen kann.
Ich würde die einzelne Zeile in eine Stringliste auftrennen und dann schauen, an welcher Stelle im Index ->[i] der String "Name:" auftaucht.

<TAB> Name: Horst ->[1] (da Index bei 0 beginnt: TAB = [0])
<TAB> Haustiere:
<TAB><TAB> Name: Fiffi ->[2]
<TAB><TAB> Alter: 10
<TAB><TAB> Vorbesitzer
<TAB><TAB><TAB> Name: Manuel ->[3]

Damit hast Du Deine Levels.

Hier der Code für das Aufsplitten des Strings (bei Dir eine Memozeile) in eine Stringliste (hat bei mir auch mit TAB funktioniert):
Delphi-Quellcode:
procedure SplitLine(Source: string; Dest: TStringList; Delimeter: char = ';');
// splittet den string am delimeter auf und hängt die einzelnen strings in eine Stringlist
var
  lpos : Integer;
begin
  Dest.Clear;
  lpos := Pos(Delimeter, Source); // p = 0, wenn nicht gefunden
  while lpos <> 0 do begin
    Dest.Add(Copy(Source, 1, lpos - 1));
    Delete(Source, 1, lpos);
    lpos := Pos(Delimeter, Source); // suche erneut nach delimiter
  end;
  // wenn string noch nicht leer, dann hänge rest auch an liste
  if Source <> 'then begin
    Dest.Add(Source);
  end;
end;
Grüße, Christoph
  Mit Zitat antworten Zitat
Benutzerbild von sx2008
sx2008

Registriert seit: 15. Feb 2008
Ort: Baden-Württemberg
2.332 Beiträge
 
Delphi 2007 Professional
 
#4

AW: String auf Tabulatoren prüfen

  Alt 17. Aug 2014, 00:47
... wie man die Anzahl der Tabulatoren eines Strings zählen kann
Hier kommt die Hilfe zur Selbsthilfe...

Warum verwendest du keine Zwischenvariablen?
Delphi-Quellcode:
var
   line : string;
for i := 0 to memo1.lines.count-1 do
begin
   // Grundregel für alle Programmierer die keinen Spaghetticode schreiben wollen
   // wenn man über eine Stringliste iteriert soll man das aktuellen String in eine Zwischenvariable kopieren
   line := memo1.Lines[i];
   ...
end;
Grundregel 2: Teile Methoden/Funktionen so lange auf bis eine weitere Aufteilung keinen Sinn mehr machen würde!

Du brauchst doch eigentlich nur deine Frage von oben anschauen und dann kommst du darauf,
dass du folgende Funktion benötigst:
Delphi-Quellcode:
function CountLeadingTabs(const s:string):Integer;
begin
   // die Implementierung ist trivial; das kriegst du selber hin
   // Schleife über den String und abbrechen sobald das aktuelle Zeichen <> #9 ist
   ...
end;
fork me on Github
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
9.411 Beiträge
 
Delphi 11 Alexandria
 
#5

AW: String auf Tabulatoren prüfen

  Alt 17. Aug 2014, 08:24
Warum verwendest du keine Zwischenvariablen?
Delphi-Quellcode:
var
   line : string;
for i := 0 to memo1.lines.count-1 do
begin
   // Grundregel für alle Programmierer die keinen Spaghetticode schreiben wollen
   // wenn man über eine Stringliste iteriert soll man das aktuellen String in eine Zwischenvariable kopieren
   line := memo1.Lines[i];
   ...
end;
Warum dann nicht gleich so?
Delphi-Quellcode:
var
   line : string;
for line in memo1.lines do
begin
   // Grundregel für alle Programmierer die keinen Spaghetticode schreiben wollen
   // wenn man über eine Stringliste iteriert soll man das aktuellen String in eine Zwischenvariable kopieren
   ...
end;
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Dejan Vu
(Gast)

n/a Beiträge
 
#6

AW: String auf Tabulatoren prüfen

  Alt 17. Aug 2014, 09:23
Ich würde mir eine kleine Methode schreiben, die mir aus einem übergebenen String den Level (Anzahl der Tabs), den Tag (also 'Name', 'Alter','Vorbesitzer') und -falls vorhanden- den Wert, also den Zeil nach dem ':' liefert.
Delphi-Quellcode:
Type
  TTreeNodeDescriptor = record
    level : Integer;
    Caption : String;
    Value : String;
    Procedure FromString (aString : String);
  end;

Procedure TTreeNodeDescriptor.FromString (aString : String);
const
  TAB = #009; // ist das nicht irgendwo in SysUtils o.ä. schon deklariert?

var
  valueDelimiterFound : Boolen;

Begin
  Level := 0;
  Value := '';
  Caption := '';
  valueDelimiterFound := False;

  for c in aString do
    case c of
      TAB :
        Inc(Level);
      ':' :
        valueDelimiterFound := true;
      else
        if valueDelimiterFound then
           Value := Value + c
        else
           Caption:=Caption + c;
    end
end;
Der Code rennt 1x durch den String und verzichtet Pos und Delete.

Delphi-Quellcode:
for line in memo1.lines do begin
  t := TTreeLevelDescriptior.FromString(line);
  if t.Caption = 'Namethen
     writeln('Anzahl der Tabs (Level)',t.Level,'. Name=',t.Value);
end;
Und falls Du morgen den kompletten Baum aufspannen willst, hast Du mit der 'FromString' Methode schon alles, was Du brauchst.
  Mit Zitat antworten Zitat
OlafSt

Registriert seit: 2. Mär 2007
Ort: Hamburg
284 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#7

AW: String auf Tabulatoren prüfen

  Alt 17. Aug 2014, 16:43
Ich würds noch anders machen:

Delphi-Quellcode:
function LeadingTabs(var AData: string): integer;
var
  i: integer;
begin
  i:=0;
  while Pos(#9,AData) <> 0 do
  begin
    Delete(AData,1,1);
    inc(i);
  end;
  Result:=i;
end;
Liefert die Anzahl Tabs zurück und auch gleich den gefragten String ohne Tabs.
  Mit Zitat antworten Zitat
Dejan Vu
(Gast)

n/a Beiträge
 
#8

AW: String auf Tabulatoren prüfen

  Alt 17. Aug 2014, 16:54
Wenigstens 1x bis zum ersten nicht-TAB Zeichen rennen und dann mit Substring abschnippeln, das erspart unnötige
'Delete' Operationen.

Delphi-Quellcode:
function LeadingTabs(var AData: string): integer;
var
  i: integer;
begin
  for i:=1 to length(aData) do
    if aData[i] <> #0 then begin
      result := i;
      aData := Substring(aData,i,maxint);
      exit;
    end;

  result := 0;
End;
Aber wo ist da der Mehrwert zu meiner Funktion? Und den Namen musst Du auch noch rausbekommen.

Übrigens sind beide Funktionen falsch, wenn der String z.B. so aussieht '<TAB>Name<Tab>: Meyer'. Meine Funktion liefert nur den falschen Level, aber deine vergisst den Prefix 'Name' und liefert einen noch falscheren (also nicht nur ein bischen falsch, sondern total falsch falsch) Level.

Geändert von Dejan Vu (17. Aug 2014 um 16:56 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Ajintaro
Ajintaro

Registriert seit: 20. Okt 2004
Ort: Sankt Augustin
138 Beiträge
 
Delphi XE6 Starter
 
#9

AW: String auf Tabulatoren prüfen

  Alt 18. Aug 2014, 14:23
Hallo ihr lieben,

vielen Dank für eure Impulse !

Also
Hier kommt die Hilfe zur Selbsthilfe...

Warum verwendest du keine Zwischenvariablen?
ist natürlich völlig richtig.

Ich habe mir den code von Dejan Vu einmal angesehen und an einigen Stellen modifiziert. Das Ergebnis funktioniert ganz gut:

Delphi-Quellcode:
Type
  TTreeNodeDescriptor = record
    level : Integer;
    Caption : String;
    Value : String;
    Procedure FromString (aString : String);
  end;
{++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// TTreeNodeDescriptor - credits to Dejan Vu
+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++}

Procedure TTreeNodeDescriptor.FromString (aString : String);
const
  TAB = #009;
var
  valueDelimiterFound: Boolean;
  c:char;
Begin
  Level := 0;
  Value := '';
  Caption := '';
  valueDelimiterFound := False;

  for c in aString do
    case c of
      TAB :
        Inc(Level);
      ':' :
        valueDelimiterFound := true;
      else
        if valueDelimiterFound then
           Value := Value + c
        else
           Caption:=Caption + c;
    end
end;
{++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
// Datei importieren button
+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++}

procedure TFmain.button_scen_importClick(Sender: TObject);
var
 line:string;
 t : TTreeNodeDescriptor;
 anode:TTreeNode;
begin
   treeview.Items.Clear;
   if Opendialog1.Execute then memo1.Lines.LoadFromFile(Opendialog1.FileName);

   for line in memo1.lines do
   begin
    t.FromString(line);
    if (t.Caption = '"name"') then
    begin
     case t.level of
      1: anode:=treeview.Items.Add(Nil,t.Value);
      3: begin
           treeview.Items.AddChild(anode,t.Value);
           //Node als knoten für die nächste Ebene vorbereiten?
          end;
      5: treeview.Items.AddChild(anode,t.Value);
     end;
    end;
   end;
End;
So kann man nicht nur den String auf Tabulatoren untersuchen for <achar> in <astring> sondern erhält auch den dazugehörigen Wert. Das Einsortieren in ein Treeview klappt nur noch nicht ganz, da die 3. Ebene 5: treeview.Items.AddChild(anode,t.Value); nicht als Child von der 2. Ebene einsortiert wird.
Jaimy
DAoC 2.0 -> Camelot Unchained !
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
39.471 Beiträge
 
Delphi 11 Alexandria
 
#10

AW: String auf Tabulatoren prüfen

  Alt 18. Aug 2014, 14:35
Gibt es nur vorne Tabulatoren?
Wenn nicht, dann zehlt das falsch, da du dann ja am ersten anderen Zeichen aufhören müsstest, mit dem Zählen.

Gibt es vorne nur Tabulatoren?
Wenn ja, dann TrimLeft und das Abgeschnittene zählen Length(alt)-Length(neu). (oder eben nur vorhne die Tabs zählen)

Und das Zerlegen:
* Pos
* SplitString
* TStringList.DelimitedText (jede Zeile einzeln) oder gleich alles in die StringList, den Delimiter auf ":" einstellen und dann über Name und Value zugreifen. (TrimLeft beim Namen, was auch gleich den Level ergibt), nein Name (also '') ist kein ":" vorhaden, und Trim/TrimLeft entfernt auch das Leerzeichen nach dem ":", also am Anfang vom Value.
* oder sonseine der vielen weiteren Varianten, ohne alles Zeichen für Zeichen einzeln behandeln zu müssen.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014

Geändert von himitsu (18. Aug 2014 um 14:37 Uhr)
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 05:06 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf