TDictionary - mit einem Bezeichner unterschiedliche Values einfügen

[Rabenrecht]

Mal wieder so ne Frage, bei der ihr euch wahrscheinlich denkt: "Mensch, kann der überhaupt irgendwas?", but here we go

Ich habe eine HashMap (also TDictionary), die als Values Listen mit Integers (TList<Integer>) enthält.
Gefüllt wird die HashMap über eine Schleife.

Aber ich bekomme es nicht hin, dass die Values der HashMap einzigarte Werte sind. Im Objektinspektor steht da bei allen Einträgen immer die selbe Speicheradresse.

In Java würde ich mir bei sowas halt in jedem Schleifendurchlauf ein neues Listenobjekt erzeugen und dieses dann (entsprechend gefüllt) der HashMap zufügen.
Aber in Delphi kann man ja keine Variablen im Anweisungsblock deklarieren, daher stehe ich diesbezüglich etwas aufm Schlauch...

[DeddyH]

Ich fürchte, ich habe kaum die Hälfte verstanden. Zeig doch mal etwas Code, dann wird das Problem vielleicht klarer.

[Klaus01]

Delphi-Quellcode:

repeat
  objVar := TMyObject.create;  //hier wird die vorherige Instanz überschrieben
  // do something with instance
  Hashmap.addItem(objVar);
until SomeCondition

Grüße
Klaus

[Stevie]

So?

Delphi-Quellcode:

uses
  Generics.Collections;

type
  TMultiMap<TKey,TValue> = class
  private
    fHashMap: TDictionary<TKey,TList<TValue>>;
  public
    constructor Create;
    destructor Destroy; override;

    procedure Add(const key: TKey; const value: TValue);
  end;

constructor TMultiMap<TKey, TValue>.Create;
begin
  inherited Create;
  fHashMap := TObjectDictionary<TKey,TList<TValue>>.Create([doOwnsValues]);
end;

destructor TMultiMap<TKey, TValue>.Destroy;
begin
  fHashMap.Free;
  inherited;
end;

procedure TMultiMap<TKey, TValue>.Add(const key: TKey; const value: TValue);
var
  list: TList<TValue>;
begin
  if not fHashMap.TryGetValue(key, list) then
  begin
    list := TList<TValue>.Create;
    fHashMap.Add(key, list);
  end;
  list.Add(value);
end;

[Rabenrecht]

Zitat von DeddyH:

Ich fürchte, ich habe kaum die Hälfte verstanden. Zeig doch mal etwas Code, dann wird das Problem vielleicht klarer.

Liegt sicherlich auch daran, dass ich ursprünglich ne Frage zu Case-Syntax hatte, diese mir dann aber selbst beantworten konnte, dann aber das noch offene "Neues Thema" Fenster für meine neue Frage genutzt habe - ohne den Titel zu ändern
Und ich zudem in der Hast das Wort "einzigartig" unbedacht verwendet habe - gemeint ist: im Speicher distinkte Objekte

Klaus: das habe ich probiert, ohne Erfolg jedoch.
Wahrscheinlich liegt das daran, dass zwar ein neues Objekt erzeugt wird, durchaus aber mit der gleichen Adresse im Speicher. Und wenn im Dictionary nur Adressen als Values abgelegt sind, zeigen die halt dann immer noch alle auf das gleiche Objekt.

Stevie: danke für die Mühe, vor allem, weil du auch beantwortet hast, wonach ich streng genommen gefragt hab... Ich sollte diese Fragen nicht in einer Minute vor nem Meeting hinklatschen.


Weil die Frage nach Code kam:

Delphi-Quellcode:

var
  vHashMap : TDictionary<Integer,TList<Integer>>;
  vList : TList<Integer>;
  state : Integer;
begin
  vHashMap := TDictionary<Integer,TList<Integer>>.Create;
  vList := TList<Integer>.Create;
  while condition do
    case state of
      0:
      begin
        vList.Add(anInteger);
        state := 1;
      end;
      1:
      begin
        if something do
          vList.Add(anInteger);
        else
        begin
          vHashMap.Add(aKey,vList);
          vList.Clear;
          state := 0;
        end;
      end;
      else
        [...]
    end;
end;

Angenommen, ich möchte die natürlichen Zahlen in Intervalle einteilen, die sich durch die Fibonacci-Zahlen definiert sind: Intervall i := [fib(i-1)+1,fib(i)].
Die HashMap soll dann die einzelnen Intervalle enthalten, der Schlüssel sei i.
(Anmerkung: dies ist nicht der eigentliche Sinn des Codes. Es ist lediglich ein greifbares und passendes Beispiel)

Lassen wir i von 3 bis 6 laufen (3, weil die geforderten Intervalle für i < 3 nicht möglich sind).
Die HashMap sollte nach der Schleife dann folgendermaßen aussehen:
((3,{2}),(4,{3}),(5,{4,5}),(6,{6,7,8}))

So, wie ich es im Code-Ausschnitt implementiert habe, würde es allerdings folgendermaßen aussehen:
((3,{6,7,8}),(4,{6,7,8}),(5,{6,7,8}),(6,{6,7,8}))

Der Grund dafür ist auch klar: das Dictionary-Objekt speichert nicht selbst den Wert eines Eintrages, sondern nur dessen Speicheradresse.
Und die ist für vList natürlich immer gleich.

Die Frage ist also: wie macht man das richtig in Delphi?


In Java würde ich mir in solchen Fällen halt einfach ein neues Objekt von TList erzeugen, wenn ichs brauche, und dieses der HashMap übergeben. Solange noch ne Referenz auf das Listen-Objekt besteht, was ja der Fall ist, wenn es in der Map drin steht, bleibt es auch im Speicher.

[Stevie]

Warum so kompliziert?

Delphi-Quellcode:

var
  map: TMultiMap<Integer,Integer>;
  i, f: Integer;
begin
  map := TMultiMap<Integer,Integer>.Create;
  for i := 3 to 6 do
    for f := fib(i-1)+1 to fib(i) do
      map.Add(i, f);

Gut, das kann man nun noch optimieren, da man weiß, dass fib(i) eh auch fib(i-1) berechnet, aber nunja

[Rabenrecht]

Zitat von Stevie:

Warum so kompliziert?

Delphi-Quellcode:

var
  map: TMultiMap<Integer,Integer>;
  i, f: Integer;
begin
  map := TMultiMap<Integer,Integer>.Create;
  for i := 3 to 6 do
    for f := fib(i-1)+1 to fib(i) do
      map.Add(i, f);

Gut, das kann man nun noch optimieren, da man weiß, dass fib(i) eh auch fib(i-1) berechnet, aber nunja

Weil mein eigentlicher Code nichts mit Fibonacci-Zahlen zu tun hat

[Stevie]

Zitat von Rabenrecht:

Weil mein eigentlicher Code nichts mit Fibonacci-Zahlen zu tun hat

Gut, wie auch immer, nutz ne multimap, dann brauchst auch für neue Keys keine Listen erzeugen und läufst Gefahr in die falsche Liste zu schreiben.
Würde man in Java übrigens auch so machen und die Multimap aus guava oder sonstwoher nutzen, damit man sich den Krams spart.

[Klaus01]

würde es auch so funktionieren?

Delphi-Quellcode:

        begin
          vHashMap.Add(aKey,vList);
          vList.free;
          vList := TList<Integer>.Create;
          state := 0;
        end;

Grüße
Klaus

[Stevie]

Zitat von Klaus01:

würde es auch so funktionieren?

Delphi-Quellcode:

        begin
          vHashMap.Add(aKey,vList);
          vList.free;
          vList := TList<Integer>.Create;
          state := 0;
        end;

Grüße
Klaus

Nein Weil du dann eine Instanz, welche in der hashmap unter aKey steht einfach frei gibst und somit in der hashmap ein dangling pointer steht...