Transparente Clicks

[shebang]

Ich habe ein TImage auf dem ein TLabel liegt.

Gibt es eine Einstellung um den Click auf das Label zu ignorieren, so dass immer das OnClick des darunter liegenden Images ausgelöst wird?

[Klaus01]

ist mir jetzt nicht bekannt,
Du könntest aber im onClick des Tlabels das onClick des TImage aufrufen.

Grüße
Klaus

[Moombas]

Ich würde es exakt so machen wie Klaus es schrieb.
Dem Label im Onclick das Onclick des TImage eintragen und der Effekt ist 1:1 das Gleiche, so lange du darin nicht die angeklickte Komponente abfragst/benötigst.

Ansonsten müsstest du im Onclick des Labels folgendes eintragen wenn ich mich nicht irre:

ImageClick(Imagename); also z.B.
Image1Click(Image1);

[shebang]

Das hab ich befürchtet.
Das Problem ist, dass es ca. 2 Dutzend dieser Kombinationen gibt und ich wissen muss, welches Image angeklickt wurde.
Schöner Code wird das dann nicht.

[Neutral General]

Also letztens hatte ich eine ähnliche Situation und da hat es geholfen im WndProc der Komponente für die WM_NCHITTEST Message HTTRANSPARENT zurückzugeben.

Ich hab das allerdings grad für ein Label getestet und da kommt scheinbar diese Message überhaupt nicht an.

Wenn du alle Labels in TStaticText änderst/ändern kannst funktioniert es aber:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls, Vcl.StdCtrls;

type
  TStaticText = class(Vcl.StdCtrls.TStaticText)
  protected
    procedure WndProc(var Message: TMessage); override;
  end;

  TForm1 = class(TForm)
    StaticText1: TStaticText;
    Image1: TImage;
    procedure StaticText1Click(Sender: TObject);
    procedure Image1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Image1Click(Sender: TObject);
begin
  ShowMessage('Image');
end;

procedure TForm1.StaticText1Click(Sender: TObject);
begin
  ShowMessage('Label'); // Wird so nie aufgerufen, stattdessen wird der Klick an das Image weitergeleitet
end;

{ TStaticText }

procedure TStaticText.WndProc(var Message: TMessage);
begin
  if Message.Msg = WM_NCHITTEST then
    Message.Result := HTTRANSPARENT
  else
    inherited;
end;

end.

[Moombas]

@shebang: Gibt es für diese Kombination keine Logik mit der du es ansonsten herleiten könntest? Also mit FindComponent etc.

Hat jedes Image eine eigene OnClick Prozedur oder alle die Gleiche?

[Uwe Raabe]

Folgender Code im OnClick-Event der Labels sollte gehen. Dabei wird angenommen, daß die Labels und die darunter liegenden Images denselben Parent haben.

Delphi-Quellcode:

type
  TImageHack = class(TImage);

procedure TForm487.Label1Click(Sender: TObject);
var
  ctrl: TControl;
  lbl: TLabel;
begin
  lbl := Sender as TLabel;
  lbl.Enabled := False; // damit es bei ControlAtPos nicht gefunden wird
  try
    ctrl := lbl.Parent.ControlAtPos(lbl.ClientRect.CenterPoint, False, False, False);
    if ctrl is TImage then
      TImageHack(ctrl).Click;
  finally
    lbl.Enabled := True;
  end;
end;

[shebang]

Danke für die Antworten.

Die Images benutzen alle das gleiche OnClick, insofern sollte die Variante meines Vorposters funktionieren. Ich teste das sofort.

Edit:
Klappt einwandfrei, nur das ClientRect.CenterPoint hab ich durch BoundsRect.CenterPoint ersetzt, damit wir im richtigen Referenzsystem arbeiten.