AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein Delphi Verschlüsselung: Unterschied von const und var ???

Verschlüsselung: Unterschied von const und var ???

Ein Thema von haentschman · begonnen am 5. Okt 2017 · letzter Beitrag vom 5. Okt 2017
Antwort Antwort
Benutzerbild von haentschman
haentschman

Registriert seit: 24. Okt 2006
Ort: Seifhennersdorf / Sachsen
5.275 Beiträge
 
Delphi 12 Athens
 
#1

Verschlüsselung: Unterschied von const und var ???

  Alt 5. Okt 2017, 07:33
Hallöle...

Ich hätte dann mal ein Problem... Ich habe eine Verschlüsselungsmethode, geborgt aus dem Internet, die gut funktioniert. Diese wollte ich erweitern...nun kommt als Result nichts raus.

Delphi-Quellcode:
// extra Unit
const
  conKey = 'ZdrjE[dyhf';

var
  aCipherMode: TCipherMode = cmCBCx;
  aHashClass: TDECHashClass = THash_SHA256;
  aTextFormat: TDECFormatClass = TFormat_MIME64;
  aKDFIndex: LongWord = 1;
Original:
Delphi-Quellcode:
class function TdTools.Decrypt(aHash: string): string;
var
  Cipher: TCipher_Rijndael;
  aSalt: Binary;
  aData: Binary;
  aCheck: Binary;
  aPass: Binary;
  aLen: Integer;
begin
  Cipher := TCipher_Rijndael.Create;
  try
    aSalt := ValidFormat(aTextFormat).Decode(RawByteString(aHash));
    aLen := Length(aSalt) - 16 - Cipher.Context.BufferSize;
    aData := Copy(aSalt, 17, aLen);
    aCheck := Copy(aSalt, aLen + 17, Cipher.Context.BufferSize);
    SetLength(aSalt, 16);
    aPass := ValidHash(aHashClass).KDFx(conKey[1], Length(conKey) * SizeOf(conKey[1]), aSalt[1], Length(aSalt), Cipher.Context.KeySize, TFormat_Copy, aKDFIndex); // Konstante
    Cipher.Mode := aCipherMode;
    Cipher.Init(aPass);
    SetLength(Result, aLen div SizeOf(aHash[1]));
    Cipher.Decode(aData[1], Result[1], aLen);
    if aCheck <> Cipher.CalcMAC then
      Result := '';
  finally
    Cipher.Free;
    ProtectBinary(aSalt);
    ProtectBinary(aData);
    ProtectBinary(aCheck);
    ProtectBinary(aPass);
  end;
end;
Erweiterungen:
Delphi-Quellcode:
class function TdTools.Encrypt(aText: string; const aKey: string): string;
var
  Cipher: TCipher_Rijndael;
  aSalt: Binary;
  aData: Binary;
  aPass: Binary;
  Key: string;
begin
  if aKey = 'then
  begin
    Key := conKey;
  end
  else
  begin
    Key := aKey;
  end;
  Cipher := TCipher_Rijndael.Create;
  try
    aSalt := RandomBinary(16);
    aPass := ValidHash(aHashClass).KDFx(Key, Length(Key) * SizeOf(Key[1]), aSalt[1], Length(aSalt), Cipher.Context.KeySize, TFormat_Copy, aKDFIndex); // Variable
    Cipher.Mode := aCipherMode;
    Cipher.Init(aPass);
    SetLength(aData, Length(aText) * SizeOf(aText[1]));
    Cipher.Encode(aText[1], aData[1], Length(aData));
    Result := string(ValidFormat(aTextFormat).Encode(aSalt + aData + Cipher.CalcMAC));
  finally
    Cipher.Free;
    ProtectBinary(aSalt);
    ProtectBinary(aData);
    ProtectBinary(aPass);
  end;
end;
Seit gestern ist es zu früh für das Problem... Da kann man eigentlich nichts falsch machen. Ich tippe auf den Unterschied von const und var...aber warum?

Danke für Infos...

Geändert von haentschman ( 5. Okt 2017 um 08:22 Uhr)
  Mit Zitat antworten Zitat
Klaus01

Registriert seit: 30. Nov 2005
Ort: München
5.752 Beiträge
 
Delphi 10.4 Sydney
 
#2

AW: Verschlüsselung: Unterschied von const und var ???

  Alt 5. Okt 2017, 08:34
Guten Morgen,

kann es sein, dass conKey ein ShortString (Ansi) ist und Dein anderer Key ein UniCode String.
Weil mumpitz

Grüße
Klaus
Klaus

Geändert von Klaus01 ( 5. Okt 2017 um 10:32 Uhr)
  Mit Zitat antworten Zitat
Redeemer

Registriert seit: 19. Jan 2009
Ort: Kirchlinteln (LK Verden)
1.010 Beiträge
 
Delphi 2009 Professional
 
#3

AW: Verschlüsselung: Unterschied von const und var ???

  Alt 5. Okt 2017, 10:39
Du rufst ValidHash falsch auf.
aPass := ValidHash(aHashClass).KDFx(Key[1], Length(Key) * SizeOf(Key[1]), aSalt[1], Length(aSalt), Cipher.Context.KeySize, TFormat_Copy, aKDFIndex); // Variable
Janni
2005 PE, 2009 PA, XE2 PA
  Mit Zitat antworten Zitat
Benutzerbild von haentschman
haentschman

Registriert seit: 24. Okt 2006
Ort: Seifhennersdorf / Sachsen
5.275 Beiträge
 
Delphi 12 Athens
 
#4

AW: Verschlüsselung: Unterschied von const und var ???

  Alt 5. Okt 2017, 10:47
Moin...
Dankeschön für deine Anteilnahme.

Ich hatte im Original noch einen Fehler drin.
Original:
Delphi-Quellcode:
// Decode
aPass := ValidHash(aHashClass).KDFx(conKey, Length(conKey) * SizeOf(conKey[1]), aSalt[1], Length(aSalt), Cipher.Context.KeySize, TFormat_Copy, aKDFIndex); // [1] fehlt!
// Encode
aPass := ValidHash(aHashClass).KDFx(conKey[1], Length(conKey) * SizeOf(conKey[1]), aSalt[1], Length(aSalt), Cipher.Context.KeySize, TFormat_Copy, aKDFIndex);
Funktionierend:
Delphi-Quellcode:
// Decode
aPass := ValidHash(HashClass).KDFx(aKey[1], Length(aKey) * 2, Salt[1], Length(Salt), Cipher.Context.KeySize, TFormat_Copy, KDFIndex); // - SizeOf(Key)
// Encode
aPass := ValidHash(HashClass).KDFx(aKey[1], Length(aKey) * 2, Salt[1], Length(Salt), Cipher.Context.KeySize, TFormat_Copy, KDFIndex); // - SizeOf(Key)
Vieleicht hat das den Unterschied gemacht...

Zitat:
Du rufst ValidHash falsch auf.
...meinst du das [1] ?
  Mit Zitat antworten Zitat
Redeemer

Registriert seit: 19. Jan 2009
Ort: Kirchlinteln (LK Verden)
1.010 Beiträge
 
Delphi 2009 Professional
 
#5

AW: Verschlüsselung: Unterschied von const und var ???

  Alt 5. Okt 2017, 11:44
Ja. Methoden, die keinen bestimmten Inhaltstyp erwarten, weil sie den Inhalt über eine unbedingt anzugebene Länge lediglich binär und ohne seine semantische Bedeutung auslesen, brauchen einen Zeiger auf das erste Element das Objekts, also [1] bei Strings und [0] bei allem anderen. Records und Arrays werden dazu packed definiert. Sieht man in der Winapi sehr oft.
Janni
2005 PE, 2009 PA, XE2 PA
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 15:43 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz