AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

[gelöst] Cursortasten von Buttons fernhalten

Ein Thema von Schwedenbitter · begonnen am 19. Sep 2017 · letzter Beitrag vom 20. Sep 2017
Antwort Antwort
Schwedenbitter

Registriert seit: 22. Mär 2003
Ort: Finsterwalde
622 Beiträge
 
Turbo Delphi für Win32
 
#1

[gelöst] Cursortasten von Buttons fernhalten

  Alt 19. Sep 2017, 16:12
Hallo,

ich nutze dynamisch erzeugte Buttons auf einer TScrollBox. Diese können mit der Maus frei verschoben werden (ähnlich Delphi IDE). Nun möchte ich eine Art Raster dadurch erreichen, dass der Benutzer diese Buttons ebenfalls mittels Tastatur verschieben kann und ich dann die Werte auf Vielfache von 8, 16 oder so runde.
Mit einem Button allein klappt das prima. Mit 2 oder mehr nicht, weil dann mit den Cursortasten der Focus gewechselt und meine Aktion auf eine anderes Control angewendet wird. Im www stand dazu, dass man den Buttons diese Verhalten abgewöhnen kann, indem man Key:= 0; setzt.

Aber ganz so einfach scheint es dann doch nicht zu sein. Denn folgender Code funktioniert eben nur bedingt:
Delphi-Quellcode:
procedure TForm1.FormKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState);
var
   aControl         : TWinControl;
   aButton         : TButton;
begin
   aControl:= ActiveControl;         // aktives Control merken
   if (aControl is TButton) then
   begin
      aButton:= (aControl as TButton);
      case Key of
         VK_LEFT   : aButton.Left:= aButton.Left - 16;
         VK_UP      : aButton.Top:= aButton.Top - 16;
         VK_RIGHT   : aButton.Left:= aButton.Left + 16;
         VK_DOWN   : aButton.Top:= aButton.Top + 16;
      end;
      Key:= 0;                        // <== Tastaturpuffer gelöscht.
      SetFocusedControl(aControl);   // <== Focus nochmal gesetzt
   end;
end;
Ich vermute also, dass VK_LEFT & Co. immer noch irgendwo im Tastaturpuffer rumlungern. Wie löse ich das Problem denn richtig?
Alex Winzer

Geändert von Schwedenbitter (20. Sep 2017 um 07:55 Uhr) Grund: Redeemer hat die Lösung präsentiert.
  Mit Zitat antworten Zitat
nahpets
(Gast)

n/a Beiträge
 
#2

AW: Cursortasten von Buttons fernhalten

  Alt 19. Sep 2017, 16:26
Rate jetzt mal:

Ändert sich das Verhalten, wenn Du statt FormKeyUp FormKeyDown nutzt?
  Mit Zitat antworten Zitat
Redeemer

Registriert seit: 19. Jan 2009
Ort: Kirchlinteln (LK Verden)
760 Beiträge
 
Delphi 2009 Professional
 
#3

AW: Cursortasten von Buttons fernhalten

  Alt 19. Sep 2017, 23:47
Das ist das falsche Event. Dein Code gehört nicht in TForm.OnKeyUp sondern nach TApplicationEvents.OnShortCut (oder von mir aus TApplication.OnShortCut ). Da dann einfach noch nach dem Änderung Handled := True setzen und dann ist an der Stelle Schluss mit der Verarbeitung der Taste.
Eine kleine Umstellung deiner Methode ist allerdings nötig, um deine Taste aus dem TWMKey -Typ zu kriegen:
- Der Parameter Key heißt jetzt Msg.CharCode . Auch hier gehen die virtuellen Key-Codes, die du verwendest.
- Für den TShiftState (wenn du ihn brauchst) gibt es Forms.KeyDataToShiftState(Msg.KeyData) .
Janni
2005 PE, 2009 PA, XE2 PA
  Mit Zitat antworten Zitat
Schwedenbitter

Registriert seit: 22. Mär 2003
Ort: Finsterwalde
622 Beiträge
 
Turbo Delphi für Win32
 
#4

AW: Cursortasten von Buttons fernhalten

  Alt 20. Sep 2017, 07:54
Das ist das falsche Event. Dein Code gehört nicht in TForm.OnKeyUp sondern nach TApplicationEvents.OnShortCut (oder von mir aus TApplication.OnShortCut )...
Danke, das passt genau! Ich habe das jetzt so zusammengebaut:
Delphi-Quellcode:
procedure TForm1.ApplicationEvents1ShortCut(var Msg: TWMKey;
   var Handled: Boolean);
begin
   Handled:= True;
   if (ActiveControl is TButton) then
   begin
      case Msg.CharCode of
         VK_LEFT   : (ActiveControl as TButton).Left:= (ActiveControl as TButton).Left - 16;
         VK_UP      : (ActiveControl as TButton).Top:= (ActiveControl as TButton).Top - 16;
         VK_RIGHT   : (ActiveControl as TButton).Left:= (ActiveControl as TButton).Left + 16;
         VK_DOWN   : (ActiveControl as TButton).Top:= (ActiveControl as TButton).Top + 16;
      else
         Handled:= False;
      end
   end
   else Handled:= False;
end;
Ich habe es so unschön gebaut, weil ich es unübersichtlicher gefunden hätte, 4 Mal nur wegen Handled:= True; ein begin ... end; einzufügen. Es geht vermutlich auch schöner.
Und TApplication.OnShortCut finde ich sogar noch besser, weil ich keine zusätzliche Komponente mit reinbasteln muss. Und schließlich und letztlich habe ich mal im Code von Vcl.AppEvnts geschnüffelt. Beim weiteren Suchen bin ich dann auf die Möglichkeit gestoßen, das ganze auch komplett über die Messages abzufangen mit z.B. procedure CMDialogKey(var Message: TCMDialogKey); message CM_DIALOGKEY; . Nachteil ist allerdings, dass es kein Handled gibt und man aufpassen muss, die nicht ausgewerteten Tasten mit Inherited schön weiterzugeben.
Alex Winzer
  Mit Zitat antworten Zitat
nahpets
(Gast)

n/a Beiträge
 
#5

AW: [gelöst] Cursortasten von Buttons fernhalten

  Alt 20. Sep 2017, 10:13
Noch ein bisserl kürzer:
Delphi-Quellcode:

procedure TForm1.ApplicationEvents1ShortCut(var Msg: TWMKey; var Handled: Boolean);
begin
   if (ActiveControl is TButton) then
   begin
      Handled:= True;
      case Msg.CharCode of
         VK_LEFT : (ActiveControl as TButton).Left := (ActiveControl as TButton).Left - 16;
         VK_UP : (ActiveControl as TButton).Top := (ActiveControl as TButton).Top - 16;
         VK_RIGHT : (ActiveControl as TButton).Left := (ActiveControl as TButton).Left + 16;
         VK_DOWN : (ActiveControl as TButton).Top := (ActiveControl as TButton).Top + 16;
      else
         Handled := False;
      end
   end;
end;
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.242 Beiträge
 
Delphi 10.4 Sydney
 
#6

AW: [gelöst] Cursortasten von Buttons fernhalten

  Alt 20. Sep 2017, 11:01
Oder auch
Delphi-Quellcode:
procedure TForm1.ApplicationEvents1ShortCut(var Msg: TWMKey; var Handled: Boolean);
const
  STEP = 16;
var
  Button: TButton;
begin
  if (ActiveControl is TButton) then
    begin
      Button := TButton(ActiveControl);
      Handled := true;
      case Msg.CharCode of
         VK_LEFT : Button.Left := Button.Left - STEP;
         VK_UP : Button.Top := Button.Top - STEP;
         VK_RIGHT : Button.Left := Button.Left + STEP;
         VK_DOWN : Button.Top := Button.Top + STEP;
      else
         Handled := False;
      end;
    end;
end;
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Schwedenbitter

Registriert seit: 22. Mär 2003
Ort: Finsterwalde
622 Beiträge
 
Turbo Delphi für Win32
 
#7

AW: [gelöst] Cursortasten von Buttons fernhalten

  Alt 20. Sep 2017, 11:11
Noch ein bisserl kürzer:
...
Das stimmt! Ich wusste nicht, dass von Hause aus gilt Handled:= False; . Ich werde gleich mal den Code anpassen. Ich habe es übrigens bei mir auch mit einer Variable besser lesbar gemacht.

Allerdings ist die Lösung doch (noch) nicht perfekt:
Wenn ich jetzt ein weiteres Fenster öffne und dort mit den Cursortasten rumhantiere, dann bewegt sich munter der jeweils auf dem Hauptform befindliche, aktive TButton. Auf dem Kindfenster passiert hingegen nichts mehr Das ist sehr ungünstig. Daher noch ein weiteres Codeschnipsel :
Delphi-Quellcode:
procedure TForm1.ApplicationEvents1ShortCut(var Msg: TWMKey; var Handled: Boolean);
const
  STEP = 16;
var
  Button: TButton;
begin
  if (Screen.ActiveForm = self) and // Ist das gewünschte Fenster aktiv?
     (ActiveControl is TButton) then
    begin
      Button := TButton(ActiveControl);
      Handled := true;
      case Msg.CharCode of
         VK_LEFT : Button.Left := Button.Left - STEP;
         VK_UP : Button.Top := Button.Top - STEP;
         VK_RIGHT : Button.Left := Button.Left + STEP;
         VK_DOWN : Button.Top := Button.Top + STEP;
      else
         Handled := False;
      end;
    end;
end;
Alex Winzer
  Mit Zitat antworten Zitat
nahpets
(Gast)

n/a Beiträge
 
#8

AW: [gelöst] Cursortasten von Buttons fernhalten

  Alt 20. Sep 2017, 11:44
Passen wir es nochmal an (dann können wir auf die implizit gemachte Annahme über den Wert von Handled verzichten):
Delphi-Quellcode:
procedure TForm1.ApplicationEvents1ShortCut(var Msg: TWMKey; var Handled: Boolean);
const
  STEP = 16;
var
  Button: TButton;
begin
  Handled := False;
  if (Screen.ActiveForm = self) and // Ist das gewünschte Fenster aktiv?
     (ActiveControl is TButton) then
    begin
      Button := TButton(ActiveControl);
      Handled := true;
      case Msg.CharCode of
         VK_LEFT : Button.Left := Button.Left - STEP;
         VK_UP : Button.Top := Button.Top - STEP;
         VK_RIGHT : Button.Left := Button.Left + STEP;
         VK_DOWN : Button.Top := Button.Top + STEP;
      else
         Handled := False;
      end;
    end;
end;
  Mit Zitat antworten Zitat
HolgerX

Registriert seit: 10. Apr 2006
Ort: Leverkusen
893 Beiträge
 
Delphi 6 Professional
 
#9

AW: [gelöst] Cursortasten von Buttons fernhalten

  Alt 20. Sep 2017, 12:58
Hmm..

Oder noch einfacher, damit dies nur auf dem einen Formular läuft:

OnShortCut vom Formular verwenden, dann brauchst Du kein ApplicationEvents.
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +2. Es ist jetzt 04:50 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf