AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

TThread: Synchronize() priorisieren?

Ein Thema von romber · begonnen am 29. Mär 2016 · letzter Beitrag vom 4. Apr 2016
Antwort Antwort
Seite 1 von 2  1 2   
romber

Registriert seit: 15. Apr 2004
Ort: Köln
1.163 Beiträge
 
Delphi 10 Seattle Professional
 
#1

TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 12:42
Hallo!

Ich habe mehrere Threads, die zeitkritische Daten aus unterschiedlichen Quellen geliefert bekommen. Die Threads haben alle eins gemeinsam: irgendwan greifen die alle an ein bestimmtes GUI-Objekt zu, synchroniziert natürlich. Besteht die Möglichkeit, einen Thread so zu priorisieren, dass er immer Vorrang bei synchronisiertem Zugriff auf die GUI hat? Dabei möchten ich keinesfalls die gesammte Thread-Prioritöt verändern, sondern nur das es bei Synchronize höhere Priorität hat.
Geht das irgendwie?

Danke!
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
40.477 Beiträge
 
Delphi 11 Alexandria
 
#2

AW: TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 12:46
Nein, wer zuerst kommt, malt zuerst.
Die Liste der Synchronisationen wird der Reihe nach abgearbeitet.

Wenn nicht gewünscht, dann wirst du die Synchronisierung wohl selber implementieren müssen.
z.B. die "Callbacks" in eine TThreadList eintragen, dann eine Message (Send oder Post) an den Hauptthread schicken und da diese Liste priorisiert abarbeiten.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
5.962 Beiträge
 
Delphi 10 Seattle Enterprise
 
#3

AW: TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 12:53
Was er sagt: Synchronize ist ein blockierender Aufruf. Er stellt dem Hauptthread einen Methodenzeiger in einer "Hier, arbeite das ab"-Warteschlange hinten an. Die Reihenfolge könnte man vielleicht mit viel Gefummel verändern, aber ich glaube was du vorhast ist nicht der beste Ansatz.

Der Thread sollte gar nichts mit der Oberfläche zu tun haben sondern nur die jeweils aktuellen Daten bereitstellen. Wenn es neue Daten gibt, kann er ja ein Event auslösen und die Oberfläche zeigt die jeweils aktuellen Daten an wie sie grade Lust hat.
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
9.844 Beiträge
 
Delphi 11 Alexandria
 
#4

AW: TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 13:35
Man sollte auch prüfen, ob das Synchronize hier nicht durch ein Queue ersetzt werden kann. Solange der Thread nicht auf das Ergebnis bzw. den Abschluss der Synchronize-Operation angewiesen ist, wäre Queue (non-blocking) hier vielleicht die bessere Wahl.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
romber

Registriert seit: 15. Apr 2004
Ort: Köln
1.163 Beiträge
 
Delphi 10 Seattle Professional
 
#5

AW: TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 16:37
Danke für die schnelle Reaktionen!

Der Thread sollte gar nichts mit der Oberfläche zu tun haben sondern nur die jeweils aktuellen Daten bereitstellen. Wenn es neue Daten gibt, kann er ja ein Event auslösen und die Oberfläche zeigt die jeweils aktuellen Daten an wie sie grade Lust hat.
Das habe ich jetzt nicht ganz verstanden In meinem Fall mache ich doch nichts anderes mit Synchronize(). Ich rufe damit eine Metode des Grids (GUI), die für die Visualisierung der Daten zuständig ist. Oder was ist mit einem Event gemeint?

Man sollte auch prüfen, ob das Synchronize hier nicht durch ein Queue ersetzt werden kann. Solange der Thread nicht auf das Ergebnis bzw. den Abschluss der Synchronize-Operation angewiesen ist, wäre Queue (non-blocking) hier vielleicht die bessere Wahl.
Danfür für diesen Hinweis. Die Threads sind tatsächlich nicht auf den Ergebnis der Synchronize angewiesen. Bringt Queue() neben dem Vorteil, dass der Threadablauf nicht blockiert wird, irgendwelche Nachteile mit sich?
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
9.844 Beiträge
 
Delphi 11 Alexandria
 
#6

AW: TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 17:02
Bringt Queue() neben dem Vorteil, dass der Threadablauf nicht blockiert wird, irgendwelche Nachteile mit sich?
Nicht, daß ich wüsste.
Synchronize = Arbeite diese Methode bei nächter Gelegenheit im Hauptthread ab und warte solange bis sie fertig ist.
Queue = Arbeite diese Methode bei nächter Gelegenheit im Hauptthread ab.
Es kann allerdings passieren, daß bei Queue die Methode gar nicht abgearbeitet wird, da bei Freigabe der TThread-Instanz alle noch vorhandenen Queue-Events gelöscht werden. Dem kann man aber vorbeugen, in dem man anstatt der einfachen Queue-Methode die gleichnamige Klassenmethode mit dem zusätzlichen TThread-Parameter an erster Stelle verwendet und diesen als nil übergibt. Dann kann das zwar theoretisch immer noch passieren, aber nur wenn das ganze Programm vor Abarbeiten des Queue-Events beendet wird. Das wäre übrigens bei Synchronize auch der Fall.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
5.962 Beiträge
 
Delphi 10 Seattle Enterprise
 
#7

AW: TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 17:06
Ich rufe damit eine Metode des Grids (GUI), die für die Visualisierung der Daten zuständig ist. Oder was ist mit einem Event gemeint?
Mit dem Event war gemeint, den Thread nicht von deiner Oberfläche abhängig zu machen. Den Thread sollte es nichts angehen, was wie auf welche Labels kommt, sondern man sollte ihm von außen übergeben, was getan werden soll wenn neue Daten gesammelt wurden. Dann kannst man auch die Oberfläche komplett überarbeiten ohne die Logik im Hintergrund wieder anfassen zu müssen. Oder die Threads in einer anderen Anwendung wiederverwenden. Oder man kommt nicht aus dem Tritt wenn die Temperatur bei manchen Kunden nun bitte in Fahrenheit und nicht Celsius angezeigt werden soll.


Als Beispiel mit TNotifyEvent , im Endeffekt das gleiche wie das OnClick bei einem TButton :

Formular:
(Braucht ein Label "airPressureLabel" und ein "temperatureLabel")
Delphi-Quellcode:
unit Unit3;

interface

uses
   System.SysUtils, System.SyncObjs, System.Classes,
   Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls,
   Threads
;

type
   TForm3 = class(TForm)
      temperatureLabel: TLabel;
      airPressureLabel: TLabel;
      procedure FormCreate(Sender: TObject);
      private var
         airPressureThread: TPressureThread;
         temperatureThread: TTemperatureThread;
      private
         procedure handleNewData(Sender: TObject);
   end;

var
   Form3: TForm3;

implementation

{$R *.dfm}

procedure TForm3.FormCreate(Sender: TObject);
begin
   airPressureThread := TPressureThread.Create(True);
   temperatureThread := TTemperatureThread.Create(True);

   airPressureThread.OnNewData := handleNewData;
   temperatureThread.OnNewData := handleNewData;

   airPressureThread.Start();
   temperatureThread.Start();
end;

procedure TForm3.handleNewData(Sender: TObject);
var
   value: Single;
begin
   if (Sender = airPressureThread) then begin
      value := airPressureThread.getAirPressure();
      airPressureLabel.Caption := String.Format('Pressure: %f Pa', [value]);
   end;

   if (Sender = temperatureThread) then begin
      value := temperatureThread.getTemperature();
      temperatureLabel.Caption := String.Format('Temperature: %f °C', [value]);
   end;
end;

end.
Zweite Unit "Threads":

Delphi-Quellcode:
unit Threads;

interface uses System.Classes, System.SyncObjs;

type
   /// <summary>
   /// Abstrakte Oberklasse für Threads die Daten
   /// bereitstellen und mit <c>OnNewData</c> signalisieren
   /// dass neue Daten bereitliegen
   /// </summary>
   TDataThread = class(TThread)
      protected var
         mutex: TSynchroObject;
      protected
         procedure triggerNewDataEvent();
      public var
         /// <remarks>
         /// Wird immer <b>im Hauptthread</b> ausgeführt
         /// </remarks>
         OnNewData: TNotifyEvent;
      public
         constructor Create(const CreateSuspended: Boolean);
         destructor Destroy(); override;
   end;

   TTemperatureThread = class(TDataThread)
      protected const
         noTemperature = -273.15;
      protected var
         FTemperature: Single;
      protected
         function retrieveTemperature(): Single;
         procedure Execute(); override;
      public
         constructor Create(const CreateSuspended: Boolean);
         /// <returns>
         /// Temperatur in °C
         /// </returns>
         /// <remarks>
         /// Wenn noch keine Temperatur aufgezeichnet wurde wird
         /// <c>-273.15</c> zurückgegeben
         /// </remarks>
         function getTemperature(): Single;
   end;

   TPressureThread = class(TDataThread)
      protected procedure Execute(); override;
      /// <returns>
      /// Druck in Pa
      /// </returns>
      public function getAirPressure(): Single;
   end;

implementation

{ TDataThread }

constructor TDataThread.Create(const CreateSuspended: Boolean);
begin
   inherited Create(CreateSuspended);
   mutex := TCriticalSection.Create();
end;

destructor TDataThread.Destroy();
begin
   mutex.Free();
   inherited;
end;

procedure TDataThread.triggerNewDataEvent();
begin
   if not Assigned(OnNewData) then Exit;
   TThread.Queue(
      nil,
      procedure()
      begin
         OnNewData(self);
      end
   );
end;

{ TTemperatureThread }

constructor TTemperatureThread.Create(const CreateSuspended: Boolean);
begin
   inherited Create(CreateSuspended);
   FTemperature := noTemperature;
end;

procedure TTemperatureThread.Execute();
var
   currentTemperature: Single;
begin
   while (not Terminated) do begin
      currentTemperature := retrieveTemperature();
      if (currentTemperature = noTemperature) then Continue;

      mutex.Acquire();
      try
         FTemperature := currentTemperature;
      finally
         mutex.Release();
      end;

      triggerNewDataEvent();
   end;
end;

function TTemperatureThread.getTemperature(): Single;
begin
   mutex.Acquire();
   try
      Result := FTemperature;
   finally
      mutex.Release();
    end;
end;

function TTemperatureThread.retrieveTemperature(): Single;
begin
   Sleep( 1000 + Random(1000) );
   Result := 42.0 + Random() * 10.0;
end;

{ TPressureThread }

procedure TPressureThread.Execute();
begin
   while (not Terminated) do begin
      // Platzhalter
    end;

end;

function TPressureThread.getAirPressure(): Single;
begin
   // Platzhalter
end;


end.
  Mit Zitat antworten Zitat
Benutzerbild von Mavarik
Mavarik

Registriert seit: 9. Feb 2006
Ort: Stolberg (Rhld)
4.076 Beiträge
 
Delphi 10.3 Rio
 
#8

AW: TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 17:32
Der Thread sollte gar nichts mit der Oberfläche zu tun haben sondern nur die jeweils aktuellen Daten bereitstellen. Wenn es neue Daten gibt, kann er ja ein Event auslösen und die Oberfläche zeigt die jeweils aktuellen Daten an wie sie grade Lust hat.
emm... nix anderes ist ein Syncronize... Ob Du nun wie Du im Beispiel den Event im Queue auslößt oder mit Sync es aus dem Thread selber machst... Ich erstmal "fast" kein Unterschied...

Bringt Queue() neben dem Vorteil, dass der Threadablauf nicht blockiert wird, irgendwelche Nachteile mit sich?
Man muss sich im klaren sein was wann passiert...

Beispiel für Queue aus dem Thread oder wie Günther es geschrieben hat ein Event dann die Daten von der anderen Seite aus holt...

Beispiel:

Ein Thread erzeugt permanent Daten und zwar nicht nur ein Integer sonst was kompliziertes...
Bei einem Syncronize musst du zwar warten auf den UI-Thread aber kannst sicher danach die Daten verwerfen...
Bei ein Queue Aufruf, musst Du sicher stellen, dass zum Zeitpunkt wo der UI-Thread die Daten darstellen will, die Daten auch noch vorhanden sind. Noch schwieriger ist es, wenn Du die Kontrolle - wie Günther - an ein anderes Programmteil übergeben hast... Denn falls der UI-Thread die Daten lesen will, muss sichergestellt werden, dass der Thread die Daten nicht gerade neu- oder überschreibt.

Musst Du alle Zwischenschritte immer darstellen? Ich habe hier z.B. eine Routine programmiert, die immer wenn der Thread neue Daten erzeugt und der UI-Thread die Daten noch nicht verarbeitet hat, der letzte Datensatz verworfen und sofort gegen den neuen Ausgetauscht wird.

Für Dein Problem, würde ich einfach 2 oder wie viele auch immer Du brauchst eigenen Threadsichere Queues erzeugen und diese über einen Workerthread der gemäß Priorität die einzelen Queues abarbeitet und dann problemlos Syncronisieren kann.

Mavarik
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
5.962 Beiträge
 
Delphi 10 Seattle Enterprise
 
#9

AW: TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 17:38
emm... nix anderes ist ein Syncronize...
Richtig, der benutzt auch TThread.Synchronize() oder .Queue() oder was auch immer. Es ging darum, den Thread nicht auf Gedeih und Verderb an irgendein Formular zu ketten sondern von außen festzulegen was geschehen soll. Vielleicht willst du auch nichts anzeigen, sondern nur loggen. Oder beides. Solche Anforderungen ändern sich ständig. Aber deshalb fasst man nicht ständig das Herzstück an.
  Mit Zitat antworten Zitat
Benutzerbild von Mavarik
Mavarik

Registriert seit: 9. Feb 2006
Ort: Stolberg (Rhld)
4.076 Beiträge
 
Delphi 10.3 Rio
 
#10

AW: TThread: Synchronize() priorisieren?

  Alt 29. Mär 2016, 17:46
emm... nix anderes ist ein Syncronize...
Richtig, der benutzt auch TThread.Synchronize() oder .Queue() oder was auch immer. Es ging darum, den Thread nicht auf Gedeih und Verderb an irgendein Formular zu ketten sondern von außen festzulegen was geschehen soll. Vielleicht willst du auch nichts anzeigen, sondern nur loggen. Oder beides. Solche Anforderungen ändern sich ständig. Aber deshalb fasst man nicht ständig das Herzstück an.
Kommt darauf an, wenn der Thread der "einzige" ist der weiß was richtig ist, geht es nicht anders...
Aber ich verstehe deinen Einwand/Ansatz!
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 19:18 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf