AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Class property meckert mich unberechtigt an

Ein Thema von Medium · begonnen am 26. Jan 2015 · letzter Beitrag vom 26. Jan 2015
Antwort Antwort
Medium

Registriert seit: 23. Jan 2008
3.679 Beiträge
 
Delphi 2007 Enterprise
 
#1

Class property meckert mich unberechtigt an

  Alt 26. Jan 2015, 10:58
Zumindest fühle ich mich unberechtigt angemeckert

Folgende kleine Klasse (Original Copypasta):
Delphi-Quellcode:
unit _uDebugLog;

interface

uses
  Classes, SysUtils, DateUtils, SyncObjs;

type
  TDebugLog = class
  private
    class var FCS: TCriticalSection;
    class var FLogFileName: String;
    class procedure SetLogFileName(const Value: String);
  public
    class var Active: Boolean;
    class property LogFileName: String read FLogFileName write SetLogFileName;
    class procedure Log(s: String);
  end;

implementation

{ TDebugLog }

class procedure TDebugLog.Log(s: String);
var
  f: TFileStream;
begin
  if not Active then Exit;
  
  FCS.Enter;
  try
    s := FormatDateTime('dd.mm.yyyy hh:nn:ss:zzz', now)+': '+s+#13#10;
    try
      f := TFileStream.Create(FLogFileName, fmOpenReadWrite or fmShareDenyWrite);
      f.Seek(0, soFromEnd);
      f.Write(s[1], Length(s));
    finally
      f.Free;
    end;
  finally
    FCS.Leave;
  end;
end;

class procedure TDebugLog.SetLogFileName(const Value: String);
var
  fileHandle: Integer;
  errorCode: Integer;
begin
  FLogFileName := Value;
  if not FileExists(FLogFileName) then
  begin
    try
      fileHandle := FileCreate(FLogFileName);
    except
      fileHandle := -1;
    end;
    if fileHandle <> -1 then
      FileClose(fileHandle)
    else
    begin
      errorCode := GetLastError;
      raise Exception.Create('Could not create log file "'+FLogFileName+'". Code: '+IntToStr(errorCode)+' Message: '+SysErrorMessage(errorCode));
    end;
  end;
end;

initialization
  TDebugLog.FCS := TCriticalSection.Create;

finalization
  TDebugLog.FCS.Free;

end.
Kompiliere ich das, errötet die Zeile mit der Deklaration der class property (LogFileName), und der Fehler lautet:
Zitat:
[DCC Fehler] _uDebugLog.pas(16): E2355 Für den Zugriff auf Klasseneigenschaften muss ein Klassenfeld oder eine statische Klassenmethode verwendet werden
Eigentlich bin ich der Meinung, genau dies zu tun. Warum geht das dann nicht? Danke im Voraus für eure Ideen! (Delphi 2007)
"When one person suffers from a delusion, it is called insanity. When a million people suffer from a delusion, it is called religion." (Richard Dawkins)
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.564 Beiträge
 
Delphi 12 Athens
 
#2

AW: Class property meckert mich unberechtigt an

  Alt 26. Jan 2015, 11:02
class procedure SetLogFileName(const Value: String); static; // static nicht vergessen
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.132 Beiträge
 
Delphi 10 Seattle Enterprise
 
#3

AW: Class property meckert mich unberechtigt an

  Alt 26. Jan 2015, 11:39
Zwei vollkommen unproduktive Herummäkeleien:
  1. Wozu diese grässlichen initialization/finalization-Abschnitte? Wenn schon, dann nimm doch Klassenkonstruktoren und -destruktoren dafür. Die sind sogar noch vor/nach den initialization/finalization-Abschnitten dran
  2. Warum ist ein Logger ein Quasi-Singleton? Und wenn du mal zwei haben möchtest? Ich hätte weniger Hemmungen eine ganz normale Klasse zu bauen und meinetwegen eine ... globale Variable für meinen Allzweck-Logger zu nehmen
  Mit Zitat antworten Zitat
Medium

Registriert seit: 23. Jan 2008
3.679 Beiträge
 
Delphi 2007 Enterprise
 
#4

AW: Class property meckert mich unberechtigt an

  Alt 26. Jan 2015, 11:54
@DeddyH: Danke, ja. Tut weh

@Hübscher Günni:
1) Ich war der Auffassung, dass diese bei D2007 noch nicht existierten. Probiere ich aber gleich aus, weil das wäre natürlich erheblich schöner. Aber irgend etwas wabert mir da him Hinterkopf, weswegen ich das autoamtisch so geschrieben haben muss.
2) Threads. Ich möchte für mein Tool eine einzige Log-Datei haben, um darin u.a. auch die Reihenfolgen zu erkennen, in denen Dinge passieren. Da hier 3-4 Threads beteiligt sind, mach ich's auf diese Weise. Das Ganze ist auch für ein ganz spezielles Problem geschrieben, dem ich auf die Schliche kommen will. (Dinge funktionieren auf meinem PC, aber beim Kunden nicht.)
"When one person suffers from a delusion, it is called insanity. When a million people suffer from a delusion, it is called religion." (Richard Dawkins)
  Mit Zitat antworten Zitat
Blup

Registriert seit: 7. Aug 2008
Ort: Brandenburg
1.447 Beiträge
 
Delphi 10.4 Sydney
 
#5

AW: Class property meckert mich unberechtigt an

  Alt 26. Jan 2015, 11:54
Klassen-Konstruktor und Klassen-Destruktor gibt es in Delphi 2007 noch nicht.
Für diesen Fall sehe ich jeweils eine Klassenmethode Initialize() und Finalize() vor, die im entsprechenden Abschnitten der Unit aufgerufen wird.
Was dabei im einzelnen passiert, geht nur die Klasse etwas an.
  Mit Zitat antworten Zitat
Medium

Registriert seit: 23. Jan 2008
3.679 Beiträge
 
Delphi 2007 Enterprise
 
#6

AW: Class property meckert mich unberechtigt an

  Alt 26. Jan 2015, 11:56
Ha! Also doch. Init- und DeInit-Prozeduren habe ich an anderen Stellen ebenfalls genutzt dafür. Der Logger hier ist aber wie gesagt eher Q'n'D für ein bestimmtes Problem. Der wird nicht Teil des Produktivbetriebes.
"When one person suffers from a delusion, it is called insanity. When a million people suffer from a delusion, it is called religion." (Richard Dawkins)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 07:07 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz