OpenSSL - MemoryLeak bei Verwendung eines X509-Zertifikats

[Bbommel]

Ich muss mal diesen gut abgehangenen Thread ausgraben, auf den ich durch Google gestoßen bin. Ich habe gerade exakt das gleiche Problem, dass jeder Aufruf von d2i_x509 zu einem kleinen Speicherleck führt. Ziel bei mir ist es letztlich, ein in einem JSON Web Key angegebenes Zertifikat auszulesen und dann später im PEM-Format weiterzunutzen.

Kleiner Code-Auszug aus einem Testprogramm:

Delphi-Quellcode:

procedure TForm2.ButtonDecodeClick(Sender: TObject);

var
  byteArray: TBytes;
  pr: PX509;
  pubKey: string;
  bio: PBIO;

begin
  byteArray:=TNetEncoding.Base64.DecodeStringToBytes(MemoKey.Lines.Text);
  MemoStatus.Lines.Add('base decoded. Length: '+length(byteArray).ToString);
  if IdSSLOpenSSLHeaders.Load then begin
    MemoStatus.Lines.Add('openssl loaded.');
    pr:=d2i_X509(nil,@@byteArray[0],length(byteArray));
    if pr<>nil then begin
      MemoStatus.Lines.Add('X509 read.');
      MemoStatus.Lines.Add('Name: '+X509_NAME_oneline(X509_get_subject_name(pr),nil,0));
      MemoStatus.Lines.Add('Public Key Length: '+pr.cert_info.key.public_key.length.ToString);
      MemoStatus.Lines.Add('Issuer name: '+X509_NAME_oneline(X509_get_issuer_name(pr),nil,0));
      bio:=BIO_new(BIO_s_mem);
      PEM_write_bio_X509(bio,pr);
      BIO_read(bio,byteArray,BIo.num_write);
      pubKey:=string(PAnsiChar(@byteArray[0]));
      MemoPEM.Lines.Text:=pubKey;
      SetLength(bytePubKey,0);
      BIO_free(bio);
      X509_free(pr);
    end else
      MemoStatus.Lines.Add('Failed read X509.');

    SetLength(byteArray,0);
  end;
end;

Wie ihr seht, passiert hier noch etwas mehr (nämlich die Umwandlung in einen String im PEM-Format - falls jemand weiß, ob das einfacher geht, gerne her damit). Ich bin erstmal froh, dass am Ende das erhoffte Ergebnis rauskommt.

Aber ich habe nun auch immer das Speicherleck. Ich kann den ganzen Code reduzieren zu

Delphi-Quellcode:

procedure TForm2.ButtonDecodeClick(Sender: TObject);

var
  byteArray, p: TBytes;
  pr: PX509;
  bytePubKey: TBytes;
  pubKey: string;
  bio: PBIO;

begin
  byteArray:=TNetEncoding.Base64.DecodeStringToBytes(MemoKey.Lines.Text);
  MemoStatus.Lines.Add('base decoded. Length: '+length(byteArray).ToString);
  if IdSSLOpenSSLHeaders.Load then begin
    MemoStatus.Lines.Add('openssl loaded.');
    pr:=d2i_X509(nil,@@byteArray[0],length(byteArray));
    if pr<>nil then
      X509_free(pr);
    else
      MemoStatus.Lines.Add('Failed read X509.');
    SetLength(byteArray,0);
  end;
end;

...und bekomme immer noch ein Speicherleck angezeigt.

Irgendwer vielleicht mittlerweile eine Idee? @DeddyH, hast du das damals gelöst bekommen oder nimmst du das Leck seitdem resigniert in Kauf?

[hoika]

Hallo,
dein byteArray wird erzeugt, aber nur beim erfolgreichen Load per SetLength freigegeben.

[Bbommel]

Zitat von hoika:

dein byteArray wird erzeugt, aber nur beim erfolgreichen Load per SetLength freigegeben.

Das stimmt natürlich und wäre prinzipiell auch eine Falle für ein Speicherleck, ist aber nur ein Fehler hier im Demoprojekt. Da die OpenSSL-Bibliothek bei mir immer geladen werden kann, ist das ByteArray auch immer freigegeben worden.

Leider ist das noch nicht die eigentliche Ursache.

Hm. Die Doku von OpenSSL gibt ja an, dass der Pointer auf das Array irgendwie verbogen wird und nachher hinter die übergebenen Byts zeigt. Irgendwie wird es wohl damit zusammenhängen. Man müsste sich also die ursprüngliche Adresse merken und sichergehen, dass man das richtige freigibt.

[TiGü]

Zitat von Bbommel:

Man müsste sich also die ursprüngliche Adresse merken und sichergehen, dass man das richtige freigibt.

Wenn bloß einer geschrieben hätte, wie man das macht...

Zitat:

WARNINGS
The use of temporary variable is mandatory.

Du hast doch schon eine p: TBytes Variable in deiner Testfunktion drin. Nutze sie doch!

[Bbommel]

Zitat von TiGü:

Zitat:

WARNINGS
The use of temporary variable is mandatory.

Du hast doch schon eine p: TBytes Variable in deiner Testfunktion drin. Nutze sie doch!

Jepp, das p ist da noch drin, weil ich gedacht hatte, ich hätte verstanden, was mir die Doku sagen will. Ich hatte das dann so umgesetzt:

Delphi-Quellcode:

procedure TForm2.ButtonDecodeClick(Sender: TObject);

var
  byteArray, p: TBytes;
  pr: PX509;
  bytePubKey: TBytes;
  pubKey: string;
  bio: PBIO;

begin
  byteArray:=TNetEncoding.Base64.DecodeStringToBytes(MemoKey.Lines.Text);
  MemoStatus.Lines.Add('base decoded. Length: '+length(byteArray).ToString);
  if IdSSLOpenSSLHeaders.Load then begin
    MemoStatus.Lines.Add('openssl loaded.');
    p:=byteArray;  // <---- Hier die wesentliche Änderung!
    pr:=d2i_X509(nil,@@p[0],length(byteArray));   // <---- und natürlich hier
    if pr<>nil then begin
      MemoStatus.Lines.Add('X509 read.');
      MemoStatus.Lines.Add('Name: '+X509_NAME_oneline(X509_get_subject_name(pr),nil,0));
      MemoStatus.Lines.Add('Public Key Length: '+pr.cert_info.key.public_key.length.ToString);
      MemoStatus.Lines.Add('Issuer name: '+X509_NAME_oneline(X509_get_issuer_name(pr),nil,0));
      bio:=BIO_new(BIO_s_mem);
      PEM_write_bio_X509(bio,pr);
      SetLength(bytePubKey,bio.num_write);
      BIO_read(bio,bytePubKey,BIo.num_write);
      pubKey:=string(PAnsiChar(@bytePubKey[0]));
      MemoPEM.Lines.Text:=pubKey;
      BIO_free(bio);
      X509_free(pr);
      SetLength(bytePubKey,0);
    end else
      MemoStatus.Lines.Add('Failed read X509.');
  end;
  SetLength(byteArray,0);
end;

Das hilft auch insofern, weil ByteArray dann seinen Inhalt behält und nicht durch d2i_x509 verbogen wird und somit dann auch - denke ich mal - korrekt freigegeben wird. Das Speicherleck beim Beenden kommt trotzdem ganz genauso.

Ein zusätzliches SetLength(p,0) macht ja eigentlich keinen Sinn, denn das zeigt auf keinen von mir reservierten Speicher und entsprechend ändert es auch nichts.

[TiGü]

OPENSSL_free(p) probiert?

[Bbommel]

So geht es:

Delphi-Quellcode:

procedure TForm2.ButtonDecodeClick(Sender: TObject);

var
  byteArray: TBytes;
  pr: PX509;
  bytePubKey: TBytes;
  PArray: Pointer;     // <--- den Pointer auf das Byte-Array auch wirklich als Pointer deklarieren
  pubKey: string;
  bio: PBIO;

begin
  byteArray:=TNetEncoding.Base64.DecodeStringToBytes(MemoKey.Lines.Text);
  MemoStatus.Lines.Add('base decoded. Length: '+length(byteArray).ToString);
  if IdSSLOpenSSLHeaders.Load then begin
    MemoStatus.Lines.Add('openssl loaded.');
    PArray:=@byteArray[0];          // <--- Pointer auf den Anfang des Arrays setzen
    pr:=d2i_X509(nil,@PArray,length(byteArray));     // <--- Pointer auf den Pointer an die Funktion übergeben
    if pr<>nil then begin
      MemoStatus.Lines.Add('X509 read.');
      MemoStatus.Lines.Add('Name: '+X509_NAME_oneline(X509_get_subject_name(pr),nil,0));
      MemoStatus.Lines.Add('Public Key Length: '+pr.cert_info.key.public_key.length.ToString);
      MemoStatus.Lines.Add('Issuer name: '+X509_NAME_oneline(X509_get_issuer_name(pr),nil,0));
      bio:=BIO_new(BIO_s_mem);
      PEM_write_bio_X509(bio,pr);
      SetLength(bytePubKey,bio.num_write);
      BIO_read(bio,bytePubKey,BIo.num_write);
      pubKey:=string(PAnsiChar(@bytePubKey[0]));
      MemoPEM.Lines.Text:=pubKey;
      BIO_free(bio);
      X509_free(pr);
      SetLength(bytePubKey,0);
    end else
      MemoStatus.Lines.Add('Failed read X509.');
  end;
  SetLength(byteArray,0);
end;

In der Variante bekomme ich kein Speicherleck mehr. Danke fürs In-die-richtige-Richtung-Schieben.

Vermutlich kommt irgendwas im Speichermanagement durcheinander, wenn man die temporäre Variable auch als ByteArray und nicht als Pointer deklariert. Mal so geraten. So funktioniert es jedenfalls. Schönes Rest-Wochenende allen, die hier reingucken!