AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Projekte Stateless - StateMachine für Delphi

Stateless - StateMachine für Delphi

Ein Thema von Sir Rufo · begonnen am 7. Sep 2015 · letzter Beitrag vom 19. Feb 2020
Antwort Antwort
Seite 1 von 3  1 23   
Benutzerbild von Sir Rufo
Sir Rufo
Registriert seit: 5. Jan 2005
Unter GITHUB: A simple library for creating state machines in DELPHI code habe ich einen Delphi-Port von GITHUB: A simple library for creating state machines in C# code veröffentlicht.

Unittests und Beispiele inklusive.

Der Code sollte ab Delphi XE2+ einfach so verwendet werden können.

Hier ein kleines Beispiel
Delphi-Quellcode:
program PhoneCall;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.Diagnostics,
  System.SysUtils,
  Stateless;

{$SCOPEDENUMS ON}

type
  State = ( OffHook, Ringing, Connected, Active, OnHold, PhoneDestroyed );
  Trigger = ( CallDialed, HungUp, CallConnected, LeftMessage, PlacedOnHold, TakenOffHold, PhoneHurledAgainstWall );
  TPhoneCall = TStateMachine<State, Trigger>;

procedure ConfigurePhoneCall( PhoneCall: TPhoneCall );
var
  LCallTimer: TStopwatch;
begin
  PhoneCall.Configure( State.OffHook )
  {} .Permit( Trigger.CallDialed, State.Ringing );

  PhoneCall.Configure( State.Ringing )
  {} .Permit( Trigger.HungUp, State.OffHook )
  {} .Permit( Trigger.CallConnected, State.Active );

  PhoneCall.Configure( State.Connected )
  {} .Permit( Trigger.HungUp, State.OffHook )
  {} .OnEntry(
    procedure( t: TPhoneCall.TTransition )
    begin
      LCallTimer := TStopwatch.StartNew;
    end )
  {} .OnExit(
    procedure( t: TPhoneCall.TTransition )
    begin
      LCallTimer.Stop;
      WriteLn( 'Duration: ', LCallTimer.ElapsedMilliseconds, 'ms' );
    end );

  PhoneCall.Configure( State.Active )
  {} .SubstateOf( State.Connected )
  {} .Permit( Trigger.LeftMessage, State.OffHook )
  {} .Permit( Trigger.PlacedOnHold, State.OnHold );

  PhoneCall.Configure( State.OnHold )
  {} .SubstateOf( State.Connected )
  {} .Permit( Trigger.TakenOffHold, State.Active )
  {} .Permit( Trigger.PhoneHurledAgainstWall, State.PhoneDestroyed );
end;

procedure Test;
var
  LCall: TPhoneCall;
begin
  LCall := TPhoneCall.Create( State.OffHook );
  try
    ConfigurePhoneCall( LCall );
    WriteLn( LCall.ToString );

    LCall.Fire( Trigger.CallDialed );
    WriteLn( LCall.ToString );

    LCall.Fire( Trigger.CallConnected );
    WriteLn( LCall.ToString );

    LCall.Fire( Trigger.PlacedOnHold );
    WriteLn( LCall.ToString );

    LCall.Fire( Trigger.TakenOffHold );
    WriteLn( LCall.ToString );

    LCall.Fire( Trigger.PlacedOnHold );
    WriteLn( LCall.ToString );

    LCall.Fire( Trigger.HungUp );
    WriteLn( LCall.ToString );

  finally
    LCall.Free;
  end;
end;

begin
  try
    Test;
  except
    on E: Exception do
      WriteLn( E.ClassName, ': ', E.Message );
  end;
  ReadLn;

end.
Und die Ausgabe:
Code:
StateMachine { State = OffHook, PermittedTriggers = { CallDialed } }
StateMachine { State = Ringing, PermittedTriggers = { HungUp, CallConnected } }
StateMachine { State = Active, PermittedTriggers = { PlacedOnHold, LeftMessage, HungUp } }
StateMachine { State = OnHold, PermittedTriggers = { TakenOffHold, PhoneHurledAgainstWall, HungUp } }
StateMachine { State = Active, PermittedTriggers = { PlacedOnHold, LeftMessage, HungUp } }
StateMachine { State = OnHold, PermittedTriggers = { TakenOffHold, PhoneHurledAgainstWall, HungUp } }
Duration: 0ms
StateMachine { State = OffHook, PermittedTriggers = { CallDialed } }
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
 
mkinzler

 
Delphi 10.4 Sydney
 
#2
  Alt 8. Sep 2015, 05:48

Das wäre doch ein Produkt für Delphinus
Markus Kinzler
  Mit Zitat antworten Zitat
DonAlfredo
 
#3
  Alt 8. Sep 2015, 10:46
Thank you very much !!!
I was awaiting this eagerly ...

Question (at the moment, I did not look closely into the sources):
Would a port to Free Pascal be possible / difficult / useless ?

Thanks, Alfred.
Alfred
  Mit Zitat antworten Zitat
mkinzler

 
Delphi 10.4 Sydney
 
#4
  Alt 8. Sep 2015, 10:54
I guess it's not impossible but because it uses delphi generics and rtti excessively many adaption may be made.

But I haven't had a very close look neither.
Markus Kinzler

Geändert von mkinzler ( 8. Sep 2015 um 11:15 Uhr)
  Mit Zitat antworten Zitat
DonAlfredo
 
#5
  Alt 8. Sep 2015, 11:11
I just had a look at the sources!
FPC is not possible at the moment.
It uses nested generics, and current FPC cannot handle this.
E.g.: FTriggerBehaviours: TObjectDictionary<TTrigger, TObjectList<TTriggerBehaviour>>;

But few months ago, I did port the same statemachine to FPC.
I will have a look and check again against Sir Rufo's and make public if ok !
Alfred
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

 
Delphi 10 Seattle Enterprise
 
#6
  Alt 8. Sep 2015, 11:34

Das wäre doch ein Produkt für Delphinus
Ja, ich überlege aber noch, wie ich das am besten verpacke. Ich wollte noch das ein oder andere auf github schieben (z.B. IdleWorker, BackgroundWorker, ...) und da gibt es bei den Types, Utils schon Überschneidungen.

Wenn das mal komplett ist, dann geht das auch zu Delphinus ...
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

 
Delphi 10 Seattle Enterprise
 
#7
  Alt 8. Sep 2015, 11:36
I just had a look at the sources!
FPC is not possible at the moment.
Yes, FPC or any backward compatibility was not in my mind
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

 
Delphi 10.1 Berlin Enterprise
 
#8
  Alt 8. Sep 2015, 11:48
Da bist du mir zuvor gekommen - wollte schon seit einiger Zeit eine Statemachine in Spring4D einfügen - Stateless war auch eins meiner möglichen Vorlagen.
Stefan
  Mit Zitat antworten Zitat
franktron

 
Delphi 10.2 Tokyo Enterprise
 
#9
  Alt 8. Sep 2015, 12:20
Mal eine Doofe Frage, was macht man damit und was tut das.
Frank
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

 
Delphi 10.1 Berlin Enterprise
 
#10
  Alt 8. Sep 2015, 12:31
https://de.wikipedia.org/wiki/Endlicher_Automat
Stefan
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 3  1 23   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 23:51 Uhr.
Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2020 by Daniel R. Wolf