Ressourcen-Datei - Zip hineinpacken und extrahieren per Code

[Guido Eisenbeis]

Für alle, die gerne über Eigenbemühungen lesen wollen: Meine Eigenbemühungen waren sehr umfangreich, ich habe zig Beiträge dazu durchgelesen und ausprobiert. Leider ohne Erfolg.

Ziel ist es, eine Zip-Datei per Code in eine Ressourcen-Datei zu packen. Diese soll im eigenen Programm eingebunden und daraus ausgepackt werden können.

Mein derzeitiger Stand:

Ich benutze den Resource Editor von Anders Melander. Dort ziehe ich die Test.zip hinein, klicke auf "Save as" und speichere als MyTest.res.

Danach binde ich die MyTest.res in meinem Programm ein, wie in unzähligen INet-Tipps beschrieben.

Delphi-Quellcode:

implementation

{$R *.dfm}
{$R MyTest.res} // Setup-Dateien als Resource einbinden.

In meinem Programm benutze die ebenfalls in unzähligen INet-Tipps beschriebenen Befehle

Delphi-Quellcode:

function ExtractRes(ResType, ResName, ResNewName: string): Boolean;
var
  Res: TResourceStream;
begin
  Res := TResourceStream.Create(Hinstance, Resname, PChar(ResType));
  try
    Res.SavetoFile(ResNewName);
  finally
    Res.Free;
  end;
  Result := True;
end;

// Extrahieren der Zip-Datei aus der Ressourcen-Datei.
if ExtractRes('RCDATA', UpperCase(sResName), sPathOfZipFileFromRes) then
begin
  // Code zum Extrahieren der Daten aus der Zip-Datei.
  ...

Funktioniert soweit wunderbar.

Was ich nun suche, ist eine Möglichkeit, die res-Datei per Code zu erstellen, anstatt per Resource Editor. Dazu habe ich etliche Variationen der im Umlauf befindlichen Lösung ausprobiert, die grundsätzlich so aussieht:

Code:

"MyTest.rc" erstellen. Darin steht: TEST RCDATA Test.zip
"MyTest.rc" zu "MyTest.res" kompilieren: brc32 -r MyTest.rc

Das Ganze habe ich rauf und runter variiert, mit und ohne -r, BRC32 oder BRCC32, Großschreibung, Kleinschreibung, mit und ohne kompletten Pfaden, und vieles mehr. Die so erstellte "MyTest.res" habe ich in mein Programm eingebunden wie oben beschrieben. Leider wirft mein Programm beim Extrahieren der zip-Datei aus dieser res-Datei jedesmal die Fehlermeldung: "Ressource TEST nicht gefunden."

Meine Untersuchungen habe gezeigt, dass sich die res-Datei des Resource Editors von der per Code erstellten res-Datei unterscheidet wie in folgenden Screenshots zu sehen.

Wie lautet der richtige Code, um eine funktionierende res-Datei erstellen?

[DieDolly]

1) erstelle eine Datei, Name egal: create_resource.bat

2) in diese Datei schreibst du rein

Code:

SET var=%cd%

brcc32.exe "%var%\meinprogramm.resourcedatei.rc" -fomeinprogramm.resourcedatei.res

3) in die meinprogramm.resourcedatei.rc-Datei schreibst du

Code:

MYTEST RCDATA ".\MyTest.zip"

Alles abspeichern, Doppelklick auf die Bat-Datei und schon wird deine RES-Datei erstellt.
Die Bat-Datei kannst du auch aus einem Delphiprogramm aufrufen.

[haentschman]

Moin...
Das geht auch ohne BAT. Delphi erzeugt die RES automatisch. Man braucht nur eine RC.

Delphi-Quellcode:

// in DPR z.B.
{$R 'MyTest.res' 'Pfad im Projectordner\MyTest.rc'}

MyTest.rc:

Code:

MyTest TEST "E:\\Projects\\Blubb\MyTest.zip"

...nur das Projekt neu erzeugen...fertsch.

Beispiel:

Zitat:

COM_DELETE_USERS FIREBIRD_25 "E:\xxxx\SQL\SQL_Common\Firebird\25\COM_DELETE_USE RS.sql"

[Uwe Raabe]

Man kann auch die Zip-Datei über den Menüpunkt Projekt - Ressourcen und Bilder... dem Projekt mitgeben. Dabei wird zwar keine eigene RES-Datei für die ZIP-Datei erstellt, diese wird aber in die projekteigene *.dres aufgenommen, die dann in das Projekt gelinkt wird. Ein entsprechende Eintrag in der DPR sollte automatisch erzeugt werden.

[Guido Eisenbeis]

@DieDolly

Ich habe mich genau an deine Anweisungen gehalten, und wie erwartet tritt der Fehler auf. Im Anhang habe ich ein Testprojekt erstellt, zum leichteren Nachvollziehen.

[DieDolly]

Zitat:

Ich habe mich genau an deine Anweisungen gehalten, und wie erwartet tritt der Fehler auf.

Welcher Fehler? Bei mir lässt sich alles kompilieren und die Resource-Datei mit dem Archiv drin ist in der Exe am Ende.

[Guido Eisenbeis]

@haentschman

Sind die doppelten Backslashs richtig? Dein Beispiel verstehe ich leider nicht.

[Guido Eisenbeis]

Zitat von Uwe Raabe:

Man kann auch die Zip-Datei über den Menüpunkt Projekt - Ressourcen und Bilder... dem Projekt mitgeben. Dabei wird zwar keine eigene RES-Datei für die ZIP-Datei erstellt, diese wird aber in die projekteigene *.dres aufgenommen, die dann in das Projekt gelinkt wird. Ein entsprechende Eintrag in der DPR sollte automatisch erzeugt werden.

Leider auch hier der gleiche Fehler beim Extrahieren der zip-Datei aus der Ressource. Vielleicht hängt es an den Befehlen zum Extrahieren? Im Anhang ist mein Testprojekt. Kannst du das bitte so ergänzen, dass es funktioniert?

[Uwe Raabe]

Delphi-Quellcode:

{ Der ResType sollte immer ein PChar sein, damit man die vordefinierten Konstanten verwenden kann (RT_BITMAP, RT_STRING, RT_RCDATA, ...)
  Dabei handelt es sich nicht wirklich um Strings, sondern um als Pointer (auf Strings) getarnte numerische Konstanten im niedrigen Wertebereich.
  RT_RCDATA ist demnach als PChar(10) definiert - an Adresse 10 kann aber kein brauchbarer String im Speicher liegen und das weiß Windows.
  Deswegen kann man diese Konstanten auch nicht in einen String packen und dann später wieder auf PChar casten.
}
function ExtractRes(ResType: PChar; const ResName, ResNewName: string): Boolean; 
var
  Res: TResourceStream;
begin
  Res := TResourceStream.Create(hInstance, Resname, ResType);
  try
    Res.SavetoFile(ResNewName);
  finally
    Res.Free;
  end;
  Result := True;
end;



procedure TForm1.Button1Click(Sender: TObject);
var
  sResName: string;
  sPathOfZipFileFromRes: string;
begin
  sResName := 'MYTEST';
  sPathOfZipFileFromRes := ExtractFilePath(ParamStr(0)) + 'MyTest.zip';  // ExtractFilePath enthält bereits den Backslash

  // Extrahieren der Zip-Datei aus der Ressourcen-Datei.
  if ExtractRes(RT_RCDATA, UpperCase(sResName), sPathOfZipFileFromRes) then // RT_RCDATA ist die vordefinierte Konstante für RCDATA Resourcen
  begin
    // Code zum Extrahieren der Daten aus der Zip-Datei.
    // ...
  end;
end;