AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Generics TList<> sortieren

Ein Thema von Shark99 · begonnen am 19. Jul 2016 · letzter Beitrag vom 25. Jul 2016
Antwort Antwort
Shark99

Registriert seit: 16. Mai 2007
403 Beiträge
 
#1

Generics TList<> sortieren

  Alt 19. Jul 2016, 13:30
Ich versuche mit Delphi Xe5 eine generische Liste zu sortieren und bekomme vom Compiler die Fehlermeldung:

[dcc32 Error] SortUnit.pas(255): E2035 Not enough actual parameters

Was mache ich falsch?
Delphi-Quellcode:
type

  TDataItem = class
    Modified: int64;
    Data: string;

    Constructor Create(iModified: int64; sData: string);
  end;

var

  TestList: TList<TDataItem>;

  ListModifiedComparer: IComparer<TDataItem>;
  
...

  ListModifiedComparer := TDelegatedComparer<TDataItem>.Construct(
                          function(const L,R:TDataItem): integer;
                          begin
                              Result := 0;
                              if (L.Modified > R.Modified) then Result := 1
                              else if (L.Modified < R.Modified) then Result := -1;
                          end;
                          );
                         
 TestList.Sort(ListModifiedComparer); // Zeile 255
  Mit Zitat antworten Zitat
bra

Registriert seit: 20. Jan 2015
711 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#2

AW: Generics TList<> sortieren

  Alt 19. Jul 2016, 13:33
Versuchs mal mit TDelegatedComparer<TDataItem>.Create statt Construct.

und ich meine die ; in der inneren Function dürfen nicht sein (kann mich aber täuschen):

Delphi-Quellcode:
ListModifiedComparer := TDelegatedComparer<TDataItem>.Create(
                          function(const L,R:TDataItem): integer
                          begin
                              Result := 0;
                              if (L.Modified > R.Modified) then Result := 1
                              else if (L.Modified < R.Modified) then Result := -1;
                          end
                          );

Geändert von bra (19. Jul 2016 um 13:36 Uhr)
  Mit Zitat antworten Zitat
Shark99

Registriert seit: 16. Mai 2007
403 Beiträge
 
#3

AW: Generics TList<> sortieren

  Alt 19. Jul 2016, 13:37
Danke, hat geklappt.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu
Online

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
38.731 Beiträge
 
Delphi 10.4 Sydney
 
#4

AW: Generics TList<> sortieren

  Alt 19. Jul 2016, 13:59
PS: Es gibt auch schon was Fertiges:
Delphi-Quellcode:
function(const L, R: TDataItem): Integer
begin
  Result := CompareValue(L.Modified, R.Modified); // oder CompareStr/CompareText
end

// lässt sich auch verschachteln
function(const L, R: TDataItem): Integer
begin
  Result := CompareValue(L.Modified, R.Modified);
  if Result = 0 then
    Result := CompareValue(L.WasAnderes, R.WasAnderes);
  if Result = 0 then
    ...
end
Aber wenn, dann kann es nie schaden, wenn man die "korrekten" Typen und passende Konstanten verwendet.
Delphi-Quellcode:
function(const A, B: xxxx): TValueRelationship;
begin
  if A = B then //if SameValue(A, B, Epsilon) then
    Result := EqualsValue
  else if A < B then
    Result := LessThanValue
  else
    Result := GreaterThanValue;
end

function(const A, B: xxxx): TValueRelationship;
begin
  Result := EqualsValue;
  if A < B then
    Result := LessThanValue
  else if A > B then
    Result := GreaterThanValue;
end
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
3.842 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#5

AW: Generics TList<> sortieren

  Alt 25. Jul 2016, 15:35
Man kann auch einen kleinen Trick nutzen.

Da TComparison<T> und IComparer<T> binärkompatibel sind, kann man die anonyme Methode direkt hardcasten:

Delphi-Quellcode:
TestList.Sort(IComparer<TDataItem>(
  function(const L, R: TDataItem): Integer
  begin
    Result := CompareValue(L.Modified, R.Modified);
  end));
Schöner wär natürlich, wenn TList<T> direkt ein Sort overload mit TComparison<T> hätte...
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 12:04 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf