AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Json auf Gleichheit prüfen

Ein Thema von Der schöne Günther · begonnen am 10. Nov 2017 · letzter Beitrag vom 10. Nov 2017
Antwort Antwort
Seite 1 von 2  1 2   
Der schöne Günther

Registriert seit: 6. Mär 2013
6.093 Beiträge
 
Delphi 10 Seattle Enterprise
 
#1

Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 11:04
Delphi-Version: 10 Seattle
Kann ich zwei TJsonObject -Instanzen auf Gleichheit prüfen? Ich sehe die Methode TJsonObject.Clone(): TJsonAncestor, aber TObject.Equals(..): Boolean wurde nicht überschrieben.

Muss man sich das selber basteln?
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.016 Beiträge
 
Delphi 12 Athens
 
#2

AW: Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 11:06
Billiger Trick: Beide JSON-Objekte in JSON-Strings umwandeln und Die dann vergleichen.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.093 Beiträge
 
Delphi 10 Seattle Enterprise
 
#3

AW: Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 11:08
Aber das scheitert doch schon an der Reihenfolge:

Delphi-Quellcode:
const
   input1 = '{"someNumber": 42, "someText": "Hallo Welt"}';
   input2 = '{"someText": "Hallo Welt", "someNumber": 42}';
  Mit Zitat antworten Zitat
Benutzerbild von sakura
sakura

Registriert seit: 10. Jun 2002
Ort: München
11.412 Beiträge
 
Delphi 11 Alexandria
 
#4

AW: Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 11:16
Aber das scheitert doch schon an der Reihenfolge:
Und daran scheitert schon ein genereller Vergleich. Ergo, Du musst Dir diesen Vergleich selbst erstellen und Deine Anforderungen umsetzen.

......

P.S.: Logisch sind Deine Beispiele gleich, aber in bestimmten Instanzen mag der gleiche Inhalt mit unterschiedlicher Reihenfolge nicht "gleich genug" sein.
Daniel W.
Ich bin nicht zurück, ich tue nur so
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.093 Beiträge
 
Delphi 10 Seattle Enterprise
 
#5

AW: Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 11:26
Aber Json ist per Definition nicht geordnet. Klar sind die Strings nicht die selben, aber in Json an sich ist die Reihenfolge doch egal:

Zitat:
An object is an unordered collection of zero or more name/value
pairs, where a name is a string and a value is a string, number,
boolean, null, object, or array.

An array is an ordered sequence of zero or more values.
Quelle: RFC 7159 (Hervorhebung durch mich)
  Mit Zitat antworten Zitat
Benutzerbild von sakura
sakura

Registriert seit: 10. Jun 2002
Ort: München
11.412 Beiträge
 
Delphi 11 Alexandria
 
#6

AW: Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 11:38
Aber Json ist per Definition nicht geordnet. Klar sind die Strings nicht die selben, aber in Json an sich ist die Reihenfolge doch egal:
Das ist mir bewusst. Ändert aber nichts daran, das es in den Standard-Bibliotheken keinen Vergleich gibt und Du diesen selbständig machen musst.

......
Daniel W.
Ich bin nicht zurück, ich tue nur so
  Mit Zitat antworten Zitat
SebastianZ

Registriert seit: 23. Jul 2009
89 Beiträge
 
Delphi 11 Alexandria
 
#7

AW: Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 12:01
Das musst du dir selbst basteln.

Mein Ansatz währe hier ein 2-stufiger Vergleich:
1. Die Textlänge des JSON-Strings vergleichen -> unterschiedliche länge, unterschiedliches JSON
2. Die einzelnen Json-Einträge vergleichen. Wie du auf diese Hinkommst ist hier gut ersichtlich:
https://stackoverflow.com/questions/...-in-rad-studio
  Mit Zitat antworten Zitat
Benutzerbild von Zacherl
Zacherl

Registriert seit: 3. Sep 2004
4.629 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#8

AW: Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 15:44
1. Die Textlänge des JSON-Strings vergleichen -> unterschiedliche länge, unterschiedliches JSON
Das mag zwar aus programmiertechnischer Sicht erstmal einfach sein, aber die Performance wird darunter ziemlich leiden, weshalb ich mir diesen Schritt sparen würde.

Der direkte Vergleich aller einzelnen Felder bringt ja auch schon ein eindeutiges Ergebnis. Beachten muss man nur, dass der Vergleich von "beiden Seiten" aus durchgeführt werden muss. Also einmal über die Felder von JSON_1 iterieren und das Vorhandensein + Gleichheit in JSON_2 sicherstellen und danach das selbe Spiel nochmal mit JSON_2 durchführen. Sonst könnte es ja sein, dass JSON_2 zwar die gleichen Felder wie JSON_1 besitzt, aber zusätzlich noch Weitere.
Projekte:
- GitHub (Profil, zyantific)
- zYan Disassembler Engine ( Zydis Online, Zydis GitHub)
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
6.093 Beiträge
 
Delphi 10 Seattle Enterprise
 
#9

AW: Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 15:53
Ja, A und B sind gleich wenn A eine Teilmenge von B und B eine Teilmenge von A ist.

Oder wie der Mathematiker sagen würde:

A=B :⇔ ∀x (x∈A⇔x∈B)


Aber wir müssen hier nicht weiterbohren. Ich bin heute faul. Wenn es etwas fertiges gegeben hätte, dann hätte ich es eingesetzt. Da es nichts gibt, lasse ich die Prüfung ob sie gleich sind halt unter den Tisch fallen...
  Mit Zitat antworten Zitat
Benutzerbild von Zacherl
Zacherl

Registriert seit: 3. Sep 2004
4.629 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#10

AW: Json auf Gleichheit prüfen

  Alt 10. Nov 2017, 16:14
Ich war mal so frei. Vergleicht die trivialen Typen allerdings als Strings, wo ich mir nicht sicher bin, ob z.b. JSON für Floats einen einheitlichen DecimalSeperator spezifiziert. Die umgekehrte Prüfung konnte man sich doch sparen, indem man vorher die Anzahl der Elemente vergleicht.

Delphi-Quellcode:
type
  TJSONType = (
    jsonInvalid,
    jsonInteger,
    jsonFloat,
    jsonString,
    jsonBoolean,
    jsonArray,
    jsonObject,
    jsonNull
  );

  TJSONHelper = record
  public
    class function ValueType(Value: TJSONValue): TJSONType; static;
    class function Equals(A, B: TJSONValue): Boolean; static;
  end;

class function TJSONHelper.ValueType(Value: TJSONValue): TJSONType;
begin
  Result := TJSONType.jsonInvalid;
  if (Value is TJSONNumber) then
  begin
    if (Value.ToString.Contains(GetJSONFormat.DecimalSeparator)) then
    begin
      Result := TJSONType.jsonFloat;
    end else
    begin
      Result := TJSONType.jsonInteger;
    end;
  end else
  if (Value is TJSONString) then
  begin
    Result := TJSONType.jsonString;
  end else
  if (Value is TJSONBool) then
  begin
    Result := TJSONType.jsonBoolean;
  end else
  if (Value is TJSONArray) then
  begin
    Result := TJSONType.jsonArray;
  end else
  if (Value is TJSONObject) then
  begin
    Result := TJSONType.jsonObject;
  end else
  if (Value is TJSONNull) then
  begin
    Result := TJSONType.jsonNull;
  end;
end;

class function TJSONHelper.Equals(A, B: TJSONValue): Boolean;
var
  T: TJSONType;
  I: Integer;
  AA, AB: TJSONArray;
  OA, OB: TJSONObject;
  P: TJSONPair;
  V: TJSONValue;
begin
  Result := true;
  T := ValueType(A);
  if (T <> ValueType(B)) then
  begin
    Exit(false);
  end;
  case T of
    jsonArray:
      begin
        AA := A as TJSONArray;
        AB := B as TJSONArray;
        if (AA.Count <> AB.Count) then
        begin
          Exit(false);
        end;
        for I := 0 to AA.Count - 1 do
        begin
          if (not Equals(AA.Items[I], AB.Items[I])) then
          begin
            Exit(false);
          end;
        end;
        Exit;
      end;
    jsonObject:
      begin
        OA := A as TJSONObject;
        OB := B as TJSONObject;
        if (OA.Count <> OB.Count) then
        begin
          Exit(false);
        end;
        for I := 0 to OA.Count - 1 do
        begin
          P := OA.Pairs[I];
          V := OB.Values[P.JsonString.Value];
          if (not Equals(P.JsonValue, V)) then
          begin
            Exit(false);
          end;
        end;
        Exit;
      end;
  end;
  if (A.Value <> B.Value) then
  begin
    Exit(false);
  end;
end;
Projekte:
- GitHub (Profil, zyantific)
- zYan Disassembler Engine ( Zydis Online, Zydis GitHub)

Geändert von Zacherl (10. Nov 2017 um 16:25 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 18:46 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz