Inherited "überspringen"?

[Uwe Raabe]

Zitat von Ghostwalker:

Delphi-Quellcode:

procedure Unterklasse2.Proc;
begin
  [...]
  Oberklasse.proc;
end;

Das hatte ich auch erst gedacht, aber weder unter Berlin noch XE2 compiliert das überhaupt:

Zitat:

[DCC Fehler]E2076 Diese Form des Methodenaufrufs ist nur für Klassenmethoden erlaubt

Funktioniert das denn bei dir?

[hoika]

Hallo,
ist es möglich beim inherited Stufen in der Hierarchie zu "überspringen"? Oder eine spezifische Implementierung von Proc aufzurufen?

Kurze Antwort: nein
Lange Antwort: es kommt drauf an

In deiner eigenen Klasse kannst du das inherited ja weglassen,
musst dann aber wissen, was in den darüberliegenden Klasse gemacht wird,
dann könntest du aber gleich reintroduce nehmen.
Oder du rufst das inherited auf und korrigierst dann die falschen Daten,
falls das geht.

[bra]

Eventuell so?

Delphi-Quellcode:

procedure Unterklasse2.Proc;
begin
  [...]
  Oberklasse(Self).proc;
end;

[SProske]

Zitat von bra:

Eventuell so?

Delphi-Quellcode:

procedure Unterklasse2.Proc;
begin
  [...]
  Oberklasse(Self).proc;
end;

Das funktioniert nur solange beide Klassen in der selben Unit sind und Proc protected, aber nicht strict protected ist. Für den beschriebenen Anwendungsfall also ungeeignet.

[hoika]

Hallo,

Oberklasse(Self).proc; Wenn aber Oberklasse.Proc dann das fehlerhafte inherited aufruft,
geht wieder alles schief ...

[bra]

Zitat von hoika:

Hallo,

Oberklasse(Self).proc; Wenn aber Oberklasse.Proc dann das fehlerhafte inherited aufruft,
geht wieder alles schief ...

Oberklasse ist im Beispiel aber das auf der ersten Ebene, hat also kein kritisches inherited.

[Uwe Raabe]

Zitat von hoika:

Oberklasse(Self).proc;

Das geht in jedem Fall schief, da du damit auch nur die virtuelle Methode, also wieder Unterklasse2.Proc, aufrufst und so in einen Stack-Overflow läufst.

Die einzige Möglichkeit, die mir dazu einfällt ist schon arg bösartig:

Delphi-Quellcode:

procedure Unterklasse2.Proc;
begin
  asm
    mov eax,self
    call Oberklasse.Proc
  end;
//  inherited;
  Writeln('Unterklasse2');
end;

[jaenicke]

Ich würde das lieber so sauber wie eben möglich ohne Assembler lösen:

Delphi-Quellcode:

uses
  System.Rtti, System.TypInfo;

procedure Unterklasse2.Proc;
begin
  System.Rtti.Invoke(@Oberklasse.Proc, TArray<TValue>.Create(TValue.From<Unterklasse2>(Self)), ccReg, nil);
end;

[Rabenrecht]

Zitat von Uwe Raabe:

Funktioniert das denn bei dir?

Ne...

Mein spezifisches Problem war anders lösbar, weil die Oberklasse.Proc nen Einzeiler mit nem Zugriff auf eine Published Property war (check auf Ereignisbehandlung) und ich das deshalb schmerzfrei nachbauen konnte.

Die Diskussion interessiert mich dennoch. Ähnliche Fälle werden in Zukunft wahrscheinlich nochmal auftreten.

Zitat von Ghostwalker:

Da du aber Unterklasse2 eh nur wegen eines Fehlers in Unterklasse1 baust, warum
leitest du das ganze nicht direkt von Oberklasse ab ? Dann kann Unterklasse1 über die
Klinge springen.

Weil im Unterschied zu meinem aufs Notwendigste reduzierte Beispiel im konkreten Fall Unterklasse1 eine ganze Menge notwendiger Funktionalität enthält

[Zacherl]

Noch eine Dritte Variante ohne Assembly oder RTTI:

Delphi-Quellcode:

{ TA }

procedure TA.X(I: Integer);
begin
  ShowMessage('1: ' + I.ToString);
end;

{ TB }

procedure TB.X(I: Integer);
begin
  inherited;
  ShowMessage('2: ' + I.ToString);
end;

{ TC }

procedure TC.X(I: Integer);
type
  TProc = procedure(Sender: TA; I: Integer);
begin
  //inherited;
  TProc(@TA.X)(Self, I);
  ShowMessage('3: ' + I.ToString);
end;