AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) Probleme beim Auslesen von Registry Keys

Probleme beim Auslesen von Registry Keys

Ein Thema von Andidreas · begonnen am 7. Okt 2015 · letzter Beitrag vom 24. Okt 2015
Antwort Antwort
Seite 2 von 2     12
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#11

AW: Probleme beim Auslesen von Registry Keys

  Alt 7. Okt 2015, 17:49
Warum keine gescheite Fehlerbehandlung? MessageDlg('Could not open Registry Key!', mtError, [mbOK], 0); Damit weißt du so viel wie vorher. RaiseLastOSError gibt dir eine gescheite Fehlermeldung aus, womit du auch was anfangen kannst.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#12

AW: Probleme beim Auslesen von Registry Keys

  Alt 7. Okt 2015, 18:16
Warum keine gescheite Fehlerbehandlung? MessageDlg('Could not open Registry Key!', mtError, [mbOK], 0); Damit weißt du so viel wie vorher. RaiseLastOSError gibt dir eine gescheite Fehlermeldung aus, womit du auch was anfangen kannst.
Definitiv Nein, so nicht. Denn du weißt nicht, was diese Klasse danach noch alles an API-Aufrufen veranstaltet. Aus diesem Grunde gibt es - ja ist komisch - Delphi-Referenz durchsuchenTRegistry.LastError und die Exception löst man dann mit RaiseLastOSError( regKey.LastError, sLineBreak + RegKeyStr ); und erhält eine ganz wunderbare Fehlermeldung.

Und wenn kein erfolgreicher OpenKey(ReadOnly), dann braucht es auch keinen CloseKey.
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#13

AW: Probleme beim Auslesen von Registry Keys

  Alt 7. Okt 2015, 18:23
Ab welcher Version gibt es denn die Methode?

Und warum sollte ein Aufruf von RaiseLastOSError zu Problemen führen? Mit deiner Begründung dürfte man die Funktion nie aufrufen, egal in was für einen Code.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#14

AW: Probleme beim Auslesen von Registry Keys

  Alt 7. Okt 2015, 18:37
Ab welcher Version gibt es denn die Methode?

Und warum sollte ein Aufruf von RaiseLastOSError zu Problemen führen? Mit deiner Begründung dürfte man die Funktion nie aufrufen, egal in was für einen Code.
Nun schauen wir an, was die Doku dazu sagt:
Zitat:
You should call the GetLastError function immediately when a function's return value indicates that such a call will return useful data. That is because some functions call SetLastError with a zero when they succeed, wiping out the error code set by the most recently failed function.
Und ohne eine genaue Analyse der Klasse TRegistry kann man nicht sagen, was da noch für API-Calls ausgeführt werden. Somit wäre das ein Fall von "kann funktionieren, muss aber nicht und vor allem kann irgendwann dann mal gar nicht mehr funktionieren".

Sinnvoll ist hier auch ein ClassHelper
Delphi-Quellcode:
interface

uses
  System.Win.Registry;

type
  HRegistry = class helper for TRegistry
    procedure ThrowLastError( const AdditionalInfo: string = '' );
    procedure OpenKeySafe( const Key: string; CanCreate: Boolean );
    procedure OpenKeyReadOnlySafe( const Key: string );
  end;

implementation

uses
  System.StrUtils,
  System.SysUtils;

{ HRegistry }

procedure HRegistry.OpenKeyReadOnlySafe( const Key: string );
begin
  if not OpenKeyReadOnly( Key )
  then
    ThrowLastError( Key );
end;

procedure HRegistry.OpenKeySafe( const Key: string; CanCreate: Boolean );
begin
  if not OpenKey( Key, CanCreate )
  then
    ThrowLastError( Key );
end;

procedure HRegistry.ThrowLastError( const AdditionalInfo: string );
begin
  if AdditionalInfo = ''
  then
    RaiseLastOSError( LastError )
  else
    RaiseLastOSError( LastError, sLineBreak + AdditionalInfo );
end;
Und dann sieht das so aus
Delphi-Quellcode:
procedure TForm1.Button30Click(Sender: TObject);

var
  regKey : TRegistry;
begin
  regKey := TRegistry.Create(KEY_READ OR KEY_WOW64_64KEY);
  Try
    regKey.RootKey := HKEY_LOCAL_MACHINE;
    regKey.OpenKeyReadOnlySafe('SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update');
    try
      ShowMessage( regKey.ReadString( 'NextDetectionTime' ) );
    finally
      regKey.CloseKey();
    end;
  Finally
    regKey.Free;
  End;
end;
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)

Geändert von Sir Rufo ( 7. Okt 2015 um 18:40 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#15

AW: Probleme beim Auslesen von Registry Keys

  Alt 7. Okt 2015, 19:18
Nun ja. Mit meinem Delphi kann ich von Helper Functions nur träumen.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#16

AW: Probleme beim Auslesen von Registry Keys

  Alt 7. Okt 2015, 19:22
Nun ja. Mit meinem Delphi kann ich von Helper Functions nur träumen.
Na dann einfach ableiten und dort noch dazupacken
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
SlpLow

Registriert seit: 4. Nov 2013
28 Beiträge
 
#17

AW: Probleme beim Auslesen von Registry Keys

  Alt 24. Okt 2015, 23:09
Nun ja. Mit meinem Delphi kann ich von Helper Functions nur träumen.
Code:
//Autor GunSmoker
resourcestring
  SMsgOSError = '%s' + sLineBreak + 'System Error. Code: %d.' + sLineBreak + '%s';
  SMsgUnkOSError = '%s' + sLineBreak + 'A call to an OS function failed';

procedure RaiseLastOSError(LastError: Integer; const AMsg: String); overload;
var
  Error: EOSError;
begin
  if AMsg = '' then
    RaiseLastOSError(LastError);

  if LastError <> 0 then
    Error := EOSError.CreateResFmt(@SMsgOSError,
      [AMsg, LastError, SysErrorMessage(LastError)])
  else
    Error := EOSError.CreateResFmt(@SMsgUnkOSError, [AMsg]);
  Error.ErrorCode := LastError;
  raise Error;
end;

Geändert von SlpLow (25. Okt 2015 um 09:32 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 03:33 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf