AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Unterschiede in 2 Bitmaps ermitteln

Ein Thema von BlueStarHH · begonnen am 22. Apr 2020 · letzter Beitrag vom 24. Apr 2020
Antwort Antwort
BlueStarHH

Registriert seit: 28. Mär 2005
Ort: Hannover-Hainholz
648 Beiträge
 
Delphi 10.3 Rio
 
#1

Unterschiede in 2 Bitmaps ermitteln

  Alt 22. Apr 2020, 16:13
Hi,

ich habe 2 Bitmaps. Diese haben beide immer die selbe Höhe/Breite. In einem der Bitmaps gibt es einen Bereich der immer rechteckig ist und immer mindestens 100 Pixel breit ist. Dieser Bereich unterscheidet sich vom anderen Bild. Wie kann diesen Bereich (als TRect) möglichst schnell finden? Es können sehr große Bilder sein und es muss innerhalb von weniger als einer Sekunde ermittelt werden können. Danke!
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
38.968 Beiträge
 
Delphi 10.4 Sydney
 
#2

AW: Unterschiede in 2 Bitmaps ermitteln

  Alt 22. Apr 2020, 16:18
Zitat:
mindestens 100 Pixel breit
Und wie hoch mindestens?

Nja, das sagt ja schonmal, dass du in dieser Richtung erstmal nur alle 100 Pixel nachgucken brauchst,
wenn gefunden, dann nochmal in kleinerens Schritten den Anfang/Ende suchen.

TBitmap.ScanLine bieted einen direkten Zugriff auf die Rohdaten einzelner Zeilen, was wesentlich schneller ist, als über TBitmap.Pixels zu gehen.
Aber aufpassen, da Jenes natürlich abhängig vom PixelFormat ist.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
BlueStarHH

Registriert seit: 28. Mär 2005
Ort: Hannover-Hainholz
648 Beiträge
 
Delphi 10.3 Rio
 
#3

AW: Unterschiede in 2 Bitmaps ermitteln

  Alt 24. Apr 2020, 11:18
Zitat:
mindestens 100 Pixel breit
Und wie hoch mindestens?
1 Pixel. Ich werden dann einfach die Bilder in 100 Pixel-Abschnitten vergleichen. Dachte, dass es da evtl. eine schnellere Lösung gibt.
  Mit Zitat antworten Zitat
freimatz

Registriert seit: 20. Mai 2010
1.057 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#4

AW: Unterschiede in 2 Bitmaps ermitteln

  Alt 24. Apr 2020, 11:57
Sicher gibt es diese, es wird halt viel aufwendiger. Man könnte sich sich auf den Spezialfall stützen. Du schreibst nur von "Bitmaps". Das ist sehr allgemein. Sind es Bilder in TBitmap? Kannst Du früher auf die Rohdaten los bevor diese in ein TBitmap geladen werden?
  Mit Zitat antworten Zitat
Benutzerbild von MyRealName
MyRealName

Registriert seit: 19. Okt 2003
Ort: Heilbronn
543 Beiträge
 
Delphi 10.4 Sydney
 
#5

AW: Unterschiede in 2 Bitmaps ermitteln

  Alt 24. Apr 2020, 15:11
Nja, das sagt ja schonmal, dass du in dieser Richtung erstmal nur alle 100 Pixel nachgucken brauchst,
wenn gefunden, dann nochmal in kleinerens Schritten den Anfang/Ende suchen.
Halte ich für gewagt, da durchaus an diesem Pixel schon die gleiche Farbe stehen kann. Ausserdem sind das eh Speicheroperation, das geht recht schnell. Da kann man großzügiger sein
  Mit Zitat antworten Zitat
BlueStarHH

Registriert seit: 28. Mär 2005
Ort: Hannover-Hainholz
648 Beiträge
 
Delphi 10.3 Rio
 
#6

AW: Unterschiede in 2 Bitmaps ermitteln

  Alt 24. Apr 2020, 15:23
Nja, das sagt ja schonmal, dass du in dieser Richtung erstmal nur alle 100 Pixel nachgucken brauchst,
wenn gefunden, dann nochmal in kleinerens Schritten den Anfang/Ende suchen.
Halte ich für gewagt, da durchaus an diesem Pixel schon die gleiche Farbe stehen kann. Ausserdem sind das eh Speicheroperation, das geht recht schnell. Da kann man großzügiger sein
Stimmt, da hast Du recht. Wenn den 100 Pixel müssten ja nicht alle zwingend unterschiedlich sein. Kann ja sein, dass einer in der Mitte zufällig genau die selbe Farbe in beiden Bildern hat.
  Mit Zitat antworten Zitat
Amateurprofi

Registriert seit: 17. Nov 2005
Ort: Hamburg
941 Beiträge
 
Delphi XE2 Professional
 
#7

AW: Unterschiede in 2 Bitmaps ermitteln

  Alt 24. Apr 2020, 16:54
@BlueStarHH:

Ich hab da mal auf die Schnelle was zusammengefrickelt.
Die Funktion FindDeltaRect liefert das Rechteck, in dem sich die Bilder unterscheiden.
Wenn die Bilder gleich sind, wird ein leeres Rechteck zurückgegeben.

Zum Test hab ich
1) Ein Bild mit 4928 x 3264 Pixeln als 24Bit Bitmap unter "A.bmp" gespeichert.
2) In das Bild einen kleinen Kreis gezeichnet und unter "B.bmp" gespeichert.
3) Die unten gezeigte Testprozedur laufen lassen.

Ausgegeben wurde
Code:
Bmp-Size: 4928 x 3264 
A vs A, T: 47 ms, R: 0 0 0 0 
A vs B, T: 47 ms, R: 1005 442 1035 464
Also 47 ms für Bilder mit 16 MPixeln.

Delphi-Quellcode:
FUNCTION FindDeltaRect(A,B:TBitmap):TRect;
var W,H,LO,X,Y:NativeInt; PA,PB,P1,P2:PByte;
begin
   W:=A.Width;
   H:=A.Height;
   if W<>B.Width then raise Exception.Create('Unterschiedliche Breiten');
   if H<>B.Height then raise Exception.Create('Unterschiedliche Höhen');
   if A.PixelFormat<>pf24bit then raise Exception.Create('A ist micht pf24bit');
   if B.PixelFormat<>pf24bit then raise Exception.Create('B ist micht pf24bit');
   if (W=0) or (H=0) then raise Exception.Create('Bitmaps sind leer');
   PA:=A.ScanLine[0];
   LO:=NativeInt(A.ScanLine[1])-NativeInt(PA);
   PB:=B.ScanLine[0];
   SetRect(Result,MaxInt,MaxInt,-MaxInt,-MaxInt);
   for Y:=0 to H-1 do begin
      P1:=PA;
      P2:=PB;
      for X:=0 to W-1 do begin
         if (PWord(P1)^<>PWord(P2)^) or ((P1+2)^<>(P2+2)^) then begin
            with Result do begin
               if X<Left then Left:=X;
               if X>Right then Right:=X;
               if Y<Top then Top:=Y;
               if Y>Bottom then Bottom:=Y;
            end;
         end;
         Inc(P1,3);
         Inc(P2,3);
      end;
      Inc(PA,LO);
      Inc(PB,LO);
   end;
   if Result.Left=MaxInt then begin
      SetRect(Result,0,0,0,0);
   end else begin
      Inc(Result.Right);
      Inc(Result.Bottom);
   end;
end;
Testprozedur:

Delphi-Quellcode:
PROCEDURE TMain.Test;
var A,B:TBitmap; R1,R2:TRect; T1,T2:Cardinal;
begin
   A:=Nil;
   B:=Nil;
   try
      try
         A:=TBitmap.Create;
         B:=TBitmap.Create;
         A.LoadFromFile(ExtractFilePath(ParamStr(0))+'A.Bmp');
         B.LoadFromFile(ExtractFilePath(ParamStr(0))+'B.Bmp');
         T1:=GetTickCount;
         R1:=FindDeltaRect(A,A);
         T1:=GetTickCount-T1;
         T2:=GetTickCount;
         R2:=FindDeltaRect(A,B);
         T2:=GetTickCount-T2;
         ShowMessage('Bmp-Size: '+IntToStr(A.Width)+' x '+IntToStr(A.Height)+#13+
                     'A vs A, T: '+IntToStr(T1)+' ms, R: '+
                     IntToStr(R1.Left)+' '+IntToStr(R1.Top)+' '+
                     IntToStr(R1.Right)+' '+IntToStr(R1.Bottom)+#13+
                     'A vs B, T: '+IntToStr(T2)+' ms, R: '+
                     IntToStr(R2.Left)+' '+IntToStr(R2.Top)+' '+
                     IntToStr(R2.Right)+' '+IntToStr(R2.Bottom));

      except
         on E:Exception do ShowMessage(E.Message);
      end;
   finally
      A.Free;
      B.Free;
   end;
end;
Gruß, Klaus
Die Titanic wurde von Profis gebaut,
die Arche Noah von einem Amateur.
... Und dieser Beitrag vom Amateurprofi....
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 21:45 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf