AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Object-Pascal / Delphi-Language Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

Ein Thema von a.def · begonnen am 1. Dez 2016 · letzter Beitrag vom 2. Dez 2016
Antwort Antwort
Seite 1 von 2  1 2   
a.def
(Gast)

n/a Beiträge
 
#1

Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 10:56
Delphi-Version: 5
Folgende Funktion befindet sich in meinem Code und davon eine für jedes meiner Enums
Delphi-Quellcode:
// EnumGetString(TWProcesses.wpIdle) würde string 'wpIdle' zurückgeben
function EnumGetString(aEnumValue: TWProcesses): string;
var
 bVal: Byte;
begin
 Move(aEnumValue, bVal, SizeOf(TWProcesses));
 Result := GetEnumName(TypeInfo(TWProcesses), bVal);
end;
Ist es möglich diese Funktion so abzuändern, dass ich alle meine Enums an eine einzige Funktion schicken kann, welche mir dann den String zurückgibt wie oben zu sehen auch?
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.093 Beiträge
 
Delphi 10 Seattle Enterprise
 
#2

AW: Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 10:58
Generics

http://docwiki.embarcadero.com/RADSt...BCber_Generics
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#3

AW: Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 11:36
Leider gibt es kein Constraint für Enums bei einem generischen Typ. Man verliert dabei also die Typsicherheit.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.093 Beiträge
 
Delphi 10 Seattle Enterprise
 
#4

AW: Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 11:44
Man kann den Compiler nicht zufällig anweisen keine Schlussfolgerungen über den generischen Typ anzustellen sodass der Benutzer den generischen Typ angeben muss?

Alternativ kann man, wenn einen das stört, ja einen Integer übergeben und steckt in seine "EnumZuString"-Methode dann nicht mehr "myEnum" sondern "Ord(myEnum)" rein.
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#5

AW: Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 12:08
Man kann den Compiler nicht zufällig anweisen keine Schlussfolgerungen über den generischen Typ anzustellen sodass der Benutzer den generischen Typ angeben muss?
Das habe ich jetzt nicht verstanden.


Alternativ kann man, wenn einen das stört, ja einen Integer übergeben und steckt in seine "EnumZuString"-Methode dann nicht mehr "myEnum" sondern "Ord(myEnum)" rein.
Dann fehlt aber die TypeInfo, die man für GetEnumName braucht.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.093 Beiträge
 
Delphi 10 Seattle Enterprise
 
#6

AW: Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 12:22
Das habe ich jetzt nicht verstanden.
Ich meine dass man sich eine generische Funktion schreibt bei welcher man den generischen Typen angeben MUSS. Dann hat man den Typen ja und kann sich seine TypInformation holen.

Für den Fall dass ein Enum nicht mehr als 128 (oder 256?) Einträge enthält ginge ja so etwas hier, aber perfekt ist das auch nicht . Mein Favorit ist der zweite der drei Aufrufe.


Delphi-Quellcode:
program Project16;

{$APPTYPE CONSOLE}

{$R *.res}

uses System.TypInfo;

type
   TEnum = record
      public class function GetName<T>(const enum: T): String; overload; static;
      public class function GetName<T>(const ordinalValue: System.ShortInt): String; overload; static;
   end;

{ TEnum }

class function TEnum.GetName<T>(const enum: T): String;
var
   ordinalValue: Integer;
begin
   ordinalValue := Default(Integer);
   Move(enum, ordinalValue, SizeOf(T));

   Result := GetEnumName( TypeInfo(T), ordinalValue );
end;

class function TEnum.GetName<T>(const ordinalValue: System.ShortInt): String;
begin
   Result := GetEnumName( TypeInfo(T), ordinalValue );
end;

type
   TMyEnum = (uno, dos, tres);
var
   myEnum:   TMyEnum;
begin
   myEnum := TMyEnum.dos;

   // Nicht typsicher, myEnum könnte genauso gut ein Float sein
   WriteLn( TEnum.GetName<TMyEnum>(myEnum) );

   // Typsicher, WENN man sich zwingt EXPLIZIT "TMyEnum" anzugeben
   WriteLn( TEnum.GetName<TMyEnum>(myEnum) );

   // Sieht typischer aus, aber statt myEnum könnte man ebenso gut "42" reinstecken
   WriteLn( TEnum.GetName<TMyEnum>( Ord(myEnum) ) );

   ReadLn;
end.
  Mit Zitat antworten Zitat
Benutzerbild von Zacherl
Zacherl

Registriert seit: 3. Sep 2004
4.629 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#7

AW: Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 12:36
Man kann den Compiler nicht zufällig anweisen keine Schlussfolgerungen über den generischen Typ anzustellen sodass der Benutzer den generischen Typ angeben muss?
Einen Typ angeben musst du bei einer generischen Klasse ja sowieso zwingend. Das Problem ist, dass die Delphi Generics außer class und interface keine Constraints zulassen. Wobei Constraints eh nur ein Versuch sind ein viel prägnanteres Design-Flow abzuschwächen:

Delphi-Quellcode:
class procedure TGenericClass<TEnum>.Print(Enum: TEnum);
var
  E: TEnum;
begin
  for E := Low(Enum) to High(Enum) do
  begin
    WriteLn(Ord(Enum));
  end;
end;
An dieser Stelle meldet sich der Delphi-Compiler obwohl ich die Klasse nirgends verwende mit einem Fehler, weil er einfach so davon ausgeht, dass TEnum kein Enum-Typ ist, sondern eine Klasse (bzw. untypisiert ist, oder was der Compiler auch immer an dieser Stelle als Standardtyp annimt). Dies ist mir relativ unverständlich, wenn ich mal mit den Templates in C++ vergleiche (diese sind auf der trivialsten Ebene praktisch Generics):

Der Code in Template-Funktionen wird erst dann verifiziert, sobald er auch generiert wird. Und generiert wird er einmalig für jeden distinkten Datentyp den ich tatsächlich irgendwo im Code an die Template-Klasse übergebe.
TGenericClass<TIrgendeinExistierendesEnum>.Print(MyEnum) würde also ohne Probleme funktionieren, während TGenericClass<TIrgendeineKlasse>.Print(MyClassInstance) korrekterweise den Fehler erzeugt, dass man Low natürlich nicht auf einen Klassentyp anwenden darf.

Die C++ Templates sind im Gegensatz zu den Delphi Generics sozusagen Context-aware.

Am Ende kommt jedenfalls bei raus, dass man unter Delphi gezwungen wird ziemlich viele nicht typsichere Operationen durchzuführen, bei denen man höchstens mit viel Mühe und unter Verwendung der RTTI eine teilweise Typsicherheit wiederherstellen kann:
http://www.delphipraxis.net/190944-r...alisieren.html

Edit: @Günther: Und wer hindert dich bei deiner Klasse daran einfach TEnum.GetName<TForm1>(Form1) aufzurufen?
Projekte:
- GitHub (Profil, zyantific)
- zYan Disassembler Engine ( Zydis Online, Zydis GitHub)
  Mit Zitat antworten Zitat
a.def
(Gast)

n/a Beiträge
 
#8

AW: Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 12:40
Die Antworten sind ja schon erstaunlich.
Wäre es bei so vielen Komplikationen einen schönen Code zu bekommen nicht die einfachste Möglichkeit mehrere overloaded Funktionen zu fahren?
  Mit Zitat antworten Zitat
Benutzerbild von Zacherl
Zacherl

Registriert seit: 3. Sep 2004
4.629 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#9

AW: Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 12:58
Wäre es bei so vielen Komplikationen einen schönen Code zu bekommen nicht die einfachste Möglichkeit mehrere overloaded Funktionen zu fahren?
Wir wollten dich nicht verunsichern, sondern nur auf eine mögliche Gefahr hinweisen. Ich würde es trotzdem folgendermaßen lösen:
Delphi-Quellcode:
type
  TEnumHelper<TEnum> = record
    public class function GetName(Value: TEnum): String; overload; static;
  end;

{ TEnumHelper<TEnum> }

class function TEnumHelper<TEnum>.GetName(Value: TEnum): String;
var
  TypInfo: PTypeInfo;
  TypData: PTypeData;
  V: Integer;
begin
  TypInfo := TypeInfo(TEnum);
  {$IFDEF DEBUG}
  if (TypInfo^.Kind <> tkEnumeration) then
  begin
    raise Exception.Create('Invalid generic type.');
  end;
  {$ENDIF}
  TypData := GetTypeData(TypInfo);
  case TypData^.OrdType of
    otSByte,
    otUByte:
      V := PByte(@Value)^;
    otSWord,
    otUWord:
      V := PWord(@Value)^;
    otSLong,
    otULong:
      V := PInteger(@Value)^;
  end;
  Result := GetEnumName(TypeInfo(TEnum), V);
end;
Du solltest halt nur aufpassen, dass du dieser Klasse als Typ tatsächlich nur Enums übergibst und nichts anderes. Im Debug-Mode würdest du zwar im Zweifelsfalle eine Runtime-Exception bekommen, aber bei Code-Pfaden, die nicht oft ausgeführt werden, entdeckt man so einen Laufzeitfehler teilweise erst recht spät.

Alternativ müsste auch das hier gehen:
Delphi-Quellcode:
class function TEnumHelper<TEnum>.GetName(Value: TEnum): String;
var
  TypInfo: PTypeInfo;
  V: Integer;
begin
  TypInfo := TypeInfo(TEnum);
  {$IFDEF DEBUG}
  if (TypInfo^.Kind <> tkEnumeration) then
  begin
    raise Exception.Create('Invalid generic type.');
  end;
  {$ENDIF}
  case SizeOf(TEnum) of
    1: V := PByte(@Value)^;
    2: V := PWord(@Value)^;
    4: V := PInteger(@Value)^;
  end;
  Result := GetEnumName(TypeInfo(TEnum), V);
end;
Projekte:
- GitHub (Profil, zyantific)
- zYan Disassembler Engine ( Zydis Online, Zydis GitHub)

Geändert von Zacherl ( 1. Dez 2016 um 13:00 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von uligerhardt
uligerhardt

Registriert seit: 19. Aug 2004
Ort: Hof/Saale
1.734 Beiträge
 
Delphi 2007 Professional
 
#10

AW: Enum in String mehrere Overloaded Funktionen zu einer einzigen zusammenfassen?

  Alt 1. Dez 2016, 15:21
Dumme Frage: Warum nimmst du statt dem:
Delphi-Quellcode:
  {$IFDEF DEBUG}
  if (TypInfo^.Kind <> tkEnumeration) then
  begin
    raise Exception.Create('Invalid generic type.');
  end;
  {$ENDIF}
nicht einfach Assert?
  Assert(TypInfo^.Kind = tkEnumeration, 'Invalid generic type.');
Uli Gerhardt
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 15:25 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz