AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

TEmbeddedWB + MultiProxy

Ein Thema von -187- · begonnen am 16. Feb 2011 · letzter Beitrag vom 1. Aug 2015
Antwort Antwort
Seite 1 von 3  1 23   
-187-

Registriert seit: 24. Sep 2005
483 Beiträge
 
Delphi 2010 Architect
 
#1

TEmbeddedWB + MultiProxy

  Alt 16. Feb 2011, 16:23
Moin, ich stehe mal wieder vor einem Problem

Ich arbeite mit der TEmbeddedWB Komponente und möchte über einen Proxy Server surfen. Soweit ist das auch kein Problem..
Jetzt möchte ich parallel zu meiner Applikation mit dem Internet Explorer surfen, jedoch ohne Proxy.

Das Problem ist das sich beide Programme die selben Einstellungen teilen und somit musste mein Vorhaben fürs erste scheitern.

Hat jemand eine Idee wie ich unabhängig vom IE mit dem TEmbeddedWB eine Proxy Verbindung erstellen kann. Noch schöner wäre es wenn ich mit 2 TEmbeddedWebBrowser unabhägig voneinander surfen könnte.

Ich bin mal gespannt

Cheers
  Mit Zitat antworten Zitat
Thom

Registriert seit: 19. Mai 2006
570 Beiträge
 
Delphi XE3 Professional
 
#2

AW: TEmbeddedWB + MultiProxy

  Alt 16. Feb 2011, 18:15
Microsoft
Allerdings gelten die Proxy-Einstellungen global für die Anwendung und nicht für jede IE-Komponente separat.
Thomas Nitzschke
Google Maps mit Delphi
  Mit Zitat antworten Zitat
-187-

Registriert seit: 24. Sep 2005
483 Beiträge
 
Delphi 2010 Architect
 
#3

AW: TEmbeddedWB + MultiProxy

  Alt 16. Feb 2011, 20:03
Naja wie ich die Einstellung setzen kann weiss ich ja bereits. Ich suche nach einer lokalen Proxy Verbindungs -Lösung Scheinbar gibt es die aber nicht.
  Mit Zitat antworten Zitat
Thom

Registriert seit: 19. Mai 2006
570 Beiträge
 
Delphi XE3 Professional
 
#4

AW: TEmbeddedWB + MultiProxy

  Alt 16. Feb 2011, 20:22
Hast Du den Artikel genau gelesen? Wahrscheinlich nicht, denn dann hättest Du gesehen, daß die Funktion InternetSetOption genau das macht, was Du möchtest: (Unter anderem) die Proxy-Einstellungen für Dein Programm ändern - unabhängig von IE-Instanzen anderer Anwendungen.
Das ganze läßt sich mit knapp 30 Programmzeilen umsetzen (plus der Typdefinitionen). Läuft bei mir super...
Thomas Nitzschke
Google Maps mit Delphi
  Mit Zitat antworten Zitat
-187-

Registriert seit: 24. Sep 2005
483 Beiträge
 
Delphi 2010 Architect
 
#5

AW: TEmbeddedWB + MultiProxy

  Alt 16. Feb 2011, 21:45
Oh, ja erwischt! Ich habe nur den Anfang gelesen ... Würdest du den Source mit uns teilen ?
  Mit Zitat antworten Zitat
Thom

Registriert seit: 19. Mai 2006
570 Beiträge
 
Delphi XE3 Professional
 
#6

AW: TEmbeddedWB + MultiProxy

  Alt 17. Feb 2011, 02:52
Ok - da will ich mal nicht so sein...
Delphi-Quellcode:
function SetProxy(Server: String): Boolean; //Server z.B. '127.0.0.1:8080' oder ''
type
  INTERNET_PER_CONN_OPTION = record
    dwOption: DWORD;
    Value: record
      case Integer of
        1: (dwValue: DWORD);
        2: (pszValue: {$IFDEF DELPHI2009_UP}PWideChar{$ELSE}PAnsiChar{$ENDIF});
        3: (ftValue: TFileTime);
    end;
  end;
  LPINTERNET_PER_CONN_OPTION = ^INTERNET_PER_CONN_OPTION;
  INTERNET_PER_CONN_OPTION_LIST = record
    dwSize: DWORD;
    pszConnection: LPTSTR;
    dwOptionCount: DWORD;
    dwOptionError: DWORD;
    pOptions: LPINTERNET_PER_CONN_OPTION;
  end;
  LPINTERNET_PER_CONN_OPTION_LIST = ^INTERNET_PER_CONN_OPTION_LIST;
const
  INTERNET_PER_CONN_FLAGS = 1;
  INTERNET_PER_CONN_PROXY_SERVER = 2;
  INTERNET_PER_CONN_PROXY_BYPASS = 3;
  INTERNET_PER_CONN_AUTOCONFIG_URL = 4;
  INTERNET_PER_CONN_AUTODISCOVERY_FLAGS = 5;
  PROXY_TYPE_DIRECT = $00000001;
  PROXY_TYPE_PROXY = $00000002;
  PROXY_TYPE_AUTO_PROXY_URL = $00000004;
  PROXY_TYPE_AUTO_DETECT = $00000008;
  INTERNET_OPTION_REFRESH = 37;
  INTERNET_OPTION_PER_CONNECTION_OPTION = 75;
  INTERNET_OPTION_SETTINGS_CHANGED = 39;
var
  OptionsList: INTERNET_PER_CONN_OPTION_LIST;
  BufSize: DWORD;
  HInternet: Pointer;
  Agent: String;
begin
  Result:=false;
  BufSize:=SizeOf(OptionsList);
  OptionsList.dwSize:=BufSize;
  OptionsList.pszConnection:=nil; //nil -> LAN, sonst Verbindungsname
  OptionsList.dwOptionCount:=3; //3 Optionen werden gesetzt
  OptionsList.pOptions:=AllocMem(3*SizeOf(INTERNET_PER_CONN_OPTION));
  try
    if not assigned(OptionsList.pOptions)
      then Exit;
    OptionsList.pOptions^.dwOption:=INTERNET_PER_CONN_FLAGS;
    OptionsList.pOptions^.Value.dwValue:=PROXY_TYPE_DIRECT or PROXY_TYPE_PROXY;
    inc(OptionsList.pOptions);
    OptionsList.pOptions^.dwOption:=INTERNET_PER_CONN_PROXY_SERVER;
    OptionsList.pOptions^.Value.pszValue:=PChar(Server);
    inc(OptionsList.pOptions);
    OptionsList.pOptions^.dwOption:=INTERNET_PER_CONN_PROXY_BYPASS;
    OptionsList.pOptions^.Value.pszValue:='local';
    dec(OptionsList.pOptions,2);
    Agent:=ExtractFileName(Application.ExeName);
    hInternet:=InternetOpen({$IFDEF DELPHI2009_UP}PWideChar{$ELSE}PAnsiChar{$ENDIF}
                            (Agent),INTERNET_OPEN_TYPE_DIRECT,nil,nil,0);
    try //Optionen setzen
      Result:=InternetSetOption(hInternet,INTERNET_OPTION_PER_CONNECTION_OPTION,
                                @OptionsList,BufSize);
      InternetSetOption(hInternet,INTERNET_OPTION_REFRESH,nil,0);
    finally
      InternetCloseHandle(hInternet);
    end;
  finally
    FreeMem(OptionsList.pOptions); //Speicher freigeben
  end;
end;
Thomas Nitzschke
Google Maps mit Delphi
  Mit Zitat antworten Zitat
-187-

Registriert seit: 24. Sep 2005
483 Beiträge
 
Delphi 2010 Architect
 
#7

AW: TEmbeddedWB + MultiProxy

  Alt 17. Feb 2011, 07:22
Wow, klappt hervorragend! Danke schön

Jetzt habe ich unabhängige Proxy Einstellungen für meine Applikation. Kann ich das auch auf meine Komponente beschränken? Sagen wir Webbrowser1 soll über einen Proxy die Verbindung aufbauen und Webbrowser2 soll ganz normal die Einstellungen vom IE nehmen bzw. die Verbindung über einen anderen Proxy aufbauen?


Edit: Schön wäre es wenn man diese Einstellung nur für einen Thread machen könnte.

Geändert von -187- (17. Feb 2011 um 10:01 Uhr)
  Mit Zitat antworten Zitat
Thom

Registriert seit: 19. Mai 2006
570 Beiträge
 
Delphi XE3 Professional
 
#8

AW: TEmbeddedWB + MultiProxy

  Alt 19. Feb 2011, 17:27
Leider bin ich nach zwei Tagen Recherche und vielen Experimenten zum Schluß gekommen: Das funktioniert so leider nicht. Die Browser-Funktionen werden in den Adressraum der eigenen Anwendung per DLL eingebunden. Somit beziehen sich ungünstigerweise alle Einstellungen auf diese DLL und damit auf die komplette Anwendung und nicht auf eine einzelne TWebBrowser-Instanz oder einen bestimmten Thread.

Aber:
Es besteht natürlich die Möglichkeit, den Proxy in die eigene Anwendung zu integrieren - entweder als fertige Proxy-Komponente in Form eines TIdHTTPProxy's oder als HTTP-Server (nimmt man wieder Indy, so bietet sich TIdHTTPServer an oder THTTPServer aus der Internet Component Suite). Die eintreffenden Anfragen aus den einzelnen WebBrowser-Komponenten kann man jetzt nach seinen eigenen Regeln blockieren, filtern und/oder an weitere interne/externe Proxys oder direkt an den Zielserver weiterleiten.
Ich habe mal eine kleine Grafik dazu erstellt:
proxyschema.png
Thomas Nitzschke
Google Maps mit Delphi
  Mit Zitat antworten Zitat
Benutzerbild von vergessen
vergessen

Registriert seit: 29. Jun 2010
85 Beiträge
 
Delphi 5 Professional
 
#9

AW: TEmbeddedWB + MultiProxy

  Alt 20. Feb 2011, 07:07
Eventuell leicht OT, Frage dennoch @Thom:

Welchen String müsste ich als Server in Deine

function SetProxy(Server: String): Boolean; //Server z.B. '127.0.0.1:8080' oder '' eingeben, um NUR lokale Dateien mit dem EmbeddedWB anzeigen zu können?

Hintergrund: Möchten einen EmbeddedWB als "Viewer" benutzen, der möglichst NICHT online gehen kann - falls das überhaupt mit den Proxy-Einstellungen (von denen ich Null Ahnung habe) möglich/zu verhindern ist.

Bitte - Danke!
  Mit Zitat antworten Zitat
Thom

Registriert seit: 19. Mai 2006
570 Beiträge
 
Delphi XE3 Professional
 
#10

AW: TEmbeddedWB + MultiProxy

  Alt 20. Feb 2011, 15:46
Die Proxy-Einstellungen beziehen sich darauf, wohin der IE seine Anfragen sendet. Läuft Dein Programm mit dem Proxy auf dem lokalen PC, so funktionieren die IP-Adressen '127.1.0.0' und die aktuelle LAN-Adresse (z.B. '192.168.1.10'). '0.0.0.0' und 'localhost' gehen nicht - das könnte aber durchaus auch an der von mir verwendeten TIdHTTPServer-Komponente liegen, die diese Adressen möglicherweise nicht korrekt auflöst.

Du müßtest jetzt in Dein Programm eine Server-Komponente einbauen. Ich verwende den schon erwähnten HTTP-Server von Indy. Der Proxy-Server TIdHTTPProxy tut zwar auch seinen Dienst - allerdings sind da die Eingriffsmöglichkeiten in den Ereignismethoden sehr eingeschränkt und man müßte einige Dinge in der Komponente überschreiben. Wesentlich einfacher geht es mit TIdHTTPServer, dessen Eigenschaft Bindings auf die gewünschte Adresse+Port zu setzen ist. Als Port würde natürlich auch 80 gehen, solange kein lokaler Webserver vor sich hinwerkelt.

In der Ereignisroutine von OnCommandGet wäre jetzt die gewünschte Adresse zu testen: Liegt sie in einem unerwünschten IP-Bereich, wird eine Fehlermeldung zurückgegeben, ansonsten wird die Anfrage weitergereicht und das Ergebnis zurückgeliefert. Dabei kann nach Belieben der User-Agent manipuliert werden (Google mag z.B. keine Indy-Kennung); es geht auch nicht jeden Web-Server an, mit welchem Browser man unterwegs ist oder welche NET-Versionen installiert sind, die Kekse können gezielt geändert oder ganz unterdrückt werden, die akzeptierte Sprache geändert, Bilder on-the-fly verändert sowie Werbebanner und Pixelbildchen ausgeblended werden und und und...

Der Beispielcode folgt - momentan bin ich noch am Testen...
Thomas Nitzschke
Google Maps mit Delphi
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 3  1 23   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 08:45 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz