AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Generische string.Split Funktion

Ein Thema von DieDolly · begonnen am 27. Sep 2018 · letzter Beitrag vom 27. Sep 2018
Antwort Antwort
DieDolly

Registriert seit: 22. Jun 2018
2.173 Beiträge
 
#1

Generische string.Split Funktion

  Alt 27. Sep 2018, 13:04
Ich habe eine FUnktion die eine einzige Zeile hat
Result := AString.Split([ADelimiter]); Split liefert aber leider nur Strings zurück.

Wie bekomme ich diese Funktion generisch? Das hier klappt leider an der markierten Stelle nicht
Delphi-Quellcode:
function Explode<T>(const ADelimiter, AString: string): TArray<T>;
var
 LArr: TArray<string>;
 Li: Integer;
begin
 SetLength(Result, 0);
 LArr := AString.Split([ADelimiter]); // erst mal den String splitten und in ein string array speichern

 for Li := 0 to Length(LArr) - 1 do
  begin
   if (TypeInfo(T) = TypeInfo(string)) then
    TArrayHelper.Add<T>(Result, LArr[Li]); ///////// und hier jetzt Result als string array füllen

   // hier unten würde ich dasselbe gerne mit Integer machen
  end;
end;
Add sieht so aus
Delphi-Quellcode:
procedure TArrayHelper.Add<T>;
begin
 SetLength(Values, Length(Values) + 1);
 Values[High(Values)] := Value;
end;
Ich würde gerne eine einzige Explode-Funktion haben die einen String annimt und Strings oder Integer als Array zurückgibt.
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
3.058 Beiträge
 
Delphi 10.4 Sydney
 
#2

AW: Generische string.Split Funktion

  Alt 27. Sep 2018, 13:34
Delphi-Quellcode:
type
  TArrayHelper = record
  public
    class function Explode<T>(const ADelimiter, AString: string): TArray<T>; static;
  end;

class function TArrayHelper.Explode<T>(const ADelimiter, AString: string): TArray<T>;
var
  LArr: TArray<string>;
  LIntArr: TArray<Integer>;
  Li: Integer;
  I: Integer;
begin
  SetLength(Result, 0);
  LArr := AString.Split([ADelimiter]);

  for Li := 0 to Length(LArr) - 1 do
  begin
    if (TypeInfo(T) = TypeInfo(string)) then
    begin
      Result := TArray<T>(LArr);
    end
    else if (TypeInfo(T) = TypeInfo(Integer)) then
    begin
      SetLength(LIntArr, Length(LArr));
      for I := Low(LIntArr) to High(LIntArr) do
      begin
        LIntArr[I] := LArr[I].ToInteger;
      end;
      Result := TArray<T>(LIntArr);
    end;
  end;
end;

procedure Test;
var
  MyString: string;
  MyStringArray: TArray<string>;
  MyIntegerArray: TArray<Integer>;
begin
  MyString := '1,2,3';
  MyStringArray := TArrayHelper.Explode<string>(',', MyString);
  MyIntegerArray := TArrayHelper.Explode<Integer>(',', MyString);
end;
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#3

AW: Generische string.Split Funktion

  Alt 27. Sep 2018, 13:36
Wenn die internen Umwandlungsmechanismen immer funktionieren, könnte das auch so gehen:
Delphi-Quellcode:
  for Li := 0 to Length(LArr) - 1 do begin
    TArrayHelper.Add<T>(Result, TValue.From(Larr[Li]).AsType<T>);
  end;
Eventuell würde ich hier aber eine TList<T> vorziehen:
Delphi-Quellcode:
  list := TList<T>.Create;
  try
    for Li := 0 to Length(LArr) - 1 do begin
      list.Add(TValue.From(Larr[Li]).AsType<T>);
    end;
    Result := list.ToArray;
  finally
    list.Free;
  end;
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
4.007 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#4

AW: Generische string.Split Funktion

  Alt 27. Sep 2018, 13:45
Das funktioniert auf keinen Fall, Uwe. TValue konvertiert string nicht in andere Datentypen sondern nur in Typen, die zuweisungskompatibel sind und das sind String und Integer nicht.

In Spring hab ich diese Funktionalität, um einen durch Komma getrennten string in ein Array jeglichen Typs zu konvertieren, das benutzt aber interne TValue Konvertierungsmechanismen, die auch Teil von Spring sind.

Beispiel:
Delphi-Quellcode:
uses
  Spring;

var
  s: string = '1,2,3,4';
  nums: TArray<Integer>;
begin
  nums := TValue.From(s).ToType<TArray<Integer>>;
Dynamisches Array eines Typs in Dynamisches Array eines anderen Typs geht noch nicht, aber das bringt mich gerade auf eine Idee
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight

Geändert von Stevie (27. Sep 2018 um 14:02 Uhr)
  Mit Zitat antworten Zitat
DieDolly

Registriert seit: 22. Jun 2018
2.173 Beiträge
 
#5

AW: Generische string.Split Funktion

  Alt 27. Sep 2018, 13:53
Danke für die Hilfe. Da war ich doch nicht so weit weg. Trotzdem hatte ich es falsch.

Anhand deiner Umwandlungen habe ich das auch mal mit einer Implode-Funktion versucht. Aber das geht leider in die Hose, da die Umwandlungen hier wohl anders sein sollen.

Meine originale Implode-Funktion
Delphi-Quellcode:
 // for i := 0 to Length(Values) - 1 do
 // begin
 // Res := Res + Values[i];
 //
 // if (i + 1 < Length(Values)) then
 // Res := Res + ADelimiter;
 // end;
oder eben

:= string.Join(',', StringArray); Aber Join gibt es auch nicht für Integer-Arrays.

Mein Ziel: ein Integer-Array als String zurückzuliefern.

Ohne Generics würde ich das sonst so machen
Delphi-Quellcode:
function Implode(const ADelimiter: string; const Values: TArray<string>): string;
var
 i: Integer;
begin
 // Result := string.Join(ADelimiter, Values);
 // oder

 Result := '';

 for i := 0 to Length(Values) - 1 do
  begin
   Result := Result + Values[i];

   if (i + 1 < Length(Values)) then
    Result := Result + ADelimiter;
  end;
end;

function Implode(const ADelimiter: string; const Values: TArray<Integer>): string;
var
 i: Integer;
 StrArray: TArray<string>;
begin
 Result := '';

 for i := 0 to Length(Values) - 1 do
  begin
   SetLength(StrArray, Length(StrArray) + 1);
   StrArray[i] := IntToStr(Values[i]);
  end;

 Result := Implode(ADelimiter, StrArray);
end;

Geändert von DieDolly (27. Sep 2018 um 14:08 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#6

AW: Generische string.Split Funktion

  Alt 27. Sep 2018, 14:07
TValue konvertiert string nicht in andere Datentypen sondern nur in Typen, die zuweisungskompatibel sind und das sind String und Integer nicht.
Stimmt! Ich hatte mich von der Konvertierung bei ToString verleiten lassen.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
4.007 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#7

AW: Generische string.Split Funktion

  Alt 27. Sep 2018, 14:21
Mein Ziel: ein Integer-Array als String zurückzuliefern.
Wenn du eine fest bestimmte Menge an Typen hast, die du behandeln möchtest, würd ich dir von Generics abraten und die entsprechenden Typen per Überladungen implementieren.
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight
  Mit Zitat antworten Zitat
DieDolly

Registriert seit: 22. Jun 2018
2.173 Beiträge
 
#8

AW: Generische string.Split Funktion

  Alt 27. Sep 2018, 14:36
Mein Ziel: ein Integer-Array als String zurückzuliefern.
Wenn du eine fest bestimmte Menge an Typen hast, die du behandeln möchtest, würd ich dir von Generics abraten und die entsprechenden Typen per Überladungen implementieren.
Habe ich bei der Implodefunktion so gemacht. Bei der Explode-Funktion nutze ich aber dann doch Generics, weil sich nur das Resultat der Funktion ändert aber nicht die Parameter.
Unschöne Out-Parameter wären das Resultat.

Geändert von DieDolly (27. Sep 2018 um 14:51 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 11:10 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz