Ball vom Paddle abprallen

[DeddyH]

Es muss nicht einmal Google sein, die Forensuche sollte schon einige Treffer bringen (Stichwort Kollisionskontrolle).

[Relfend114]

Klar habe ich schon überall nachgeguckt nur handeln die anderen Beiträge nicht genau wie bei mir mit dem Paddle. Habe schon mal was von IntersectRect gelesen nur habe ich garkeine Ahnung wie man es anwendet.

[Mavarik]

An welcher Stelle hängt es den?

[Relfend114]

Also von den Wänden springt der Ball ab (also links und rechts). Links ist dann auch das Paddle jedoch fliegt der Ball einfach durch... und ich bekomm es einfach nicht hin dass er auch von dem Paddle abprallt...

[BadenPower]

Zitat von Relfend114:

nur habe ich garkeine Ahnung wie man es anwendet.

Und wir haben keine Ahnung mit was Du arbeitest.

Läuft da eine GameEnginge, oder zeichnest Du das Paddle und den Ball selbst auf einen Canvas.

Oder, oder, oder...

[Relfend114]

Der Ball ist ein Timer und läuft halt auf einem kleinen Feld welches ein Shape ist. Das Paddle ist ebenfalls ein Shape

[Mavarik]

Zitat von Relfend114:

Der Ball ist ein Timer und läuft halt auf einem kleinen Feld welches ein Shape ist. Das Paddle ist ebenfalls ein Shape

Läuft der Ball mit Geschwindigkeitsvektoren (Real) oder einfach nur als Integer : inc(X) inc(Y)?

[BadenPower]

Zitat von Relfend114:

Der Ball ist ein Timer und läuft halt auf einem kleinen Feld welches ein Shape ist. Das Paddle ist ebenfalls ein Shape

Ein Timer ist eine Zeitkomponete und hat daher keine Form.
Dein Ball ist eher wahrscheinlich auch ein Shape, welches Du über einen Timer gesteuert, über die Oberfläche bewegen lässt.

Mach es uns doch nicht so schwer.
Lade mal Dein Projekt hoch.

[DeddyH]

Oder erstell mal ein neues Projekt, benenne das Formular frmDemo und die Unit uDemoMain. Die überschreibst Du dann komplett mit dem folgenden Code und weist im Objektinspektor dem OnCreate-Ereignis die FormCreate-Methode zu.

Delphi-Quellcode:

unit uDemoMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls;

type
  TfrmDemo = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    FPaddle: TPanel;
    FBall: TImage;
    FTimer: TTimer;
    procedure DoOnTimer(Sender: TObject);
    function Collision(FirstRect, SecondRect: TRect): Boolean;
  public
    { Public-Deklarationen }
  end;

var
  frmDemo: TfrmDemo;

implementation

{$R *.dfm}

const
  STEP = 2;

{ TfrmDemo }

function TfrmDemo.Collision(FirstRect, SecondRect: TRect): Boolean;
var
  OutRect: TRect;
begin
  Result := IntersectRect(OutRect, FirstRect, SecondRect);
end;

procedure TfrmDemo.DoOnTimer(Sender: TObject);
var
  PaddleRect, BallRect: TRect;
begin
  FBall.Top := FBall.Top + STEP;
  PaddleRect := Rect(FPaddle.Left, FPaddle.Top, FPaddle.Left + FPaddle.Width,
    FPaddle.Top + FPaddle.Height);
  BallRect := Rect(FBall.Left, FBall.Top, FBall.Left + FBall.Width,
    FBall.Top + FBall.Height);
  if Collision(PaddleRect, BallRect) then
    begin
      FTimer.Enabled := false;
      ShowMessage('Kollision');
    end;
end;

procedure TfrmDemo.FormCreate(Sender: TObject);
const
  EDGELENGTH = 20;
var
  FBitmap: TBitmap;
begin
  //Paddel erzeugen
  FPaddle := TPanel.Create(self);
  FPaddle.Parent := self;
  FPaddle.Top := ClientHeight - FPaddle.Height;
  FPaddle.Left := (ClientWidth - FPaddle.Width) div 2;
  //Ball erzeugen
  FBall := TImage.Create(self);
  FBall.Parent := self;
  FBall.Width := EDGELENGTH;
  FBall.Height := EDGELENGTH;
  FBall.Top := 0;
  FBall.Left := (ClientWidth - FBall.Width) div 2;
  //Ball malen und darstellen
  FBitmap := TBitmap.Create;
  try
    FBitmap.Width := EDGELENGTH;
    FBitmap.Height := EDGELENGTH;
    FBitmap.Canvas.Brush.Color := clRed;
    FBitmap.Canvas.Ellipse(0, 0, FBitmap.Width, FBitmap.Height);
    FBall.Picture.Assign(FBitmap);
  finally
    FBitmap.Free;
  end;
  //Timer erzeugen
  FTimer := TTimer.Create(self);
  FTimer.Interval := 20;
  FTimer.OnTimer := DoOnTimer;
end;

end.

[Relfend114]

Ich könnte vielleicht die Lösung gefunden haben aber jetzt habe ich ein weiteres Problem...
Ich möchte ja die Richtung des Balls ändern wenn er das Paddle berührt. Das mache ich mit FRichtungX := -FRichtungX.
Ich wollte FRichtungX := -FRichtungX in eine function einpacken damit es dann so aussieht: result := FRichtungX := -FRichtungX;
Dann kriege ich jedoch eine Fehlermeldung -.- wollte dann einfach diese function dann aufrufen wenn Paddle und Ball kollidieren.