AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Anfängerfrage eigene TLabel-Komponente

Ein Thema von DieDolly · begonnen am 23. Jun 2018 · letzter Beitrag vom 25. Jun 2018
Antwort Antwort
Seite 1 von 2  1 2   
DieDolly

Registriert seit: 22. Jun 2018
906 Beiträge
 
#1

Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 19:46
Ich brauche eure Hilfe noch einmal.
Ich versuche gerade eine eigene Label-Komponente zu erstellen. Die einzigen Unterschiede sollen sein
  1. andere Standardfarbe
  2. eigenes MouseMove- und MouseLeave-Event, was immer ausgeführt werden soll und was eine Farbe und ggf. Styles setzt (ähnlich wie ein Link)

Leider komme ich gerade nicht weiter. Mein Ansatz ist vermutlich mehr als fragwürdig
Delphi-Quellcode:
unit MyLabel;

interface

uses
 Winapi.Windows, Winapi.Messages, System.SysUtils, System.Classes, Vcl.StdCtrls, Vcl.Graphics, Vcl.Controls;

const
 CColorDefault: TColor = clRed;
 CColorHover: TColor = clGreen;

type
 TMyLabel = class(TLabel)
 private
  {Private-Deklarationen}
  FLastLabelColor: TColor;

  FColorHover: TColor;
  FColorActive: TColor;

  FOnMouseMove: TNotifyEvent;
  FOnMouseLeave: TNotifyEvent;

  procedure setLastLabelColor(aLabel: TLabel);
  function getLastLabelColor: TColor;
 protected
  {Protected-Deklarationen}
 public
  {Public-Deklarationen}
  constructor Create(AOwner: TComponent); override;

  procedure CMMouseMove(var Message: TMessage); message CM_MOUSEENTER;
  procedure CMMouseLeave(var Message: TMessage); message CM_MOUSELEAVE;
 published
  {Published-Deklarationen}
  property ColorHover: TColor read FColorHover write FColorHover;
  property ColorActive: TColor read FColorActive write FColorActive;

  property OnMouseMove: TNotifyEvent read FOnMouseMove write FOnMouseMove;
  property OnMouseLeave: TNotifyEvent read FOnMouseLeave write FOnMouseLeave;
 end;

procedure register;

implementation

// Funktionen um die letzte Farbe eines Labels vor dem MouseMove-Event zwischenzuspeichern und wieder auszulesen
procedure TMyLabel.setLastLabelColor(aLabel: TLabel);
begin
 if FLastLabelColor = -1 then
  FLastLabelColor := aLabel.Font.Color;
end;

function TMyLabel.getLastLabelColor: TColor;
begin
 Result := FLastLabelColor;
 FLastLabelColor := -1;
end;

//

constructor TMyLabel.Create(AOwner: TComponent);
begin
 inherited Create(AOwner);

 Color := CColorHover;
 ColorHover := CColorHover;
 ColorActive := CColorHover;
end;

procedure TMyLabel.CMMouseMove(var Message: TMessage);
begin
 inherited;
 if Assigned(FOnMouseMove) then
  begin

  end;
end;

procedure TMyLabel.CMMouseLeave(var Message: TMessage);
begin
 inherited;
 if Assigned(FOnMouseLeave) then
  begin

  end;
end;

procedure register;
begin
 RegisterComponents('My Label', [TMyLabel]);
end;

end.

Geändert von DieDolly (23. Jun 2018 um 20:19 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von scrat1979
scrat1979

Registriert seit: 12. Jan 2007
Ort: Sulzbach a.d. Murr
897 Beiträge
 
Delphi 10.3 Rio
 
#2

AW: Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 20:17
Das sieht doch schon gar nicht schlecht aus.

Solltest du nicht im MouseLeave und MouseMove (wäre hier MouseEnter nicht besser?) jeweils die Labelfarbe auch setzen? Was genau funktioniert denn nicht?
Michael Kübler
  Mit Zitat antworten Zitat
DieDolly

Registriert seit: 22. Jun 2018
906 Beiträge
 
#3

AW: Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 20:19
Ich weiß nicht wie ich auf das Event reagiere. Aktuell habe ich ein Showmessage in beiden Events stehen aber ich bekomme den Dialog nicht angezeigt.
  Mit Zitat antworten Zitat
Benutzerbild von scrat1979
scrat1979

Registriert seit: 12. Jan 2007
Ort: Sulzbach a.d. Murr
897 Beiträge
 
Delphi 10.3 Rio
 
#4

AW: Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 20:20
Delphi-Quellcode:
procedure TMyLabel.CMMouseLeave(var Message: TMessage);
begin
 inherited;

// Hier Labelfarbe setzen

 if Assigned(FOnMouseLeave) then
  FOnMouseLeave;
end;
Michael Kübler
  Mit Zitat antworten Zitat
DieDolly

Registriert seit: 22. Jun 2018
906 Beiträge
 
#5

AW: Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 20:42
Das hat mir geholfen danke.

Das mit dem MouseLeave scheint nicht ganz zu klappen. Die Farbe die das Label vorher hatte wird nicht wieder zugewiesen.

Mein Versuch
Delphi-Quellcode:
function TMyLabel.GetLastLabelColor: TColor;
begin
 Result := FLastLabelColor;
 FLastLabelColor := -1;
end;

procedure TMyLabel.SetLastLabelColor(aLabel: TLabel);
begin
 if FLastLabelColor = -1 then
  FLastLabelColor := aLabel.Font.Color;
end;

constructor TMyLabel.Create(AOwner: TComponent);
begin
 inherited Create(AOwner);

 FLastLabelColor := 1;

 // usw.
end;

procedure TMyLabel.SetLabelMouseProperties(Sender: TLabel; Color: TColor; Cursor: TCursor = crDefault; Styles: TFontStyles = []);
begin
 TLabel(Sender).Font.Color := Color;
 TLabel(Sender).Cursor := Cursor;
 TLabel(Sender).Font.Style := Styles;
end;

procedure TMyLabel.CMMouseEnter(var Message: TMessage);
begin
 inherited;

 SetLastLabelColor(Self); // alte Farbe zwischenspeichern?
 SetLabelMouseProperties(Self, CColorHover, crHandPoint);

 if Assigned(FOnMouseEnter) then
  FOnMouseEnter(Self);
end;

procedure TMyLabel.CMMouseLeave(var Message: TMessage);
begin
 inherited;

 SetLabelMouseProperties(Self, GetLastLabelColor); // alte, zwischengespeicherte Farbe wieder setzen

 if Assigned(FOnMouseLeave) then
  FOnMouseLeave(Self);
end;
Statt der zwischengespeicherten Farbe (clRed) wird aber schwarz zurückgeschrieben.
  Mit Zitat antworten Zitat
Benutzerbild von KodeZwerg
KodeZwerg

Registriert seit: 1. Feb 2018
2.263 Beiträge
 
Delphi 2010 Professional
 
#6

AW: Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 21:00
Frage:
Bei dem hier:
Delphi-Quellcode:
function TMyLabel.GetLastLabelColor: TColor;
begin
 Result := FLastLabelColor;
 FLastLabelColor := -1;
end;
 FLastLabelColor := -1; wieso killst du da den Farbwert?
Gruß vom KodeZwerg
Wenn ein unerwarteter Fehler aufgetreten ist, frage ich mich immer, welche Fehler erwartet wurden...
  Mit Zitat antworten Zitat
DieDolly

Registriert seit: 22. Jun 2018
906 Beiträge
 
#7

AW: Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 21:02
Weil ich ab da den Wert der Zwischenvariable nicht mehr brauche.
Ich habe den Fehler gefunden. Im Constructor fehlte ein Minuszeichen.

Hier ist mein Zwischenresultat
Delphi-Quellcode:
unit MyLabel;

interface

uses
 Winapi.Windows, Winapi.Messages, System.SysUtils, System.Classes, Vcl.StdCtrls, Vcl.Graphics, Vcl.Controls, Dialogs;

const
 CColorDefault: TColor = clRed;
 CColorHover: TColor = clGreen;

type
 TMyLabel = class(TLabel)
 private
  {Private-Deklarationen}
  FLastLabelColor: TColor;
  FStyles: TFontStyles;

  FColorHover: TColor;
  FColorActive: TColor;

  FOnMouseEnter: TNotifyEvent;
  FOnMouseLeave: TNotifyEvent;

  FUnderlinedOnEnter: Boolean;
  FItalicOnEnter: Boolean;

  function GetLastLabelColor: TColor;
  procedure SetLastLabelColor(aLabel: TLabel);
  procedure SetLabelMouseProperties(Sender: TLabel; Color: TColor; Cursor: TCursor = crDefault; Styles: TFontStyles = []);
 protected
  {Protected-Deklarationen}
 public
  {Public-Deklarationen}
  constructor Create(AOwner: TComponent); override;

  procedure CMMouseEnter(var Message: TMessage); message CM_MOUSEENTER;
  procedure CMMouseLeave(var Message: TMessage); message CM_MOUSELEAVE;
 published
  {Published-Deklarationen}
  property ColorHover: TColor read FColorHover write FColorHover;
  property ColorActive: TColor read FColorActive write FColorActive;
  property UnderlinedOnEnter: Boolean read FUnderlinedOnEnter write FUnderlinedOnEnter;

  property ItalicOnEnter: Boolean read FItalicOnEnter write FItalicOnEnter;

  property OnMouseEnter: TNotifyEvent read FOnMouseEnter write FOnMouseEnter;
  property OnMouseLeave: TNotifyEvent read FOnMouseLeave write FOnMouseLeave;
 end;

procedure register;

implementation

// Funktionen um die letzte Farbe eines Labels vor dem MouseMove-Event zwischenzuspeichern und wieder auszulesen
function TMyLabel.GetLastLabelColor: TColor;
begin
 Result := FLastLabelColor;
 FLastLabelColor := -1;
end;

procedure TMyLabel.SetLastLabelColor(aLabel: TLabel);
begin
 if FLastLabelColor = -1 then
  FLastLabelColor := aLabel.Font.Color;
end;

procedure TMyLabel.SetLabelMouseProperties(Sender: TLabel; Color: TColor; Cursor: TCursor = crDefault; Styles: TFontStyles = []);
begin
 TLabel(Sender).Font.Color := Color;
 TLabel(Sender).Cursor := Cursor;
 TLabel(Sender).Font.Style := Styles;
end;

//

constructor TMyLabel.Create(AOwner: TComponent);
begin
 inherited Create(AOwner);

 FLastLabelColor := -1;

 Color := CColorDefault;
 Font.Color := CColorDefault;

 ColorHover := CColorHover;
 ColorActive := CColorHover;
end;

procedure TMyLabel.CMMouseEnter(var Message: TMessage);
begin
 inherited;

 FStyles := [];
 if FUnderlinedOnEnter then
  FStyles := FStyles + [fsUnderline];
 if FItalicOnEnter then
  FStyles := FStyles + [fsItalic];

 SetLastLabelColor(Self);
 SetLabelMouseProperties(Self, CColorHover, crHandPoint, FStyles);

 if Assigned(FOnMouseEnter) then
  FOnMouseEnter(Self);
end;

procedure TMyLabel.CMMouseLeave(var Message: TMessage);
begin
 inherited;

 SetLabelMouseProperties(Self, GetLastLabelColor);

 if Assigned(FOnMouseLeave) then
  FOnMouseLeave(Self);
end;

procedure register;
begin
 RegisterComponents('My Label', [TMyLabel]);
end;

end.

Geändert von DieDolly (23. Jun 2018 um 21:09 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von scrat1979
scrat1979

Registriert seit: 12. Jan 2007
Ort: Sulzbach a.d. Murr
897 Beiträge
 
Delphi 10.3 Rio
 
#8

AW: Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 21:15
Ich verstehe nur nicht ganz, warum du das ganze zwischenspeichern willst. Du hast doch die Hover-Farbe und die „Standardfarbe“. Die Standardfarbe würde ich im Constructor und beim Farbwechsel durch neue manuelle Zuweisung in eine Hilfsvariable speichern. Im MouseEnter bzw. MouseMove/MouseEnter setzt du dann eben entweder die Hover-Farbe oder die aus der Hilfsvariable als Font.Color
Michael Kübler
  Mit Zitat antworten Zitat
DieDolly

Registriert seit: 22. Jun 2018
906 Beiträge
 
#9

AW: Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 21:25
Ich bin für Verbesserungen und Anpassungen deinerseits + Bereitstellung der Änderungen dankbar.
Ich bin mir nicht sicher, ob ich verstehe was du meinst. Deswegen würde ich dich bitte, wenn möglich, die Änderungen einzubauen und zu zeigen.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
34.931 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#10

AW: Anfängerfrage eigene TLabel-Komponente

  Alt 23. Jun 2018, 22:39
Ich bin mir nicht sicher, ob ich verstehe was du meinst. Deswegen würde ich dich bitte, wenn möglich, die Änderungen einzubauen und zu zeigen.
Warum speicherst du LastColor, wo du diesen Wert doch bereits in einer anderen Variable kennt?
PS: Wenn du während des Hover eine neue Farbe zuweist, dann wird nach dem Leave die falsche Farbe angezeigt.

Wozu haben die Set-Methoden einen TLabel-Parameter?
Und warum verwendest du den, anstatt direkt auf Self zuzugreifen?

Bezüglich dem Default-Wert für deine Property solltest du nochmal nachsehen,
denn es macht die DFM übersichtlicher, wenn Default-Werte (das, was im Constructor gesetzt wurde) nicht sinnlos die DFM zumüllen.

Die Color-Property sollten Setter-Methoden bekommen, damit beim Zuweisen auch gleich die Anzeige aktualisiert werden kann.

Und warum eine Magic-Number, anstatt einer ordentlichen Konstante?
Es gibt sogar schon eine Fertige, die man statt der -1 nutzen kann. (Delphi-Referenz durchsuchenclNone / Delphi-Referenz durchsuchenVcl.Graphics.TColor)
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014

Geändert von himitsu (23. Jun 2018 um 22:57 Uhr)
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 06:29 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf