AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Zur Laufzeit Comboboxen hinzufügen

Ein Thema von KomischerKautz · begonnen am 14. Feb 2020 · letzter Beitrag vom 21. Feb 2020
Antwort Antwort
Seite 4 von 4   « Erste     234
jus

Registriert seit: 22. Jan 2005
310 Beiträge
 
Delphi 2007 Professional
 
#31

AW: Zur Laufzeit Comboboxen hinzufügen

  Alt 18. Feb 2020, 11:58
Eine TComponentList könnte man auch verwenden.
Wird eine Komponente (TComponent) freigegeben, dann wird sie autoamtisch aus der Liste entfernt.

TComponent haben ein Notify-System, um sich gegenseitig über ihre Freigabe zu informieren, z.B. Property auf nil zu setzen oder sich aus den Listen der Components und Controls ihrer Parents zu entfernen.
.....
Wie könnte so ein Notify-System aussehen? Ich bin schon paar paar Mal in fremde Sourcen darüber gestolpert, aber so richtig kapiert habe das nicht. Ich wäre sehr interesiert wie man das mit einer Liste mit Notify realisiert
  Mit Zitat antworten Zitat
Dennis07

Registriert seit: 19. Sep 2011
Ort: Deutschland
407 Beiträge
 
Delphi 10.3 Rio
 
#32

AW: Zur Laufzeit Comboboxen hinzufügen

  Alt 18. Feb 2020, 12:02
Jede Komponente hat FreeNotifications, die sie u.a. an diejenigen Komponenten versendet, die sie als Besitzer festgelegt haben.
Wenn eine Komponente zerstört wird, werden deren Subkomponenten, die in einer (eigentlich zwei) Komponentenlisten gespeichert sind, automatisch freigegeben. Nicht zu verwechseln ist dies mit den eingebetteten Steuerelementen, die in TList<TControl> gespeichert werden; diese haben nichts damit zu tun.
Dennis
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
35.267 Beiträge
 
Delphi 10.3 Rio
 
#33

AW: Zur Laufzeit Comboboxen hinzufügen

  Alt 18. Feb 2020, 12:34
siehe TComponentList (unit Contnrs)

Eine TList, die ein Dummy-TComponent drinnen hat oder die selbst ein TComponent ist, über dessen TComponent.Notification beim opRemove es das jeweilige Objekt aus der Liste löscht.
TList.Notify bei lnAdded via TComponent.FreeNotification registrieren und beim lnExtracted/lnDeleted via TComponent.RemoveFreeNotification deregistrieren. (wer bei wem ist egal, da alles gegenseitig)

Delphi-Quellcode:
procedure TComponentListDummy.Notification(AComponent: TComponent; Operation: TOperation);
begin
  if Operation = opRemove then
    Parent.Extract(AComponent); // Item aus Liste entfernen, ohne enthaltenes Objekt (nochmal) freizugeben
  inherited;
end;

procedure TComponentList.Notify(Ptr: Pointer; Action: TListNotification);
begin
  if Assinged(Ptr) then
    case Action of
      lnAdded:
        TComponent(Ptr).FreeNotification(FDummy);
      lnExtracted, lnDeleted:
        TComponent(Ptr).RemoveFreeNotification(FDummy);
    end;
  inherited;
end;
Nochmal als Beispiel mit einem Property:
Delphi-Quellcode:
type
  TDemo = class(TComponent)
  private
    FLink: TComponent;
    procedure SetLink(Value: TComponent);
  protected
    procedure Notification(AComponent: TComponent; Operation: TOperation); override;
  public
    property Link: TComponent read FLink write SetLink;
  end;

procedure TDemo.SetLink(Value: TComponent);
begin
  if Assigned(FLink) then
    Self.RemoveFreeNotification(FLink); // oder FLink.RemoveFreeNotification(Self);
  FLink := Value;
  if Assigned(FLink) then
    Self.FreeNotification(FLink);
end;

procedure TDemo.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited;
  if Operation = opRemove then begin
    if FLink = AComponent then
      FLink := nil;
  end;
end;
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
jus

Registriert seit: 22. Jan 2005
310 Beiträge
 
Delphi 2007 Professional
 
#34

AW: Zur Laufzeit Comboboxen hinzufügen

  Alt 20. Feb 2020, 19:28
siehe TComponentList (unit Contnrs)
...
Delphi-Quellcode:
procedure TComponentListDummy.Notification(AComponent: TComponent; Operation: TOperation);
begin
  if Operation = opRemove then
    Parent.Extract(AComponent); // Item aus Liste entfernen, ohne enthaltenes Objekt (nochmal) freizugeben
  inherited;
end;

procedure TComponentList.Notify(Ptr: Pointer; Action: TListNotification);
begin
  if Assinged(Ptr) then
    case Action of
      lnAdded:
        TComponent(Ptr).FreeNotification(FDummy);
      lnExtracted, lnDeleted:
        TComponent(Ptr).RemoveFreeNotification(FDummy);
    end;
  inherited;
end;
....
@himitsu: vielen Dank für die Erklärung! Hat bei mir eine Weile gedauert, bis ich verstanden habe, dass dein Code nur zur Erklärung dient und bereits implizit im TComponentList enthalten ist. Sprich, man muß sich normalerweise bei TComponentList nicht mehr um das Entfernen aus der TComponentList kümmern, wenn eine Komponente freigegeben wird.

Vielleicht auch für den TE oder andere interessant, aufbauend auf den Beitrag #8 von KodeZwerg ein Beispiel mit TComponentList:
Delphi-Quellcode:
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Contnrs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private-Deklarationen }
    ComponentList: TComponentList;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  cb: TComboBox;
begin
  cb := TComboBox.Create(self);
  cb.Parent := self;
  cb.Top := (ComponentList.Count * (cb.Height + 3));
  // weitere eigenschaften setzen
  cb.Items.Add(DateTimeToStr(now)); // mit irgendein Text blabla Text füllen
  cb.ItemIndex := 0;
  ComponentList.Add(cb);
  Caption := 'ComponentList: ' + IntToStr(ComponentList.Count);
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  cb: TComboBox;
begin
  if ComponentList.Count > 0 then
  begin
    cb := TComboBox(ComponentList[ComponentList.Count-1]);
    cb.Free;
    Caption := 'ComponentList: ' + IntToStr(ComponentList.Count);
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ComponentList := TComponentList.Create;
  Caption := 'ComponentList: ' + IntToStr(ComponentList.Count);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  ComponentList.Free;
end;

end.
Angehängte Dateien
Dateityp: zip TComponentListDemo.zip (4,0 KB, 3x aufgerufen)
  Mit Zitat antworten Zitat
Benutzerbild von KodeZwerg
KodeZwerg

Registriert seit: 1. Feb 2018
2.344 Beiträge
 
Delphi 2010 Professional
 
#35

AW: Zur Laufzeit Comboboxen hinzufügen

  Alt 21. Feb 2020, 08:24
Danke an himitsu und jus für den Component-Notify tipp/Beispiel-Code, ich werde übers Wochenende mal 'ne kleine DynamicControls unit erschaffen
Gruß vom KodeZwerg
Wenn ein unerwarteter Fehler aufgetreten ist, frage ich mich immer, welche Fehler erwartet wurden...
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 10:22 Uhr.
Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf