AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Funktion/Prozedur abbrechen?

Ein Thema von JulianT · begonnen am 20. Apr 2015 · letzter Beitrag vom 20. Apr 2015
Antwort Antwort
Seite 2 von 2     12
Benutzerbild von bernau
bernau

Registriert seit: 1. Dez 2004
Ort: Köln
1.268 Beiträge
 
Delphi 11 Alexandria
 
#11

AW: Funktion/Prozedur abbrechen?

  Alt 20. Apr 2015, 14:00
Hmmm, da die Methode BerechnenClick heißt, impliziere ich jetzt mal, dass diese aufgerufen wird, wenn auf einen Button geklickt wird, und zu diesem Zeitpunkt müssen alle Werte korrekt eingegeben sein, oder es ist eben Murks -> Exception
Stimmt. Immer wieder erstaunlich, daß man seine eigene Vorgehensweise in einen fremden Code impliziert. Ich prüfe nämlich meist im OnChange eines Edits.

Dennoch denke ich, daß ich Benachrichtigungen an den Anwender nicht mit Exceptions durchführen sollte.
Gerd
Kölner Delphi Usergroup: http://wiki.delphitreff.de
  Mit Zitat antworten Zitat
Popov
(Gast)

n/a Beiträge
 
#12

AW: Funktion/Prozedur abbrechen?

  Alt 20. Apr 2015, 14:01
Sowas ist nicht nötig:
Delphi-Quellcode:
  begin
    if Edit2.Text > Edit1.Text then ShowMessage('Invalide Eingabe');
  end;
Dafür braucht man keinen Begin End Block. Das reicht:
Delphi-Quellcode:
  if Edit2.Text > Edit1.Text then ShowMessage('Invalide Eingabe');
  //
Auch hier ist es unnötig:
Delphi-Quellcode:
  begin
    if Edit2.Text <= Edit1.Text then
        maxpunktzahl:=StrToInt(Edit1.Text);
        schülerpunkte:=StrToInt(Edit2.Text);
        Minpunkte[1]:=(maxpunktzahl/100)*96;
        Minpunkte[2]:=(maxpunktzahl/100)*80;
        Minpunkte[3]:=(maxpunktzahl/100)*60;
        Minpunkte[4]:=(maxpunktzahl/100)*40;
        Minpunkte[5]:=(maxpunktzahl/100)*20;
        Minpunkte[6]:=(maxpunktzahl/100)*0;
        StringGrid1.Cells[1,1]:=FloatToStr(Ceil(Minpunkte[1]));
        StringGrid1.Cells[1,2]:=FloatToStr(Ceil(Minpunkte[2]));
        StringGrid1.Cells[1,3]:=FloatToStr(Ceil(Minpunkte[3]));
        StringGrid1.Cells[1,4]:=FloatToStr(Ceil(Minpunkte[4]));
        StringGrid1.Cells[1,5]:=FloatToStr(Ceil(Minpunkte[5]));
        StringGrid1.Cells[1,6]:=FloatToStr(Ceil(Minpunkte[6]));

  begin
Geht man davon aus, dass die Einrückung nach maxpunktzahl:=StrToInt(Edit1.Text); nicht zufällig ist, sondern die anderen Zeilen mit bei der Abfrage einbezogen werden sollen, dann sollte das so aussehen:
Delphi-Quellcode:
    if Edit2.Text <= Edit1.Text then
      begin
        maxpunktzahl:=StrToInt(Edit1.Text);
        schülerpunkte:=StrToInt(Edit2.Text);
        Minpunkte[1]:=(maxpunktzahl/100)*96;
        Minpunkte[2]:=(maxpunktzahl/100)*80;
        Minpunkte[3]:=(maxpunktzahl/100)*60;
        Minpunkte[4]:=(maxpunktzahl/100)*40;
        Minpunkte[5]:=(maxpunktzahl/100)*20;
        Minpunkte[6]:=(maxpunktzahl/100)*0;
        StringGrid1.Cells[1,1]:=FloatToStr(Ceil(Minpunkte[1]));
        StringGrid1.Cells[1,2]:=FloatToStr(Ceil(Minpunkte[2]));
        StringGrid1.Cells[1,3]:=FloatToStr(Ceil(Minpunkte[3]));
        StringGrid1.Cells[1,4]:=FloatToStr(Ceil(Minpunkte[4]));
        StringGrid1.Cells[1,5]:=FloatToStr(Ceil(Minpunkte[5]));
        StringGrid1.Cells[1,6]:=FloatToStr(Ceil(Minpunkte[6]));
      end;
Und was die Abfragen angeht, aus dem:
Delphi-Quellcode:
    if (schülerpunkte >= Minpunkte[1]) then Edit3.Text:='1else
    begin
      if (schülerpunkte >= Minpunkte[2]) then Edit3.Text:='2else
      begin
        if (schülerpunkte >= Minpunkte[3]) then Edit3.Text:='3else
        begin
          if (schülerpunkte >= Minpunkte[4]) then Edit3.Text:='4else
          begin
            if (schülerpunkte >= Minpunkte[5]) then Edit3.Text:='5else
            begin
              if (schülerpunkte >= Minpunkte[6]) then Edit3.Text:='6else
            end;
          end;
        end;
      end;
    end;
mach das:
Delphi-Quellcode:
    if (schülerpunkte >= Minpunkte[1]) then Edit3.Text:='1
    else if (schülerpunkte >= Minpunkte[2]) then Edit3.Text:='2
    else if (schülerpunkte >= Minpunkte[3]) then Edit3.Text:='3
    else if (schülerpunkte >= Minpunkte[4]) then Edit3.Text:='4
    else if (schülerpunkte >= Minpunkte[5]) then Edit3.Text:='5
    else if (schülerpunkte >= Minpunkte[6]) then Edit3.Text:='6
    else
    begin

    end;
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#13

AW: Funktion/Prozedur abbrechen?

  Alt 20. Apr 2015, 14:34
Oder um es kurz und knapp zu schreiben:
Delphi-Quellcode:
unit Form.Main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

const
  NotenSchlüssel: array [1 .. 5] of Single = ( 96.0, 80.0, 60.0, 40.0, 20.0 );

type
  TForm1 = class( TForm )
    Edit1: TEdit;
    Edit2: TEdit;
    Button1: TButton;
    Label1: TLabel;
    procedure Button1Click( Sender: TObject );
  private
    {Private-Deklarationen}
  public
    {Public-Deklarationen}
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function GetSchulnoteFromPercent( APercent: Single ): Integer;
begin
  // Guard
  if ( APercent < 0 ) or ( APercent > 100 ) then
    raise EArgumentOutOfRangeException.Create( 'Der Wert muss zwischen 0% und 100% liegen!' );
 
  Result := Low( NotenSchlüssel );
  repeat
    if APercent >= NotenSchlüssel[Result] then
      Exit;
    Inc( Result );
  until Result > High( NotenSchlüssel );
end;

function GetSchulnoteFromPunkte( AErreicht, AMax : Integer ) : Integer;
begin
  // Guard
  if AErreicht < 0 then
    raise EArgumentOutOfRangeException.Create( 'Die erreichte Punktzahl darf nicht kleiner 0 sein!' );
  if AMax <= 0 then
    raise EArgumentOutOfRangeException.Create( 'Die maximale Punktzahl darf nicht kleiner oder gleich 0 sein!' );
  if AErreicht > AMax then
    raise EArgumentOutOfRangeException.CreateFmt( 'Die erreichte Punktzahl (%d) kann nicht größer als die maximale Punktzahl (%d) sein!',
      [AErreicht, AMax] );

  Result := GetSchulnoteFromPercent( AErreicht / AMax * 100 );
end;

procedure TForm1.Button1Click( Sender: TObject );
var
  LErreichtePunktZahl, LMaxPunktZahl: Integer;
begin
  LErreichtePunktZahl := StrToInt( Edit1.Text );
  LMaxPunktZahl := StrToInt( Edit2.Text );

  Label1.Caption := IntToStr( GetSchulnoteFromPunkte( LErreichtePunktZahl, LMaxPunktZahl ) );
end;

end.
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)

Geändert von Sir Rufo (20. Apr 2015 um 15:32 Uhr)
  Mit Zitat antworten Zitat
BadenPower

Registriert seit: 17. Jun 2009
616 Beiträge
 
#14

AW: Funktion/Prozedur abbrechen?

  Alt 20. Apr 2015, 15:18
In diesem konkreten Fall können eben drei Exceptions auftreten
  1. Edit1.Text kann nicht in einen Integer umgewandelt werden
  2. Edit2.Text kann nicht in einen Integer umgewandelt werden
  3. Die Punktzahl ist größer als die maximale Punktzahl
Es sind mehr als 3.

Du hast die Eingabe von negativen Werten vergessen.
Programmieren ist die Kunst aus Nullen und Einsen etwas sinnvollen zu gestalten.
Der bessere Künstler ist allerdings der Anwender, denn dieser findet Fehler, welche sich der Programmierer nicht vorstellen konnte.
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#15

AW: Funktion/Prozedur abbrechen?

  Alt 20. Apr 2015, 15:24
In diesem konkreten Fall können eben drei Exceptions auftreten
  1. Edit1.Text kann nicht in einen Integer umgewandelt werden
  2. Edit2.Text kann nicht in einen Integer umgewandelt werden
  3. Die Punktzahl ist größer als die maximale Punktzahl
Es sind mehr als 3.

Du hast die Eingabe von negativen Werten vergessen.
Erwischt ... habe ich in dem kurz und knapp Beispiel noch ergänzt
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.016 Beiträge
 
Delphi 12 Athens
 
#16

AW: Funktion/Prozedur abbrechen?

  Alt 20. Apr 2015, 15:40
Und extrem große Zahlen?
2 Milliarden Punkte ist schon ein bissl übertrieben.
Oder vielleicht war jemand soooo schlecht, daß es mehr Punktabzüge gab, als Punkte.

Also Grundsätzlich kann man das alles als eine "Prüfung auf gültige Eingabewerte (Wertebereich)" ansehn.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
BadenPower

Registriert seit: 17. Jun 2009
616 Beiträge
 
#17

AW: Funktion/Prozedur abbrechen?

  Alt 20. Apr 2015, 15:54
Also Grundsätzlich kann man das alles als eine "Prüfung auf gültige Eingabewerte (Wertebereich)" ansehn.
Und das sollte man meiner Meinung nach nicht unbedingt mit Exceptions machen.

Sind die Eingaben laut Eingabeprüfung fehlerhaft, dann sollte/muss man den Benutzer darauf aufmerksam machen. Dazu gibt man eine normale Meldung aus.

Die Benutzung von Exceptions hierfür kann auch ungewollt dazu führen, dass der Benutzer dies gar nicht mitbekommt, oder eine Fehlermeldung erhält, welche nicht dem Ursprünglichen Fehler entspricht.

Man stelle sich vor, dass in einer Eingabeprüfungs-Prozedur Exceptions geworfen werden, wie in Sir Rufo's Beispiel, und diese von einer anderen Prozedur aufgerufen wird in der irgendwo ein Try-Except-Block verwendet wird.
Programmieren ist die Kunst aus Nullen und Einsen etwas sinnvollen zu gestalten.
Der bessere Künstler ist allerdings der Anwender, denn dieser findet Fehler, welche sich der Programmierer nicht vorstellen konnte.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.016 Beiträge
 
Delphi 12 Athens
 
#18

AW: Funktion/Prozedur abbrechen?

  Alt 20. Apr 2015, 16:02
in der irgendwo ein Try-Except-Block verwendet wird.
Dann ist der Try-Except-Block falsch, denn Fehlermeldungen dürfen/sollten niemals verfälscht oder "blind" abgefangen werden.

Wenn man GUI und Code trennt (MVVM oder Dregleichen), dann darf/sollte man im Code schon eine Exception werfen, wenn die Eingaben "ungültig" sind.

Was die GUI damit dann macht, ist ihr überlassen.
* durchreichen und als Fehlermeldung anzeigen
* oder abfangen und irgendwie anders auf das Problem hinweisen
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#19

AW: Funktion/Prozedur abbrechen?

  Alt 20. Apr 2015, 16:03
Man stelle sich vor, dass in einer Eingabeprüfungs-Prozedur Exceptions geworfen werden, wie in Sir Rufo's Beispiel, und diese von einer anderen Prozedur aufgerufen wird in der irgendwo ein Try-Except-Block verwendet wird.
Und, wo ist da das Problem? Wenn diese Prozedur diese Exceptions behandeln kann, dann ist doch alles so wie es sein soll, und wenn nicht, dann stellt sich doch die Frage, ob der Programmierer den Sinn und Zweck von Exceptions verstanden hat.

Denn sowas hier
Delphi-Quellcode:
try
  foo;
except
end;
ist voll daneben ... und das hier
Delphi-Quellcode:
try
  foo;
except
  on E: Exception do
    ShowMessage( E.ClassName + ': ' + E.Message );
end;
in einer GUI-Anwendung zeigt die Unfähigkeit/Unwissenheit des Programmierers
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 19:06 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz