Hallo,

Ich möchte quasi eine C++-Klasse die mir als byte Array vorliegt in ihre Datentypen wiederherstellen.
Beispielhaft ein Array ($00, $00, $A4, $43, $00, $00, $A4, $43). Hier liegen 8 bytes vor die ich gerne als 2 float Werte rekonstruieren möchte.

Derzeitig rufe ich einfach mehrmals mal die ReadProcessMemory Routine mit den unterschiedlichen Offsets.

zusammenfalten · markieren

Delphi-Quellcode:

begin
  FBasePointer := BasePointer;
  if FBasePointer <> 0 then
  begin
    FMemoryHandle.Read(BasePointer + NAVIGATION_POINTER_OFFSET, FNavigationPointer);
    Position := TPosition.Create(FMemoryHandle, FNavigationPointer);
    FMemoryHandle.Read(BasePointer + VISUAL_POSITION_X_OFFSET, VisualPosition.X);
    FMemoryHandle.Read(BasePointer + VISUAL_POSITION_Y_OFFSET, VisualPosition.Y);
    FMemoryHandle.Read(BasePointer + VISUAL_POSITION_Z_OFFSET, VisualPosition.Z);
    FMemoryHandle.Read(BasePointer + HEALTH_OFFSET, FHealth);
    FMemoryHandle.Read(BasePointer + MAXHEALTH_OFFSET, FMaxHealth);
    FMemoryHandle.Read(BasePointer + PLAYERINFO_POINTER_OFFSET, FPlayerInfoPointer);
    FMemoryHandle.Read(BasePointer + WEAPON_MANAGER_POINTER_OFFSET, FPedWeaponManagerPointer);
    FMemoryHandle.Read(BasePointer + ARMOR_OFFSET, FArmor);
    FMemoryHandle.Read(BasePointer + VEHICLE_POINTER_OFFSET, FCurrentVehiclePointer);
  end;
end;

Am liebsten wäre mir aber wenn ich die ganze Klasse einlese und die Variablen auf die jeweiligen Positionen im gelesenen Byte Array referenzieren würden.

ich hatte die Hoffnung dass mir jemand eine Aufschlussreiche Hilfestellung bieten könnte, wie ich das möglichst dynamischer und performanter hinbekommen könnte, weil ich teilweise Klassen mit 100 Variablen lesen muss, wäre diese Methode für eine Umstellung recht mühsehlig und ob es dann auch wirklich ein Performance Gewinn wäre, empfände ich ebenfalls für fraglich.. Das ist so oder so viel mehr Aufwand als er mir in C++ vorliegen würde, da ich in C++ einfach nur die Klasse deklarieren und den gelesenen Speicherbereich als diese Interpretieren lassen müsste, aber es müsste doch wenigstens eine ähnliche Performance in Pascal möglich sein oder?

zusammenfalten · markieren

Delphi-Quellcode:

uses
  Classes, SysUtils;
var
  FMyByteArray: array of byte;
  FFloatBuffer1: array[0..3] of byte;
  FFloatBuffer2: array[0..3] of byte;
  float1: single absolute FFloatBuffer1;
  float2: single absolute FFloatBuffer2;
  muhbuffer: array[0..3] of byte;
  muh: single absolute muhbuffer;
  i, c: integer;
  output: string;
begin
  SetLength(FMyByteArray, 8);
  FMyByteArray[0] := 0;
  FMyByteArray[1] := 0;
  FMyByteArray[2] := $A4;
  FMyByteArray[3] := $43;
  FMyByteArray[4] := 0;
  FMyByteArray[5] := 0;
  FMyByteArray[6] := $A4;
  FMyByteArray[7] := $43;
  c := 0;
  for i := 0 to Length(FMyByteArray) -1 do
  begin
    if i >= 4 then
    begin
      Writeln('[', i, '] Write in Float Buffer 2 ', IntToHex(FMyByteArray[i], 2));
      FFloatBuffer2[c] := FMyByteArray[i];
      c := c + 1;
    end
    else
    begin
      Writeln('[', i, '] Write in Float Buffer 1 ', IntToHex(FMyByteArray[i], 2));
      FFloatBuffer1[i] := FMyByteArray[i];
    end;
  end;
  Writeln('Output float1: ', FloatToStr(float1), #10 + 'Output float2: ', FloatToStr(float2));
  muh := 328;
  for i := 0 to Length(FFloatBuffer1) - 1 do
    output := output + '[' +IntToStr(i) + '] ' + IntToHex(FFloatBuffer1[i], 2) + #10;
  Writeln(output, 'Output Float muh: ', FloatToStr(muh));
  Readln();
end.

Ausgabe:

markieren

Code:

[0] Write in Float Buffer 1 00
[1] Write in Float Buffer 1 00
[2] Write in Float Buffer 1 A4
[3] Write in Float Buffer 1 43
[4] Write in Float Buffer 2 00
[5] Write in Float Buffer 2 00
[6] Write in Float Buffer 2 A4
[7] Write in Float Buffer 2 43
Output float1: 328
Output float2: 328
[0] 00
[1] 00
[2] A4
[3] 43
Output Float muh: 328

Im vorraus vielen dank

Sieht für mich nach einem Fall von varianten Records aus.
Einfach mal googlen. Sieht nur auf den ersten Blick merkwürdig aus, ist aber ziemlich einfach.

Dürfte in deinem Fall etwa so aussehen:

zusammenfalten · markieren

Delphi-Quellcode:

tMyArray = Array [0..7] of Byte;

tMyFloatRec = record
  Float1 : Single;
  Float2 : Single;
end;

tMyRec = Record
  case boolean of
    true : (MyArr : tMyArray);
    false : (myFloatRec : tMyFloatRec);
end;

Ist natürlich ungeprüft und da es bei mir schon ziemlich lange her ist, dass ich das verwendet habe, bitte ich im Nachsicht, wenn es nicht ganz korrekt ist.

Ich erinnere mich gerade, dass ich damals noch einen Compiler-Schalte setzen musste, für ausgerichtete Felder. Keine Ahnung, ob das heute auch noch notwendig ist.

Vielleicht verstehe ich die Frage nicht...

Du hast ein Array woher auch immer darin sind Daten...

Gehen wir mal davon aus, dass die Datentypen in Codierung und große gleich sind...

Dann nimm einfach einen Record und move die rein?

order per Absolute...

markieren

Delphi-Quellcode:

var
  Buffer : array [0...Sizeof(MyRecord)-1] of byte;
  Datensatz : MyRecord absolute Buffer;

oder einfach

Move(Buffer[0]^,Datensatz,Sizeof(DatenSatz)) Oder ich habe es doch nicht verstanden...

beim nächsten mal probiere ich sowas offensichtliches aus, tut mir leid, läuft exzellent. Vielen Dank

zusammenfalten · markieren

Delphi-Quellcode:

type
  T2Floats = record
    Float1, Float2: single;
  end;
var
  MyBuffer: array[0..7] of byte = (0, 0, $A4, $43, 0, 0, $A4, $43);
  MyRecord: T2Floats absolute MyBuffer;
begin
  Writeln(FloatToStr(MyRecord.Float1), ' ', FloatToStr(MyRecord.Float2));
  Readln();
end.

Ich hatte heute mal versucht das umzusetzen und das habe ich teilweise auch Erfolgreich getan,
dabei musste ich feststellen dass ich jedes byte Array um 4 bytes weniger lesen muss damit es funktioniert.
Nur das "wieso?" leuchtet mir nicht ganz ein, kann vielleicht nochmal jemand helfen? rein Verständnishalber?

markieren

Code:

class CNavigation
{
public:
   char pad_0[0x20];
   Vector4 Rotation;
   char pad_1[0x20];
   Vector3 Position;

};

zusammenfalten · markieren

Delphi-Quellcode:

  TVector3 = record
    X, Y, Z: single;
  end;

  TVector4 = record
    X, Y, Z, W: single;
  end;

  TNavigation = record
    pad_0: array[0..$1C] of char; // 20
    Rotation: TVector4;
    pad_1: array[0..$1C] of char; // 20
    Position: TVector3;
  end;

.. und wenn Du mt packed records arbeitest?

Grüße
Klaus

zuerst mal ist deine convertierung c delphi falsch
0x20 ist 32 decimal
Also müsstest du das entweder

markieren

Delphi-Quellcode:

pad_0: array[0..31] of char; // 32 einträge
//Oder
pad_0: array[0..$1F] of char; // 32 einträge

Übersetzen

passt, habt vielen dank ihr beiden

markieren

Delphi-Quellcode:

  TNavigation = packed record
    pad_0: array[0..$1F] of byte; // 20
    Rotation: TVector4;
    pad_1: array[0..$1F] of byte; // 20
    Position: TVector3;
  end;

Zitat von Klaus01:

.. und wenn Du mt packed records arbeitest?

Grüße
Klaus

oder mit {$A1}