AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

RTTI und Array of Record

Ein Thema von baumina · begonnen am 4. Apr 2017 · letzter Beitrag vom 6. Apr 2017
Antwort Antwort
Benutzerbild von baumina
baumina

Registriert seit: 5. Mai 2008
Ort: Oberschwaben
1.275 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#1

RTTI und Array of Record

  Alt 4. Apr 2017, 14:41
Folgende Klassen und Records habe ich (Code stark gekürzt):

Delphi-Quellcode:
  TAcField = class
  private
    FFieldName : String;
    FFieldValue : String;
  public
    constructor Create(AFieldName : String);
    property FieldName : String read FFieldName;
    property FieldValue : String read FFieldValue write FFieldValue;
  end;

  TAcArticle = record
    Art_Desc : TAcField;
    Art_Qty : TAcField;
  end;

  TAcArticleArray = Array[1..5] of TAcArticle;

  TAc = class
  private
    FHeader : TAcField;
    FVersion : TAcField;
    FArticles : TAcArticleArray;
    procedure FreeFields;
  end;

procedure TAc.FreeFields;
type
  PAcField = ^TAcField;
  PAcArticleArray = ^TAcArticleArray;

var
  LCtx : TRttiContext;
  LField : TRttiField;
  LArrayField : TRttiField;
  pField : PAcField;
  pArray : PAcArticleArray;
  i : Integer;

begin
  for LField in LCtx.GetType(Self.ClassInfo).GetDeclaredFields do
  begin
    if lfield.getvalue(self).Typeinfo.Name = 'TAcFieldthen
    begin
      pField := PAcField(NativeInt(Self) + lField.Offset);
      TAcField(pField^).Free;
      LField.SetValue(self, nil);
    end;
    if lfield.getvalue(self).Typeinfo.Name = 'TAcArticleArraythen
    begin
      pArray := PAcArticleArray(NativeInt(Self) + lField.Offset);
      for i := Low(TAcArticleArray(pArray^)) to High(TAcArticleArray(pArray^)) do
      begin
// das funktioniert zwar, aber möchte ich auch noch abstrahieren
// TAcArticleArray(pArray^)[i].Art_Desc.Free;
// TAcArticleArray(pArray^)[i].Art_Qty.Free;
// end;
// alle meine Versuche waren bislang ohne Erfolg:
        for LArrayField in LCtx.GetType(????TAcArticleArray(pArray^)[i]????).AsRecord.GetFields do
        begin
          pField := PAcField(NativeInt(LArrayField) + LArrayField.Offset);
          TAcField(pField^).Free;
          LArrayField.SetValue(LArrayField, nil);
        end;
      end;
    end;
  end;
end;
Wie schaffe ich es alle Felder im Array freizugeben?
Hinter dir gehts abwärts und vor dir steil bergauf ! (Wolfgang Ambros)

Geändert von baumina ( 4. Apr 2017 um 14:44 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Zacherl
Zacherl

Registriert seit: 3. Sep 2004
4.626 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#2

AW: RTTI und Array of Record

  Alt 4. Apr 2017, 15:03
Darf man fragen, warum du hierfür RTTI verwendest? Sieht für mich so aus, als ob das Problem ohne RTTI viel einfacher und performanter zu lösen wäre.
Projekte:
- GitHub (Profil, zyantific)
- zYan Disassembler Engine ( Zydis Online, Zydis GitHub)
  Mit Zitat antworten Zitat
Benutzerbild von baumina
baumina

Registriert seit: 5. Mai 2008
Ort: Oberschwaben
1.275 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#3

AW: RTTI und Array of Record

  Alt 4. Apr 2017, 15:12
Wie oben schon geschrieben, habe ich alles stark gekürzt. Tatsächlich handelt es sich um ca. 200 Felder, die nicht nur freigegeben werden müssen, sondern auch validiert uvm. werden müssen. Diese Klasse wird sicherlich im Laufe der Zeit immer wieder neue Felder bekommen, oder vorhandene verändert, so dass ich mir über RTTI sicherlich am wenigsten Fehlerquellen beim Programmieren einhandeln kann.
Hinter dir gehts abwärts und vor dir steil bergauf ! (Wolfgang Ambros)
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
3.585 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#4

AW: RTTI und Array of Record

  Alt 4. Apr 2017, 15:47
Ohne Anspruch auf Vollständigkeit, Fehlerfreiheit oder besondere Performance:

Delphi-Quellcode:
procedure FinalizeInstance(p: Pointer; typeInfo: PTypeInfo);
var
  ctx: TRttiContext;
  f: TRttiField;
  fieldType: TRttiType;
  i: Integer;
  arrayType: TRttiArrayType;
  elementType: TRttiType;
  obj: ^TObject;
begin
  for f in ctx.GetType(typeInfo).GetDeclaredFields do
  begin
    fieldType := f.FieldType;
    case fieldType.TypeKind of
      tkRecord:
      begin
        FinalizeInstance(Pointer(PByte(p) + f.Offset), fieldType.Handle);
        FinalizeRecord(Pointer(PByte(p) + f.Offset), fieldType.Handle);
      end;
      tkArray:
      begin
        arrayType := TRttiArrayType(fieldType);
        elementType := arrayType.ElementType;
        // handle only one dim
        for i := 0 to arrayType.TotalElementCount - 1 do
          FinalizeInstance(Pointer(PByte(p) + f.Offset + (i * elementType.TypeSize)), elementType.Handle);
      end;
      tkClass:
      begin
        obj := Pointer(PByte(p) + f.Offset);
        FreeAndNil(obj^);
      end;
    end;
  end;
end;
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight

Geändert von Stevie ( 4. Apr 2017 um 15:52 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von baumina
baumina

Registriert seit: 5. Mai 2008
Ort: Oberschwaben
1.275 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#5

AW: RTTI und Array of Record

  Alt 6. Apr 2017, 09:50
Klasse, ganz herzlichen Dank!
Hinter dir gehts abwärts und vor dir steil bergauf ! (Wolfgang Ambros)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 00:46 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf