AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Netzwerke Delphi Mit Server auf OnConnect reagieren wie?

Mit Server auf OnConnect reagieren wie?

Ein Thema von holger_barntrup · begonnen am 15. Mai 2019 · letzter Beitrag vom 22. Mai 2019
Antwort Antwort
Seite 1 von 3  1 23   
holger_barntrup

Registriert seit: 1. Feb 2007
Ort: Barntrup
17 Beiträge
 
Delphi XE7 Professional
 
#1

Mit Server auf OnConnect reagieren wie?

  Alt 15. Mai 2019, 11:42
Hallo zusammen
Nach Ewigkeiten mal wieder ein Beitrag.
Ich hatte mir mal ein ein Beispiel für einen Server heruntergeladen und etwas damit herumprobiert.
Was ich nicht hin bekomme ist bei einem Connect eines Clients dem zu antworten.

Hier mal der Code (Ist auch hier aus dem Forum):



Code:
unit UFrmServer;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, StdCtrls, ExtCtrls, IdTcpServer, IdContext,
  IdBaseComponent, IdComponent, IdCustomTCPServer;

type
  TfrmServer = class(TForm)
    pnlConnection: TPanel;
    editPort: TEdit;
    pnlPort: TPanel;
    Panel1: TPanel;
    editIp: TEdit;
    btnStart: TButton;
    ListBox1: TListBox;
    procedure btnStartClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);

  private
    FServer: TIdTCPServer;
    { Private-Deklarationen }
  protected
    procedure OnExecuteEventHandler(AContext: TIdContext);

  public
    { Public-Deklarationen }
  end;

var
  frmServer: TfrmServer;

implementation

{$R *.dfm}

procedure TfrmServer.btnStartClick(Sender: TObject);
begin
  // Ein TCP-Server nimmt Anfragen einer bestimmten Adresse entgegen und
  // beantwortet diese entsprechend einem bestimmten Protokoll

  // Binden der IP Adresse
  self.FServer.Bindings.Items[0].IP := self.editIp.Text;
  // Binden des Ports
  self.FServer.Bindings.Items[0].Port := StrToInt(self.editPort.Text);

  // Die Adresse(n), auf denen der Server Anfragen entgegen nimmt setzen sich
  // aus einer IP und einem Port zusammen. Durch das Binden wurde nun eine
  // solche Adresse zugewiesen, kommen Anfragen, die an diese Adresse gerichtet
  // werden an, so wird der Server sie beantworten

  // Hier wird der Server aktiviert, er wartet nun aktiv auf Anfragen!
  self.FServer.Active := True;

  // Den Start samt Uhrzeit einfach in der Listbox anzeigen, damit man sieht
  // das der Server gestartet wurde (optional!)
  self.ListBox1.Items.Add(FormatDateTime('hh:mm:ss', now) + ' Server Started');
end;

procedure TfrmServer.FormCreate(Sender: TObject);
begin
  // Dynamisches Erzeugen eines Servers (das klappt auch mit der Turbo Delphi
  // Explorer Edition)
  self.FServer := TIdTCPServer.Create(self);
  // Zuweisen des OnExecute Events
  // Dieses wird benötigt, wenn der Server aktiviert wird
  // Es wird endlos immer wieder ausgeführt (darin besteht die gesamte Arbeit
  // des Servers)
  self.FServer.OnExecute := self.OnExecuteEventHandler;
  // Hinzufügen einer neuen Bindung (siehe btnStartClick)
  self.FServer.Bindings.Add;
end;


procedure TfrmServer.OnExecuteEventHandler(AContext: TIdContext);
begin

  // Hier findet die eigentliche Arbeit des Servers statt. In einem neben-
  // läufigen Prozess wird diese Prozedur immer wieder aufgerufen

  // Einfache Idee hier, es wird eine Zeile eingelesen und (mit Uhrzeit in die
  // Listbox geschrieben
  // Das eigentliche Lesen der Zeile geschieht dabei durch
  // AContext.Connection.IoHandler.Readln

  // AContext ist das Argument dieser Methode, der Context, in dem die
  // Methode aufgerufen wurde
  // Die Eigenschaft Connection gibt einem die etablierte Verbindung zurück
  // IoHandler enthält den "Handler" für Input/Output-Ereignisse. Dieser bietet
  // die Methode Readln an. Diese blockiert, bis Daten ankommen, liest hier die
  // Daten als String aus, bis ein Zeilenende auftritt und gibt liefert diesen
  // String
  // Werden keine Daten empfangen, blockiert die Methode (wartet bis etwas
  // ankommt)
  self.ListBox1.Items.Add(FormatDateTime('hh:mm:ss', now) + ' Received Data: ' +
                          AContext.Connection.IOHandler.ReadLn);





  // Wurde ein String empfangen, kann es noch interessant sein, von wem dieser
  // String kam. Im Kontext dieser Verbindung findet sich in der Eigenschaft
  // Binding die angesprochene Adresse des Servers (hier wird nur eine gebunden,
  // aber es sind mehrere möglich) und die Adresse des Anfragestellers
  // PeerIp und PeerPort (Anfragesteller) werden mit in die Listbox übernommen
  self.ListBox1.Items.Add(FormatDateTime('hh:mm:ss', now) +
                          Format('Received from: %s:%d',
                                 [AContext.Binding.PeerIP,
                                  AContext.Binding.PeerPort]));

   if AContext.Connection.IOHandler.ReadLn = 'OFF' then AContext.Connection.IOHandler.WriteLn( 'OFF wurde erfolgreich uebermittelt'+#10+#13);


end;

end.
  Mit Zitat antworten Zitat
mjustin

Registriert seit: 14. Apr 2008
2.682 Beiträge
 
Delphi 2009 Professional
 
#2

AW: Mit Server auf OnConnect reagieren wie?

  Alt 15. Mai 2019, 12:28
Sendet der Client nach dem Aufbau der Verbindung einen definierte Nachricht (wie z.B. "HELLO" oder "LOGIN")?

Oder macht der Client nur die Verbindung auf und der Server soll dann etwas an diese Verbindung senden?


p.s. im Beispielcode wird aus dem Server-Thread auf ein VCL Element (Listbox1) zugegriffen, das ist nicht threadsafe.
Michael Justin
  Mit Zitat antworten Zitat
holger_barntrup

Registriert seit: 1. Feb 2007
Ort: Barntrup
17 Beiträge
 
Delphi XE7 Professional
 
#3

AW: Mit Server auf OnConnect reagieren wie?

  Alt 15. Mai 2019, 12:41

Oder macht der Client nur die Verbindung auf und der Server soll dann etwas an diese Verbindung senden?
Genau so, sobald die Verbindung besteht soll der Server eine Kennung (ASCII) senden.
  Mit Zitat antworten Zitat
holger_barntrup

Registriert seit: 1. Feb 2007
Ort: Barntrup
17 Beiträge
 
Delphi XE7 Professional
 
#4

AW: Mit Server auf OnConnect reagieren wie?

  Alt 15. Mai 2019, 12:42

p.s. im Beispielcode wird aus dem Server-Thread auf ein VCL Element (Listbox1) zugegriffen, das ist nicht threadsafe.
Das ist auch nur für das Beispiel so. Was meinst du genau mit threadsafe?
  Mit Zitat antworten Zitat
holger_barntrup

Registriert seit: 1. Feb 2007
Ort: Barntrup
17 Beiträge
 
Delphi XE7 Professional
 
#5

AW: Mit Server auf OnConnect reagieren wie?

  Alt 16. Mai 2019, 07:17
Das muss doch irgendwie möglich sein bei dynamisch erzeugtem Server auf das OnConnect Ereignis zu reagieren.
  Mit Zitat antworten Zitat
Schokohase

Registriert seit: 17. Apr 2018
725 Beiträge
 
Delphi 10.2 Tokyo Starter
 
#6

AW: Mit Server auf OnConnect reagieren wie?

  Alt 16. Mai 2019, 08:05
Das muss doch irgendwie möglich sein bei dynamisch erzeugtem Server auf das OnConnect Ereignis zu reagieren.
Natürlich, sobald du dem OnConnect-Event einen passenden Event-Handler zuweist, wird das auch passieren.
  Mit Zitat antworten Zitat
mjustin

Registriert seit: 14. Apr 2008
2.682 Beiträge
 
Delphi 2009 Professional
 
#7

AW: Mit Server auf OnConnect reagieren wie?

  Alt 16. Mai 2019, 14:31
Beispielcode (mit Konsolenausgabe anstatt Listbox).

Hinweise:
  • das Erzeugen eines neuen Bindings ist nicht notwendig, standardmäßig wird beim Starten eines Indy TCP Servers bereits ein Binding erzeugt, mit IP 0.0.0.0. Im Code wird dann nur noch der Port gesetzt (über die DefaultPort-Property)
  • als Port verwendet das Beispiel den Telnet-Port, daher kann man mit 'telnet localhost' auf der Kommandozeile die Verbindung testen
  • der Server meldet sich nach dem Verbindungsaufbau mit der Ausgabe 'Welcome to Indy TCP Server example' und trennt nach einer Sekunde die Verbindung wieder

Delphi-Quellcode:
unit Unit1;

interface

uses
  IdTCPServer, IdContext,
  Classes, SysUtils, Forms, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    FServer: TIdTCPServer;

    procedure Log(const Msg: string);

    procedure OnConnect(AContext: TIdContext);
    procedure OnExecute(AContext: TIdContext);
  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
begin
  FServer.Active := True;

  Log('Server is listening');
  Log('Bindings[0].IP=' + FServer.Bindings[0].IP);
  Log('Bindings[0].Port=' + IntToStr(FServer.Bindings[0].Port));
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FServer := TIdTCPServer.Create(Self);

  FServer.OnExecute := OnExecute;
  FServer.OnConnect := OnConnect;

  FServer.DefaultPort := 23; // Telnet Port
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FServer.Active := False;
end;

procedure TForm1.Log(const Msg: string);
begin
  WriteLn(Msg); // Ausgabe setzt Linken als "Konsolenanwendung" voraus
end;

procedure TForm1.OnConnect(AContext: TIdContext);
begin
  Log('CONNECT');
  Log(AContext.Binding.PeerIP);

  AContext.Connection.IOHandler.WriteLn('Welcome to Indy TCP Server example');

  Log('Welcome message sent');
end;

procedure TForm1.OnExecute(AContext: TIdContext);
begin
  Sleep(1000);

  AContext.Connection.IOHandler.WriteLn('Bye');

  AContext.Connection.Disconnect;
end;

end.
Michael Justin
  Mit Zitat antworten Zitat
holger_barntrup

Registriert seit: 1. Feb 2007
Ort: Barntrup
17 Beiträge
 
Delphi XE7 Professional
 
#8

AW: Mit Server auf OnConnect reagieren wie?

  Alt 17. Mai 2019, 05:50
Hallo Michael
Vielen Dank für dein Beispiel. Ich glaub das bringt mich schon mal ein wenig weiter.

Das hier verstehe ich nur gar nicht:
  WriteLn(Msg); // Ausgabe setzt Linken als "Konsolenanwendung" voraus
Wie linkt man als "Konsolenanwendung"
  Mit Zitat antworten Zitat
holger_barntrup

Registriert seit: 1. Feb 2007
Ort: Barntrup
17 Beiträge
 
Delphi XE7 Professional
 
#9

AW: Mit Server auf OnConnect reagieren wie?

  Alt 17. Mai 2019, 10:38
Wie linkt man als "Konsolenanwendung"
Selber herausgefunden.

Der Server startet scheinbar nicht und eine Ausgabe in der Konsole hab ich auch nicht. Lässt sich jedenfalls nicht connecten.




Den einzigen Unterschiede zwischen dem von dir geposteten Quelltext und dem Meinigen ist:
Delphi-Quellcode:
{$R *.lfm}
{$R *.dfm


Geändert von holger_barntrup (17. Mai 2019 um 11:04 Uhr)
  Mit Zitat antworten Zitat
diesisteintester

Registriert seit: 8. Okt 2009
Ort: Karlsruhe
1 Beiträge
 
Delphi 10.1 Berlin Professional
 
#10

AW: Mit Server auf OnConnect reagieren wie?

  Alt 17. Mai 2019, 11:16
{$R *.lfm} kommt von der Lazerus IDE, {$R *.dfm} von Delphi ... macht soweit ja mal keinen Unterschied.

Hab den Code auch mal getestet und der geht ...

wenn du sagst der "Server startet nicht", was passiert denn im Debugger?

Exception oder EA Violation ???
Tom
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 3  1 23   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 04:03 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf