Hallo #,

aus ptb.de

Zitat:

Die mitteleuropäische Sommerzeit (MESZ) beginnt jeweils am letzten Sonntag im Monat März um 2 Uhr mitteleuropäischer Zeit. An diesem Tag werden die Uhren um 2 Uhr um eine Stunde auf 3 Uhr vorgestellt. Ziel der Zeitumstellung ist die bessere Ausnutzung der Tageshelligkeit.

Die Sommerzeit endet jeweils am letzten Sonntag im Monat Oktober um 3 Uhr mitteleuropäischer Sommerzeit. An diesem Tag werden die Uhren um 3 Uhr auf 2 Uhr zurückgestellt. Bei dieser doppelt erscheinenden Stunde wird die erste Stunde als 2A und die zweite Stunde als 2B bezeichnet.

Wir sind faul:

zusammenfalten · markieren

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
var
  tz : TTimeZoneInformation;
  tdtTimeStart : TDateTime;
  tdtTimeEnd : TDateTime;
  sText : string;
begin
  GetTimeZoneInformation(tz);

  tz.DaylightDate.wYear := 2014;
  tz.StandardDate.wYear := 2014;

  tdtTimeStart := SystemTimeToDateTime(tz.DaylightDate);
  tdtTimeEnd := SystemTimeToDateTime(tz.StandardDate);

  sText := 'Start: '+DateToStr(tdtTimeStart)+#13#10+
           'Ende: '+DateToStr(tdtTimeEnd);

  MessageBox(0, PChar(sText), '', 0);
end;

Aber: Es kommt 5.3. raus beim Start.

Ich könnte dass bissel auch per Funktion schreiben,
will ich aber nicht oder muss ich doch ???


Heiko

http://delphiforfun.org/Programs/Mat...cs/DSTCalc.htm

Du solltest mal die Dokumentation lesen.
http://msdn.microsoft.com/en-us/libr...=vs.85%29.aspx

5.3. heißt nicht, daß es der 05.03. ist

Denn Jahr = 0, also ist das ein relativer Datumswert.
Nur wenn Jahr einen Wert enthält, ist es ein absolutes Datum, was man so direkt verwenden kann.

05.03.0000 = 3. Monat und 5. "Woche"
wDayOfWeek gibt den Wochentag an und davon muß der 5 in diesem Monat verwendet werden.

Auch nicht ganz. In DayLightDate bedeuten die Felder Folgendes:

• wYear - Wenn 0, dann treffen die weiteren Regeln zu. Wenn <> 0 handelt es sich um ein festes Datum, z.b. einmalige Umstellung.
• wHour - Umstellungsstunde
• wMinute - Umstellungsminute
• wDayOfWeek - Wochentag (0 = Sonntag)
• wDay - Am wievielten durch wDayOfWeek angegebener Wochentag des Monats erfolgt die Umstellung(1-5, 5 bedeutet letzter)

Wichtig ist: Es handelt sich um eine reine Informationsstruktur über die Konfigurationsregelen der Zeitzone. Die Errechnung eines konkreten Datums muß selber gemacht werden!

Hallo,

war ein langer Tag heute,
der erste Link klappt bei 2014 nicht mal mit dem Taschenrechner,
der zweite ist ja noch komplizierter ...
ich baue mir jetzt eine eigene Funktion.

Select StartSommerZeit From RDB$DataBase ...

Heiko

So?

siehe erstes IF im ConvertDate

zusammenfalten · markieren

Delphi-Quellcode:

uses
  Windows, SysUtils, DateUtils, Math;

type
  TTimeZoneInformationHelper = record helper for TTimeZoneInformation
  public const
    CurrentYear = 0;
    NextDates = 1;
  private
    procedure ConvertDate(var Date: TSystemTime; IsDaylight, DoNextDates: Boolean; RelDate: TSystemTime);
    function GetDate(Index: Integer): TDateTime;
    function GetDateStr(Index: Integer): string;
  public
    procedure ReadInfo(Year: Word=NextDates; DoConvertDates: Boolean=True);
    procedure ConvertDates(DoNextDates: Boolean=False); overload;
    procedure ConvertDates(DoNextDates: Boolean; RelDate: TSystemTime); overload;

    property GetStandardDate: TDateTime index 0 read GetDate;
    property GetDaylightDate: TDateTime index 1 read GetDate;
    property GetStandardDateStr: string index 0 read GetDateStr;
    property GetDaylightDateStr: string index 1 read GetDateStr;
  end;

{ TTimeZoneInformationHelper }

procedure TTimeZoneInformationHelper.ConvertDate(var Date: TSystemTime; IsDaylight, DoNextDates: Boolean; RelDate: TSystemTime);
var
  NextZone: TTimeZoneInformation;
  NewDate: TDateTime;
begin
  if Date.wYear = 0 then begin
    Date.wYear := RelDate.wYear;
    if Date.wDay < 5 then
      Date.wDay := DayOf(EncodeDayOfWeekInMonth(Date.wYear, Date.wMonth, Date.wDay, IfThen(Date.wDayOfWeek = 0, 7, Date.wDayOfWeek)))
    else begin
      NewDate := EncodeDayOfWeekInMonth(Date.wYear, Date.wMonth, 1, IfThen(Date.wDayOfWeek = 0, 7, Date.wDayOfWeek));
      while MonthOf(NewDate) = MonthOf(IncWeek(NewDate)) do
        NewDate := IncWeek(NewDate);
      Date.wDay := DayOf(NewDate);
    end;
  end;
  if DoNextDates and (SystemTimeToDateTime(RelDate) > SystemTimeToDateTime(Date)) then begin
    NextZone.ReadInfo(RelDate.wYear + 1, True);
    if IsDaylight then
      Date := NextZone.DaylightDate
    else
      Date := NextZone.StandardDate;
  end;
end;

procedure TTimeZoneInformationHelper.ConvertDates(DoNextDates: Boolean);
var
  Current: TSystemTime;
begin
  GetLocalTime(Current);
  ConvertDates(DoNextDates, Current);
end;

procedure TTimeZoneInformationHelper.ConvertDates(DoNextDates: Boolean; RelDate: TSystemTime);
begin
  ConvertDate(Self.StandardDate, False, DoNextDates, RelDate);
  ConvertDate(Self.DaylightDate, True, DoNextDates, RelDate);
end;

function TTimeZoneInformationHelper.GetDate(Index: Integer): TDateTime;
begin
  if Index = 0 then
    Result := SystemTimeToDateTime(Self.StandardDate)
  else
    Result := SystemTimeToDateTime(Self.DaylightDate);
end;

function TTimeZoneInformationHelper.GetDateStr(Index: Integer): string;
begin
  Result := DateTimeToStr(GetDate(Index));
end;

procedure TTimeZoneInformationHelper.ReadInfo(Year: Word; DoConvertDates: Boolean);
begin
  if Year in [CurrentYear, NextDates] then begin
    if GetTimeZoneInformation(Self) = TIME_ZONE_ID_INVALID then
      RaiseLastOSError;
  end else
    if not GetTimeZoneInformationForYear(Year, nil, Self) then
      RaiseLastOSError;

  if DoConvertDates then
    ConvertDates(Year = NextDates);
end;

markieren

Delphi-Quellcode:

var
  TZI: TTimeZoneInformation;
begin
  TZI.ReadInfo;
  ShowMessage('Start: ' + TZI.GetStandardDateStr + sLineBreak + 'Ende: ' + TZI.GetDaylightDateStr);

Wäre es möglich, das das so einfach geht?

zusammenfalten · markieren

Delphi-Quellcode:

Function AnfangDerSommerzeit(Jahr : Word) : TDateTime;
Begin
  result := EncodeDate(Jahr,4,1);
// return result - DayOfWeek(Result); // Letzter Sonntag im März
  result := result - DayOfWeek(Result);
End;

Function EndeDerSommerzeit(Jahr : Word) : TDateTime;
Begin
  result := EncodeDate(Jahr,11,1);
// return result - DayOfWeek(Result); // Letzter Sonntag im Oktober
  result := result - DayOfWeek(Result);
End;

Zitat von Furtbichler:

Wäre es möglich, das das so einfach geht?

zusammenfalten · markieren

Delphi-Quellcode:

Function AnfangDerSommerzeit(Jahr : Word) : TDateTime;
Begin
  result := EncodeDate(Jahr,4,1);
  return result - DayOfWeek(Result); // Letzter Sonntag im März
End;

Function EndeDerSommerzeit(Jahr : Word) : TDateTime;
Begin
  result := EncodeDate(Jahr,11,1);
  return result - DayOfWeek(Result); // Letzter Sonntag im Oktober
End;

Hilfe Furtbichler,

was macht denn das 'return' da drin?
Ist das 'return' nicht eher was für C++ ?

Das erinnert mich irgendwie auch an Basic, aber ehrlich, ich verstehe die Funktion so nicht.

Ich habe Deine Funktion in meinem Delphi getestet und so geht sie dann:

zusammenfalten · markieren

Delphi-Quellcode:

Function TForm1.AnfangDerSommerzeit(Jahr : Word) : TDateTime;
Begin
   result := EncodeDate(Jahr,4,1);
   result:= (result - DayOfWeek(Result))+1; // Letzter Sonntag im März
End;

Function TForm1.EndeDerSommerzeit(Jahr : Word) : TDateTime;
Begin
   result := EncodeDate(Jahr,11,1);
   result:= (result - DayOfWeek(Result))+1; // Letzter Sonntag im Oktober
End;

Hm, da stellt sich mir noch die Frage, ob die Funktion zwei Resultate blitzschnell und fürs Auge unbemerkt liefert, oder ob das erste 'result' in der Funktion verbleibt...

Zitat von Codix32:

Hm, da stellt sich mir noch die Frage, ob die Funktion zwei Resultate blitzschnell und fürs Auge unbemerkt liefert, oder ob das erste 'result' in der Funktion verbleibt...

Das erste result wird doch überschrieben.
Mit result wird ja auch nicht aus der Funktion herausgesprungen, daher zählt das was als letztes, bevor die Funktion verlassen wird, in result geschrieben wird.

Grüße
Klaus

Zitat von Codix32:

was macht denn das 'return' da drin?

C# verdorben, sorry.

Das 'result' ist einfach eine lokale Variable, die Du verwenden kannst. Wie Klaus01 schon richtig schrieb, entspricht sie dem Resultat. Eine Sprunganweisung ist mit der Zuweisung nicht verbunden.